-
Notifications
You must be signed in to change notification settings - Fork 19
/
PackageManagerClient.cls
318 lines (274 loc) · 10.6 KB
/
PackageManagerClient.cls
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
Class %ZPM.PackageManager.Client.REST.PackageManagerClient Extends (%RegisteredObject, %ZPM.PackageManager.Core.IPackageService)
{
Property Location As %String;
Property Username As %String;
Property Password As %String;
Property Token As %String;
Method GetInfo(url As %String) As %DynamicObject
{
Set tRequest = ..GetHttpRequest()
Set tSC = tRequest.Get()
If $$$ISOK(tSC), tRequest.HttpResponse.StatusCode=200 {
Set tRes = {}.%FromJSON(tRequest.HttpResponse.Data)
Return tRes
}
$$$ThrowStatus($$$ERROR($$$GeneralError,"Registry server not available."))
}
Method ListModules(pSearchCriteria As %ZPM.PackageManager.Core.SearchCriteria) As %ListOfObjects(ELEMENTTYPE="%ZPM.PackageManager.Core.ResolvedModuleReference")
{
Set tList = ##class(%Library.ListOfObjects).%New()
Set tRequest = ..GetHttpRequest()
Set name = $$$lcase(pSearchCriteria.Name)
Set tVersionExpression = pSearchCriteria.VersionExpression
Set tSC = ##class(%ZPM.PackageManager.Core.SemanticVersionExpression).FromString(pSearchCriteria.VersionExpression, .tVersionExpression)
$$$ThrowOnError(tSC)
Set tURL = tRequest.Location_"packages/-/all"
If (name '= "") {
Set tURL = tRequest.Location_"packages/" _ name
}
Do tRequest.SetParam("allVersions", pSearchCriteria.AllVersions)
Do tRequest.SetParam("includePrerelease", pSearchCriteria.IncludePrerelease)
Do tRequest.SetParam("includeSnapshots", pSearchCriteria.IncludeSnapshots)
Set tSC = tRequest.Get($$$URLENCODE(tURL))
If $$$ISOK(tSC), tRequest.HttpResponse.StatusCode=200 {
Set tRes = {}.%FromJSON(tRequest.HttpResponse.Data)
If ('tRes.%IsA("%Library.DynamicArray")) {
Set tRes = [].%Push(tRes)
}
Set tIter = tRes.%GetIterator()
While tIter.%GetNext(.key, .item) {
Set allVersionsString = ""
If (item.allVersions) {
Set tIterVer = item.allVersions.%GetIterator()
While tIterVer.%GetNext(.key, .version) {
Set allVersionsString = allVersionsString_$LB(version)
}
}
Set tIterVer = item.versions.%GetIterator()
WHILE tIterVer.%GetNext(.verkey, .version) {
Set tVersion = ##class(%ZPM.PackageManager.Core.SemanticVersion).FromString(version)
CONTINUE:'tVersion.Satisfies(tVersionExpression)
Set tModRef = ##class(%ZPM.PackageManager.Core.ResolvedModuleReference).%New()
Set tModRef.Name = item.name
Set tModRef.Repository = item.repository
Set tModRef.VersionString = version
Set tModRef.Description = item.description
Set tModRef.Deployed = item.deployed
if $IsObject(item."platform_versions") {
Set tIterPVer = item."platform_versions".%GetIterator()
While tIterPVer.%GetNext(.tPVerKey, .platformVersion) {
Do tModRef.PlatformVersions.Insert(platformVersion)
}
}
Set tModRef.AllVersions = $ListToString(allVersionsString, ", ")
Set tModRef.Origin = item.origin
Do tList.Insert(tModRef)
}
}
}
Return tList
}
Method GetModule(pModuleReference As %ZPM.PackageManager.Core.ResolvedModuleReference, Output AsArchive As %Boolean = 1) As %Stream.Object
{
Set tRequest = ..GetHttpRequest()
Set tFileBinStream = ""
Set AsArchive = 1
Set name = pModuleReference.Name
Set version = pModuleReference.VersionString
Set deployed = pModuleReference.Deployed
If deployed {
Set platformVersion = $System.Version.GetMajor() _ "." _$System.Version.GetMinor()
}
Set tSC = tRequest.Get($$$URLENCODE(tRequest.Location _ "packages/" _ name _ "/" _ version _ $Select(deployed: "/" _ platformVersion, 1: "")))
Set tPackageUrl = ""
If $$$ISOK(tSC), tRequest.HttpResponse.StatusCode=200 {
Set tRes = {}.%FromJSON(tRequest.HttpResponse.Data)
Set tPackageUrl = tRes.url
Set tHash = tRes.hash
Set tRequest = ..GetHttpRequest()
Set tRequest.Timeout = 300
Set tSC = tRequest.Get(tPackageUrl)
If $$$ISOK(tSC), tRequest.HttpResponse.StatusCode=200 {
Set tFileBinStream = ##class(%Stream.FileBinary).%New()
Set tFileBinStream.Filename = ##class(%File).TempFilename("tgz")
do tFileBinStream.CopyFromAndSave(tRequest.HttpResponse.Data)
If (tHash'="") {
set tTestHash = $$$lcase(##class(%File).SHA1Hash(tFileBinStream.Filename, 1))
if tTestHash'=tHash {
$$$ThrowStatus($$$ERROR($$$GeneralError, "Download module, hash mismatch. " _ tTestHash))
}
}
Set token = tRequest.HttpResponse.GetHeader("INSTALLTOKEN")
If (token'="") {
Set ^IRIS.TempZPMRInst(name,version) = token
}
}
}
If tFileBinStream="" {
$$$ThrowStatus($$$ERROR($$$GeneralError,"Download module '" _ name _ "@" _ version _ "', something went wrong (StatusCode: " _ tRequest.HttpResponse.StatusCode _ ")." ))
}
Quit tFileBinStream
}
Method GetModuleManifest(pModuleReference As %ZPM.PackageManager.Core.ResolvedModuleReference) As %Stream.Object
{
Set tRequest = ..GetHttpRequest()
Set tFileBinStream = ""
Set name = pModuleReference.Name
Set version = pModuleReference.VersionString
Set tSC = tRequest.Get($$$URLENCODE(tRequest.Location_"packages/" _ name _ "/"_version_"/manifest"))
If $$$ISOK(tSC), tRequest.HttpResponse.StatusCode=200 {
Return tRequest.HttpResponse.Data
}
$$$ThrowStatus($$$ERROR($$$GeneralError,"Download package manifest, something went wrong."))
}
Method SendAnalyticsToRegistry(action As %String, data As %DynamicObject)
{
Set tRequest = ..GetHttpRequest()
Set tRequest.ContentType = "application/json"
Do tRequest.SetHeader("INSTALLTOKEN", $Get(^IRIS.TempZPMRInst(data.name,data.version)))
Kill ^IRIS.TempZPMRInst(data.name,data.version)
Do data.%ToJSON(tRequest.EntityBody)
Set tSC = tRequest.Post($$$URLENCODE(tRequest.Location_"collect/" _ action))
If ($$$ISERR(tSC) || (tRequest.HttpResponse.StatusCode'=200)) {
$$$ThrowStatus($$$ERROR($$$GeneralError,"Error Sending Analytics Data"))
}
}
Method SendAnalyticsToGoogle(action As %String, data As %DynamicObject)
{
Set TrackingID = ##class(%ZPM.PackageManager.Client.Settings).GetAnalyticsTrackingId()
Quit:(TrackingID = "") 0
Set tRequest = ##class(%Net.HttpRequest).%New()
Set tRequest.FollowRedirect = 1
Set tRequest.Server = "www.google-analytics.com"
Set tRequest.SSLConfiguration = ..GetSSLConfiguration(tRequest.Server)
Set status = $case($$$ISOK(data.success), 1: "Success", : "Failure")
Set version = data.version
Set irisPlatform = $system.Version.GetPlatform()
Set irisVersion = $system.Version.GetNumber()
Set irisProduct = $system.Version.GetProduct()
Do tRequest.SetParam("v","1")
Do tRequest.SetParam("tid",TrackingID)
Do tRequest.SetParam("cid",##class(%SYS.System).InstanceGUID())
Do tRequest.SetParam("ds","web")
Do tRequest.SetParam("t","event")
Do tRequest.SetParam("ec",data.name)
Do tRequest.SetParam("ea",status)
Do tRequest.SetParam("el",version_", "_irisProduct_", "_irisPlatform_", "_irisVersion)
Return tRequest.Post("/collect")
}
Method CollectAnalytics(action As %String, name As %String, version As %String, success As %Boolean = 1, msg As %String = "") As %Status
{
If ('##class(%ZPM.PackageManager.Client.Settings).GetAnalyticsAvailable()) {
Return $$$OK
}
Set jo = {}
Set jo.name = name
Set jo.version = version
Set jo.guid = ##class(%SYS.System).InstanceGUID()
Set jo."system_version" = $ZVersion
Set zpmVersion = ##class(%ZPM.PackageManager.Client.Utils).GetZPMVersion()
If (zpmVersion'="") {
Set jo."zpmclient_version" = zpmVersion
}
Do jo.%Set("success",success,"boolean")
Set jo."error_msg" = msg
Try {
Do ..SendAnalyticsToRegistry(action, jo)
Do ..SendAnalyticsToGoogle(action, jo)
} Catch ex {
Return ex.AsStatus()
}
Return $$$OK
}
/// For run-time checks to ensure the service is available before attempting to invoke it.
Method IsAvailable() As %Boolean
{
Set tAvailable = 0
Set tRequest = ..GetHttpRequest()
Set tRequest.Timeout = 30
Set tSC = tRequest.Get($$$URLENCODE(tRequest.Location_"_ping"))
If $$$ISOK(tSC), tRequest.HttpResponse.StatusCode = 401 {
$$$ThrowStatus($$$ERROR($$$GeneralError, "Registry "_..Location_": аuthorization required."))
}
If $$$ISOK(tSC) && (tRequest.HttpResponse.StatusCode = 200) {
Set tAvailable = 1
}
Return tAvailable
}
Method GetHttpRequest(tLocation = {..Location}) As %Net.HttpRequest
{
Set tRequest = ##class(%Net.HttpRequest).%New()
Set tRequest.FollowRedirect = 1
Set tLocation = $$$URLDECODE(tLocation)
If ($piece(tLocation, "://")'["http") {
Set tLocation = "http://" _ tLocation
}
Do ##class(%Net.URLParser).Parse(tLocation,.tComponents)
If ($$$lcase(tComponents("scheme")) [ "http") {
If ($Data(tComponents("host"))#2) {
Set tRequest.Server = tComponents("host")
}
If ($Data(tComponents("port"))#2) {
Set tRequest.Port = tComponents("port")
}
If ($$$lcase(tComponents("scheme")) = "https") {
Set tRequest.Https = 1
}
If ($Get(tComponents("path"))'="") {
Set path = tComponents("path")
If ($Extract(path,1,1)="/") {
Set path = $Extract(path,2,*)
}
Set tRequest.Location = path
}
If $Extract(tRequest.Location, *) '= "/" {
Set tRequest.Location = tRequest.Location _ "/"
}
#; in case of redirection
Set tRequest.SSLConfiguration = ..GetSSLConfiguration(tRequest.Server)
If (..Token '= "") {
// key auth
Do tRequest.SetHeader("apikey",..Token)
}
If (..Username '= "") && (..Password '= "") {
// basic auth
Set tRequest.Username = ..Username
Set tRequest.Password = ..Password
}
set proxy=$System.Util.GetEnviron("https_proxy")
if proxy'="" {
Do ##class(%Net.URLParser).Parse(proxy,.pr)
if (tRequest.Https) {
set tRequest.ProxyHTTPS=1
set tRequest.ProxyTunnel=1
}
set tRequest.ProxyPort=pr("port")
set tRequest.ProxyServer=pr("host")
if $get(pr("username"))'="",$get(pr("password"))'="" {
set tRequest.ProxyAuthorization="Basic "_$system.Encryption.Base64Encode(pr("username")_":"_pr("password"))
}
}
}
Return tRequest
}
ClassMethod GetSSLConfiguration(host) As %String
{
NEW $NAMESPACE
SET $NAMESPACE = "%SYS"
IF '##class(Security.SSLConfigs).Exists(host) {
DO ##class(Security.SSLConfigs).Create(host)
}
QUIT host
}
/// Used for unittests, reset's external temporary registry from any packages.
Method ResetRegistry() As %Status
{
Set debugKey = $system.Util.GetEnviron("TEST_REGISTRY_DEBUG")
if (debugKey="") {
Quit $$$OK
}
Set tRequest = ..GetHttpRequest()
Do tRequest.SetHeader("REGISTRY_DEBUG", debugKey)
Quit tRequest.Get(tRequest.Location_"_reset")
}
}