-
Notifications
You must be signed in to change notification settings - Fork 276
/
SNMP.pm
2671 lines (2189 loc) · 83.5 KB
/
SNMP.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
package pf::SNMP;
=head1 NAME
pf::SNMP - Object oriented module to access SNMP enabled network switches
=head1 DESCRIPTION
The pf::SNMP module implements an object oriented interface to access
SNMP enabled network switches. This module only contains some basic
functionnality and is meant to be subclassed.
=cut
use strict;
use warnings;
use Carp;
use Data::Dumper;
use Net::SNMP;
use Log::Log4perl;
use Try::Tiny;
our $VERSION = 2.00;
use pf::config;
use pf::locationlog;
use pf::node;
# SNMP constants
use pf::SNMP::constants;
use pf::util;
use pf::util::radius qw(perform_disconnect);
=head1 SUBROUTINES
=over
=cut
=item supportsFloatingDevice
Returns 1 if switch type supports floating network devices
=cut
sub supportsFloatingDevice {
my ( $this ) = @_;
my $logger = Log::Log4perl::get_logger( ref($this) );
$logger->error("Floating devices are not supported on switch type " . ref($this));
return $FALSE;
}
=item supportsWiredMacAuth
Returns 1 if switch type supports Wired MAC Authentication (Wired Access Authorization through RADIUS)
=cut
sub supportsWiredMacAuth {
my ( $this ) = @_;
my $logger = Log::Log4perl::get_logger( ref($this) );
$logger->error(
"Wired MAC Authentication (Wired Access Authorization through RADIUS) "
. "is not supported on switch type " . ref($this) . ". Please let us know what hardware you are using."
);
return $FALSE;
}
=item supportsWiredDot1x - Returns 1 if switch type supports Wired 802.1X
=cut
sub supportsWiredDot1x {
my ( $this ) = @_;
my $logger = Log::Log4perl::get_logger( ref($this) );
$logger->error(
"Wired 802.1X is not supported on switch type " . ref($this) . ". "
. "Please let us know what hardware you are using."
);
return $FALSE;
}
=item supportsWirelessMacAuth
Returns 1 if switch type supports Wireless MAC Authentication (RADIUS Authentication)
=cut
sub supportsWirelessMacAuth {
my ( $this ) = @_;
my $logger = Log::Log4perl::get_logger( ref($this) );
$logger->error(
"Wireless MAC Authentication is not supported on switch type " . ref($this) . ". "
. "Please let us know what hardware you are using."
);
return $FALSE;
}
=item supportsWirelessDot1x - Returns 1 if switch type supports Wireless 802.1X (aka WPA-Enterprise)
=cut
sub supportsWirelessDot1x {
my ( $this ) = @_;
my $logger = Log::Log4perl::get_logger( ref($this) );
$logger->error(
"Wireless 802.1X (WPA-Enterprise) is not supported on switch type " . ref($this) . ". "
. "Please let us know what hardware you are using."
);
return $FALSE;
}
=item supportsRadiusVoip
=cut
sub supportsRadiusVoip {
my ( $this ) = @_;
my $logger = Log::Log4perl::get_logger( ref($this) );
$logger->warn(
"RADIUS Authentication of IP Phones is not supported on switch type " . ref($this) . ". "
. "Please let us know what hardware you are using."
);
return $FALSE;
}
=item supportsSaveConfig
=cut
sub supportsSaveConfig {
my ( $this ) = @_;
my $logger = Log::Log4perl::get_logger( ref($this) );
return $FALSE;
}
=item supportsRadiusDynamicVlanAssignment
=cut
sub supportsRadiusDynamicVlanAssignment { return $TRUE; }
sub new {
my ( $class, %argv ) = @_;
my $this = bless {
'_customVlan1' => undef,
'_customVlan2' => undef,
'_customVlan3' => undef,
'_customVlan4' => undef,
'_customVlan5' => undef,
'_error' => undef,
'_guestVlan' => undef,
'_ip' => undef,
'_isolationVlan' => undef,
'_macDetectionVlan' => undef,
'_macSearchesMaxNb' => undef,
'_macSearchesSleepInterval' => undef,
'_mode' => undef,
'_normalVlan' => undef,
'_registrationVlan' => undef,
'_sessionRead' => undef,
'_sessionWrite' => undef,
'_sessionControllerWrite' => undef,
'_SNMPAuthPasswordRead' => undef,
'_SNMPAuthPasswordTrap' => undef,
'_SNMPAuthPasswordWrite' => undef,
'_SNMPAuthProtocolRead' => undef,
'_SNMPAuthProtocolTrap' => undef,
'_SNMPAuthProtocolWrite' => undef,
'_SNMPCommunityRead' => undef,
'_SNMPCommunityTrap' => undef,
'_SNMPCommunityWrite' => undef,
'_SNMPEngineID' => undef,
'_SNMPPrivPasswordRead' => undef,
'_SNMPPrivPasswordTrap' => undef,
'_SNMPPrivPasswordWrite' => undef,
'_SNMPPrivProtocolRead' => undef,
'_SNMPPrivProtocolTrap' => undef,
'_SNMPPrivProtocolWrite' => undef,
'_SNMPUserNameRead' => undef,
'_SNMPUserNameTrap' => undef,
'_SNMPUserNameWrite' => undef,
'_SNMPVersion' => 1,
'_SNMPVersionTrap' => 1,
'_cliEnablePwd' => undef,
'_cliPwd' => undef,
'_cliUser' => undef,
'_cliTransport' => undef,
'_wsPwd' => undef,
'_wsUser' => undef,
'_wsTransport' => undef,
'_radiusSecret' => undef,
'_controllerIp' => undef,
'_uplink' => undef,
'_vlans' => undef,
'_voiceVlan' => undef,
'_VoIPEnabled' => undef
}, $class;
foreach ( keys %argv ) {
if (/^-?SNMPCommunityRead$/i) {
$this->{_SNMPCommunityRead} = $argv{$_};
} elsif (/^-?SNMPCommunityTrap$/i) {
$this->{_SNMPCommunityTrap} = $argv{$_};
} elsif (/^-?SNMPCommunityWrite$/i) {
$this->{_SNMPCommunityWrite} = $argv{$_};
} elsif (/^-?customVlan1$/i) {
$this->{_customVlan1} = $argv{$_};
} elsif (/^-?customVlan2$/i) {
$this->{_customVlan2} = $argv{$_};
} elsif (/^-?customVlan2$/i) {
$this->{_customVlan2} = $argv{$_};
} elsif (/^-?customVlan3$/i) {
$this->{_customVlan3} = $argv{$_};
} elsif (/^-?customVlan4$/i) {
$this->{_customVlan4} = $argv{$_};
} elsif (/^-?customVlan5$/i) {
$this->{_customVlan5} = $argv{$_};
} elsif (/^-?guestVlan$/i) {
$this->{_guestVlan} = $argv{$_};
} elsif (/^-?ip$/i) {
$this->{_ip} = $argv{$_};
} elsif (/^-?isolationVlan$/i) {
$this->{_isolationVlan} = $argv{$_};
} elsif (/^-?macDetectionVlan$/i) {
$this->{_macDetectionVlan} = $argv{$_};
} elsif (/^-?macSearchesMaxNb$/i) {
$this->{_macSearchesMaxNb} = $argv{$_};
} elsif (/^-?macSearchesSleepInterval$/i) {
$this->{_macSearchesSleepInterval} = $argv{$_};
} elsif (/^-?mode$/i) {
$this->{_mode} = $argv{$_};
} elsif (/^-?normalVlan$/i) {
$this->{_normalVlan} = $argv{$_};
} elsif (/^-?registrationVlan$/i) {
$this->{_registrationVlan} = $argv{$_};
} elsif (/^-?SNMPAuthPasswordRead$/i) {
$this->{_SNMPAuthPasswordRead} = $argv{$_};
} elsif (/^-?SNMPAuthPasswordTrap$/i) {
$this->{_SNMPAuthPasswordTrap} = $argv{$_};
} elsif (/^-?SNMPAuthPasswordWrite$/i) {
$this->{_SNMPAuthPasswordWrite} = $argv{$_};
} elsif (/^-?SNMPAuthProtocolRead$/i) {
$this->{_SNMPAuthProtocolRead} = $argv{$_};
} elsif (/^-?SNMPAuthProtocolTrap$/i) {
$this->{_SNMPAuthProtocolTrap} = $argv{$_};
} elsif (/^-?SNMPAuthProtocolWrite$/i) {
$this->{_SNMPAuthProtocolWrite} = $argv{$_};
} elsif (/^-?SNMPPrivPasswordRead$/i) {
$this->{_SNMPPrivPasswordRead} = $argv{$_};
} elsif (/^-?SNMPPrivPasswordTrap$/i) {
$this->{_SNMPPrivPasswordTrap} = $argv{$_};
} elsif (/^-?SNMPPrivPasswordWrite$/i) {
$this->{_SNMPPrivPasswordWrite} = $argv{$_};
} elsif (/^-?SNMPPrivProtocolRead$/i) {
$this->{_SNMPPrivProtocolRead} = $argv{$_};
} elsif (/^-?SNMPPrivProtocolTrap$/i) {
$this->{_SNMPPrivProtocolTrap} = $argv{$_};
} elsif (/^-?SNMPPrivProtocolWrite$/i) {
$this->{_SNMPPrivProtocolWrite} = $argv{$_};
} elsif (/^-?SNMPUserNameRead$/i) {
$this->{_SNMPUserNameRead} = $argv{$_};
} elsif (/^-?SNMPUserNameTrap$/i) {
$this->{_SNMPUserNameTrap} = $argv{$_};
} elsif (/^-?SNMPUserNameWrite$/i) {
$this->{_SNMPUserNameWrite} = $argv{$_};
} elsif (/^-?cliEnablePwd$/i) {
$this->{_cliEnablePwd} = $argv{$_};
} elsif (/^-?cliPwd$/i) {
$this->{_cliPwd} = $argv{$_};
} elsif (/^-?cliUser$/i) {
$this->{_cliUser} = $argv{$_};
} elsif (/^-?cliTransport$/i) {
$this->{_cliTransport} = $argv{$_};
} elsif (/^-?wsPwd$/i) {
$this->{_wsPwd} = $argv{$_};
} elsif (/^-?wsUser$/i) {
$this->{_wsUser} = $argv{$_};
} elsif (/^-?wsTransport$/i) {
$this->{_wsTransport} = lc($argv{$_});
} elsif (/^-?radiusSecret$/i) {
$this->{_radiusSecret} = $argv{$_};
} elsif (/^-?controllerIp$/i) {
$this->{_controllerIp} = lc($argv{$_});
} elsif (/^-?uplink$/i) {
$this->{_uplink} = $argv{$_};
} elsif (/^-?SNMPEngineID$/i) {
$this->{_SNMPEngineID} = $argv{$_};
} elsif (/^-?SNMPVersion$/i) {
$this->{_SNMPVersion} = $argv{$_};
} elsif (/^-?SNMPVersionTrap$/i) {
$this->{_SNMPVersionTrap} = $argv{$_};
} elsif (/^-?vlans$/i) {
$this->{_vlans} = $argv{$_};
} elsif (/^-?voiceVlan$/i) {
$this->{_voiceVlan} = $argv{$_};
} elsif (/^-?VoIPEnabled$/i) {
$this->{_VoIPEnabled} = $argv{$_};
}
}
return $this;
}
=item isUpLink - determine is a given ifIndex is connected to another switch
=cut
sub isUpLink {
my ( $this, $ifIndex ) = @_;
return ( ( defined( $this->{_uplink} ) )
&& ( grep( { $_ == $ifIndex } @{ $this->{_uplink} } ) == 1 ) );
}
=item connectRead - establish read connection to switch
=cut
sub connectRead {
my $this = shift;
my $logger = Log::Log4perl::get_logger( ref($this) );
if ( defined( $this->{_sessionRead} ) ) {
return 1;
}
$logger->debug( "opening SNMP v"
. $this->{_SNMPVersion}
. " read connection to $this->{_ip}" );
if ( $this->{_SNMPVersion} eq '3' ) {
( $this->{_sessionRead}, $this->{_error} ) = Net::SNMP->session(
-hostname => $this->{_ip},
-version => $this->{_SNMPVersion},
-username => $this->{_SNMPUserNameRead},
-timeout => 2,
-retries => 1,
-authprotocol => $this->{_SNMPAuthProtocolRead},
-authpassword => $this->{_SNMPAuthPasswordRead},
-privprotocol => $this->{_SNMPPrivProtocolRead},
-privpassword => $this->{_SNMPPrivPasswordRead}
);
} else {
( $this->{_sessionRead}, $this->{_error} ) = Net::SNMP->session(
-hostname => $this->{_ip},
-version => $this->{_SNMPVersion},
-timeout => 2,
-retries => 1,
-community => $this->{_SNMPCommunityRead}
);
}
if ( !defined( $this->{_sessionRead} ) ) {
$logger->error( "error creating SNMP v"
. $this->{_SNMPVersion}
. " read connection to "
. $this->{_ip} . ": "
. $this->{_error} );
return 0;
} else {
my $oid_sysLocation = '1.3.6.1.2.1.1.6.0';
$logger->trace("SNMP get_request for sysLocation: $oid_sysLocation");
my $result = $this->{_sessionRead}
->get_request( -varbindlist => [$oid_sysLocation] );
if ( !defined($result) ) {
$logger->error( "error creating SNMP v"
. $this->{_SNMPVersion}
. " read connection to "
. $this->{_ip} . ": "
. $this->{_sessionRead}->error() );
$this->{_sessionRead} = undef;
return 0;
}
}
return 1;
}
=item disconnectRead - closing read connection to switch
=cut
sub disconnectRead {
my $this = shift;
my $logger = Log::Log4perl::get_logger( ref($this) );
if ( !defined( $this->{_sessionRead} ) ) {
return 1;
}
$logger->debug( "closing SNMP v" . $this->{_SNMPVersion} . " read connection to $this->{_ip}" );
$this->{_sessionRead}->close;
return 1;
}
=item connectWriteTo
Establishes an SNMP Write connection to a given IP and installs the session object into this object's sessionKey.
It performs a write test to make sure that the write actually works.
=cut
sub connectWriteTo {
my ($this, $ip, $sessionKey) = @_;
my $logger = Log::Log4perl::get_logger( ref($this) );
# if connection already exists, no need to connect again
return 1 if ( defined( $this->{$sessionKey} ) );
$logger->debug( "opening SNMP v" . $this->{_SNMPVersion} . " write connection to $ip" );
if ( $this->{_SNMPVersion} eq '3' ) {
( $this->{$sessionKey}, $this->{_error} ) = Net::SNMP->session(
-hostname => $ip,
-version => $this->{_SNMPVersion},
-timeout => 2,
-retries => 1,
-username => $this->{_SNMPUserNameWrite},
-authprotocol => $this->{_SNMPAuthProtocolWrite},
-authpassword => $this->{_SNMPAuthPasswordWrite},
-privprotocol => $this->{_SNMPPrivProtocolWrite},
-privpassword => $this->{_SNMPPrivPasswordWrite}
);
} else {
( $this->{$sessionKey}, $this->{_error} ) = Net::SNMP->session(
-hostname => $ip,
-version => $this->{_SNMPVersion},
-timeout => 2,
-retries => 1,
-community => $this->{_SNMPCommunityWrite}
);
}
if ( !defined( $this->{$sessionKey} ) ) {
$logger->error( "error creating SNMP v" . $this->{_SNMPVersion} . " write connection to $ip: $this->{_error}" );
return 0;
} else {
my $oid_sysLocation = '1.3.6.1.2.1.1.6.0';
$logger->trace("SNMP get_request for sysLocation: $oid_sysLocation");
my $result = $this->{$sessionKey}->get_request( -varbindlist => [$oid_sysLocation] );
if ( !defined($result) ) {
$logger->error(
"error creating SNMP v" . $this->{_SNMPVersion} . " write connection to $ip: "
. $this->{$sessionKey}->error()
);
$this->{$sessionKey} = undef;
return 0;
} else {
my $sysLocation = $result->{$oid_sysLocation} || '';
$logger->trace(
"SNMP set_request for sysLocation: $oid_sysLocation to $sysLocation"
);
$result = $this->{$sessionKey}->set_request(
-varbindlist => [
"$oid_sysLocation", Net::SNMP::OCTET_STRING,
$sysLocation
]
);
if ( !defined($result) ) {
$logger->error(
"error creating SNMP v" . $this->{_SNMPVersion} . " write connection to $ip: "
. $this->{$sessionKey}->error()
. " it looks like you specified a read-only community instead of a read-write one"
);
$this->{$sessionKey} = undef;
return 0;
}
}
}
return 1;
}
=item connectWrite
Establishes a default SNMP Write connection to the network device.
Uses connectWriteTo with IP from configuration internally.
=cut
sub connectWrite {
my $this = shift;
return $this->connectWriteTo($this->{_ip}, '_sessionWrite');
}
=item connectWriteToController
Establishes an SNMP write connection to the controller of the network device as defined in controllerIp.
=cut
sub connectWriteToController {
my $this = shift;
return $this->connectWriteTo($this->{_controllerIp}, '_sessionControllerWrite');
}
=item disconnectWriteTo
Closes an SNMP Write connection. Requires sessionKey stored in object (as when calling connectWriteTo).
=cut
sub disconnectWriteTo {
my ($this, $sessionKey) = @_;
my $logger = Log::Log4perl::get_logger( ref($this) );
return 1 if ( !defined( $this->{$sessionKey} ) );
$logger->debug(
"closing SNMP v" . $this->{_SNMPVersion} . " write connection to " . $this->{$sessionKey}->hostname()
);
$this->{$sessionKey}->close();
$this->{$sessionKey} = undef;
return 1;
}
=item disconnectWrite
Closes the default SNMP connection to the network device's IP.
=cut
sub disconnectWrite {
my $this = shift;
return $this->disconnectWriteTo('_sessionWrite');
}
=item disconnectWriteToController
Closes the SNMP connection to the network device's controller.
=cut
sub disconnectWriteToController {
my $this = shift;
return $this->disconnectWriteTo('_sessionControllerWrite');
}
=item setVlan
Set a port to a VLAN validating some rules first then calling the switch's _setVlan.
=cut
sub setVlan {
my ($this, $ifIndex, $newVlan, $switch_locker_ref, $presentPCMac) = @_;
my $logger = Log::Log4perl::get_logger( ref($this) );
if ( !$this->isProductionMode() ) {
$logger->warn(
"Should set ifIndex $ifIndex to VLAN $newVlan but the switch is not in production -> Do nothing"
);
return 1;
}
my $vlan = $this->getVlan($ifIndex);
if ( !defined($presentPCMac) && ( $newVlan ne $this->{_macDetectionVlan} ) ) {
my @macArray = $this->_getMacAtIfIndex( $ifIndex, $vlan );
if ( scalar(@macArray) == 1 ) {
$presentPCMac = $macArray[0];
}
}
#handle some exceptions
# old VLAN is not a VLAN we manage
if (!$this->isManagedVlan($vlan)) {
$logger->warn("old VLAN $vlan is not a managed VLAN -> Do nothing");
return 1;
}
# VLAN -1 handling
# TODO at some point we should create a new blackhole / blacklist API
# it would take advantage of per-switch features
if ($newVlan == -1) {
$logger->warn("VLAN -1 is not supported in SNMP-Traps mode. Returning the switch's mac-detection VLAN.");
$newVlan = $this->getVlanByName('macDetectionVlan');
}
# unmanaged VLAN
if (!$this->isManagedVlan($newVlan)) {
$logger->warn(
"new VLAN $newVlan is not a managed VLAN -> replacing VLAN $newVlan with MAC detection VLAN "
. $this->getVlanByName('macDetectionVlan')
);
$newVlan = $this->getVlanByName('macDetectionVlan');
}
# VLAN are not defined on the switch
if ( !$this->isDefinedVlan($newVlan) ) {
if ( $newVlan == $this->getVlanByName('macDetectionVlan') ) {
$logger->warn(
"MAC detection VLAN " . $this->getVlanByName('macDetectionVlan')
. " is not defined on switch " . $this->{_ip}
. " -> Do nothing"
);
return 1;
}
$logger->warn(
"new VLAN $newVlan is not defined on switch " . $this->{_ip}
. " -> replacing VLAN $newVlan with MAC detection VLAN "
. $this->getVlanByName('macDetectionVlan')
);
$newVlan = $this->getVlanByName('macDetectionVlan');
if ( !$this->isDefinedVlan($newVlan) ) {
$logger->warn(
"MAC detection VLAN " . $this->getVlanByName('macDetectionVlan')
. " is also not defined on switch " . $this->{_ip}
. " -> Do nothing"
);
return 1;
}
}
#closes old locationlog entries and create a new one if required
locationlog_synchronize($this->{_ip}, $ifIndex, $newVlan, $presentPCMac, $NO_VOIP, $WIRED_SNMP_TRAPS);
if ( $vlan == $newVlan ) {
$logger->info(
"Should set " . $this->{_ip} . " ifIndex $ifIndex to VLAN $newVlan "
. "but it is already in this VLAN -> Do nothing"
);
return 1;
}
#and finally set the VLAN
$logger->info("setting VLAN at " . $this->{_ip} . " ifIndex $ifIndex from $vlan to $newVlan");
return $this->_setVlan( $ifIndex, $newVlan, $vlan, $switch_locker_ref );
}
=item setVlanWithName - set the ifIndex VLAN to the VLAN name in the switch instead of vlan number
TODO: not implemented, currently only a nameholder
=cut
sub setVlanWithName {
my ($this) = @_;
my $logger = Log::Log4perl::get_logger( ref($this) );
$logger->warn("not implemented!");
return;
}
=item _setVlanByOnlyModifyingPvid
=cut
sub _setVlanByOnlyModifyingPvid {
my ( $this, $ifIndex, $newVlan, $oldVlan, $switch_locker_ref ) = @_;
my $logger = Log::Log4perl::get_logger( ref($this) );
if ( !$this->connectRead() ) {
return 0;
}
my $OID_dot1qPvid = '1.3.6.1.2.1.17.7.1.4.5.1.1'; # Q-BRIDGE-MIB
my $result;
if ( !$this->connectWrite() ) {
return 0;
}
my $dot1dBasePort = $this->getDot1dBasePortForThisIfIndex($ifIndex);
$logger->trace("SNMP set_request for Pvid for new VLAN");
$result
= $this->{_sessionWrite}->set_request( -varbindlist =>
[ "$OID_dot1qPvid.$dot1dBasePort", Net::SNMP::GAUGE32, $newVlan ]
);
if ( !defined($result) ) {
$logger->error(
"error setting Pvid: " . $this->{_sessionWrite}->error );
}
return ( defined($result) );
}
=item getVlanByName - get the VLAN number of a given name in switches.conf
Input: vlan name (as in switches.conf)
=cut
sub getVlanByName {
my ($this, $vlanName) = @_;
my $logger = Log::Log4perl::get_logger(ref($this));
if (!exists($this->{"_".$vlanName})) {
# VLAN name doesn't exist
$logger->warn("VLAN $vlanName is not a valid VLAN identifier (see switches.conf)");
return;
}
if ($this->{"_".$vlanName} !~ /^\d+$/) {
# is not resolved to a valid VLAN number
$logger->warn("VLAN $vlanName is not properly configured in switches.conf, not a vlan number");
return;
}
return $this->{"_".$vlanName};
}
=item setVlanByName - set the ifIndex VLAN to the VLAN identified by given name in switches.conf
Input: ifIndex, vlan name (as in switches.conf), switch lock
=cut
sub setVlanByName {
my ($this, $ifIndex, $vlanName, $switch_locker_ref) = @_;
my $logger = Log::Log4perl::get_logger(ref($this));
if (!exists($this->{"_".$vlanName})) {
# VLAN name doesn't exist
$logger->warn("VLAN $vlanName is not a valid VLAN identifier (see switches.conf)");
return;
}
if ($this->{"_".$vlanName} !~ /^\d+$/) {
# is not resolved to a valid VLAN number
$logger->warn("VLAN $vlanName is not properly configured in switches.conf, not a vlan number");
return;
}
return $this->setVlan($ifIndex, $this->{"_".$vlanName}, $switch_locker_ref);
}
=item setIsolationVlan - set the port VLAN to the isolation VLAN
DEPRECATED: use setVlanByName($ifIndex, $switch_locker_ref, 'isolationVlan') instead
=cut
# TODO deprecated in 1.8.7 remove for 1.9 / 2.0 ?
sub setIsolationVlan {
my ( $this, $ifIndex, $switch_locker_ref ) = @_;
my $logger = Log::Log4perl::get_logger(ref($this));
$logger->warn("this method is deprecated, please update your code to use setVlanByName instead");
return $this->setVlan( $ifIndex, $this->{_isolationVlan},
$switch_locker_ref );
}
=item setRegistrationVlan - set the port VLAN to the registration VLAN
DEPRECATED: use setVlanByName($ifIndex, $switch_locker_ref, 'registrationVlan') instead
=cut
# TODO deprecated in 1.8.7 remove for 1.9 / 2.0 ?
sub setRegistrationVlan {
my ( $this, $ifIndex, $switch_locker_ref ) = @_;
my $logger = Log::Log4perl::get_logger(ref($this));
$logger->warn("this method is deprecated, please update your code to use setVlanByName instead");
return $this->setVlan( $ifIndex, $this->{_registrationVlan},
$switch_locker_ref );
}
=item getIfOperStatus - obtain the ifOperStatus of the specified switch port (1 indicated up, 2 indicates down)
=cut
sub getIfOperStatus {
my ( $this, $ifIndex ) = @_;
my $logger = Log::Log4perl::get_logger( ref($this) );
my $oid_ifOperStatus = '1.3.6.1.2.1.2.2.1.8';
if ( !$this->connectRead() ) {
return 0;
}
$logger->trace(
"SNMP get_request for ifOperStatus: $oid_ifOperStatus.$ifIndex");
my $result = $this->{_sessionRead}
->get_request( -varbindlist => ["$oid_ifOperStatus.$ifIndex"] );
return $result->{"$oid_ifOperStatus.$ifIndex"};
}
=item setMacDetectionVlan - set the port VLAN to the MAC detection VLAN
=cut
sub setMacDetectionVlan {
my ( $this, $ifIndex, $switch_locker_ref,
$closeAllOpenLocationlogEntries )
= @_;
return $this->setVlan( $ifIndex, $this->{_macDetectionVlan},
$switch_locker_ref, undef, $closeAllOpenLocationlogEntries );
}
=item setNormalVlan - set the port VLAN to the 'normal' VLAN
DEPRECATED: use setVlanByName($ifIndex, $switch_locker_ref, 'normalVlan') instead
=cut
# TODO deprecated in 1.8.7 remove for 1.9 / 2.0 ?
sub setNormalVlan {
my ( $this, $ifIndex, $switch_locker_ref ) = @_;
my $logger = Log::Log4perl::get_logger(ref($this));
$logger->warn("this method is deprecated, please update your code to use setVlanByName instead");
return $this->setVlan( $ifIndex, $this->{_normalVlan},
$switch_locker_ref );
}
=item getAlias - get the port description
=cut
sub getAlias {
my ( $this, $ifIndex ) = @_;
my $logger = Log::Log4perl::get_logger( ref($this) );
if ( !$this->connectRead() ) {
return '';
}
my $OID_ifAlias = '1.3.6.1.2.1.31.1.1.1.18';
$logger->trace("SNMP get_request for ifAlias: $OID_ifAlias.$ifIndex");
my $result = $this->{_sessionRead}
->get_request( -varbindlist => ["$OID_ifAlias.$ifIndex"] );
return $result->{"$OID_ifAlias.$ifIndex"};
}
=item getSwitchLocation - get the switch location string
=cut
sub getSwitchLocation {
my ( $this ) = @_;
my $logger = Log::Log4perl::get_logger( ref($this) );
return if ( !$this->connectRead() );
my $OID_sysLocation = '1.3.6.1.2.1.1.6.0';
$logger->trace("SNMP get_request for sysLocation: $OID_sysLocation");
my $result = $this->{_sessionRead}->get_request( -varbindlist => ["$OID_sysLocation"] );
if ( !defined($result) ) {
$logger->error("couldn't fetch sysLocation on $this->{_ip}: " . $this->{_sessionWrite}->error());
return;
}
if (!defined($result->{"$OID_sysLocation"})) {
$logger->error("no result for sysLocation on $this->{_ip}");
}
return $result->{"$OID_sysLocation"};
}
=item setAlias - set the port description
=cut
sub setAlias {
my ( $this, $ifIndex, $alias ) = @_;
my $logger = Log::Log4perl::get_logger( ref($this) );
$logger->info( "setting "
. $this->{_ip}
. " ifIndex $ifIndex ifAlias from "
. $this->getAlias($ifIndex)
. " to $alias" );
if ( !$this->isProductionMode() ) {
$logger->info(
"not in production mode ... we won't change this port ifAlias");
return 1;
}
if ( !$this->connectWrite() ) {
return 0;
}
my $OID_ifAlias = '1.3.6.1.2.1.31.1.1.1.18';
$logger->trace(
"SNMP set_request for ifAlias: $OID_ifAlias.$ifIndex = $alias");
my $result = $this->{_sessionWrite}->set_request( -varbindlist =>
[ "$OID_ifAlias.$ifIndex", Net::SNMP::OCTET_STRING, $alias ] );
return ( defined($result) );
}
=item getManagedIfIndexes - get the list of ifIndexes which are managed
=cut
sub getManagedIfIndexes {
my $this = shift;
my $logger = Log::Log4perl::get_logger( ref($this) );
my @managedIfIndexes;
my @tmp_managedIfIndexes;
my $ifTypeHashRef;
my $ifOperStatusHashRef;
my $vlanHashRef;
my $OID_ifType = '1.3.6.1.2.1.2.2.1.3';
my $OID_ifOperStatus = '1.3.6.1.2.1.2.2.1.8';
my @UpLinks = $this->getUpLinks(); # fetch the UpLink list
if ( !$this->connectRead() ) {
return @managedIfIndexes;
}
# fetch all ifType at once
$logger->trace("SNMP get_request for ifType: $OID_ifType");
my $result = $this->{_sessionRead}->get_table( -baseoid => $OID_ifType );
foreach my $key ( keys %{$result} ) {
$key =~ /^$OID_ifType\.(\d+)$/;
$ifTypeHashRef->{$1} = $result->{$key};
}
# fetch all ifOperStatus at once
$logger->trace("SNMP get_request for ifOperStatus: $OID_ifOperStatus");
$result
= $this->{_sessionRead}->get_table( -baseoid => $OID_ifOperStatus );
foreach my $key ( keys %{$result} ) {
$key =~ /^$OID_ifOperStatus\.(\d+)$/;
$ifOperStatusHashRef->{$1} = $result->{$key};
}
foreach my $ifIndex ( keys %{$ifTypeHashRef} ) {
# skip non ethernetCsmacd port type
if ( $ifTypeHashRef->{$ifIndex} == $SNMP::ETHERNET_CSMACD ) {
# skip UpLinks
if ( grep( { $_ == $ifIndex } @UpLinks ) == 0 ) {
my $ifOperStatus = $ifOperStatusHashRef->{$ifIndex};
# skip ports with ifOperStatus not present
if ( ( defined $ifOperStatus )
&& ( $ifOperStatusHashRef->{$ifIndex} != $SNMP::NOT_PRESENT ) )
{
push @tmp_managedIfIndexes, $ifIndex;
} else {
$logger->debug(
"ifIndex $ifIndex excluded from managed ifIndexes since its ifOperstatus is 6 (notPresent)"
);
}
} else {
$logger->debug(
"ifIndex $ifIndex excluded from managed ifIndexes since it's an uplink"
);
}
} else {
$logger->debug(
"ifIndex $ifIndex excluded from managed ifIndexes since it's not an ethernetCsmacd port"
);
}
}
$vlanHashRef = $this->getAllVlans(@tmp_managedIfIndexes);
foreach my $ifIndex (@tmp_managedIfIndexes) {
my $portVlan = $vlanHashRef->{$ifIndex};
if ( defined $portVlan ) { # skip port with no VLAN
if ( grep( { $_ == $portVlan } @{ $this->{_vlans} } ) != 0 )
{ # skip port in a non-managed VLAN
push @managedIfIndexes, $ifIndex;
} else {
$logger->debug(
"ifIndex $ifIndex excluded from managed ifIndexes since it's not in a managed VLAN"
);
}
} else {
$logger->debug(
"ifIndex $ifIndex excluded from managed ifIndexes since no VLAN could be determined"
);
}
}
return @managedIfIndexes;
}
=item isManagedVlan - is the VLAN in the list of VLANs managed by the switch?
=cut
sub isManagedVlan {
my ($this, $vlan) = @_;
# can I find $vlan in _vlans ?
if (grep({$_ == $vlan} @{$this->{_vlans}}) == 0) {
#unmanaged VLAN
return 0;
}
return 1;
}
=item getMode - get the mode
=cut
sub getMode {
my ($this) = @_;
return $this->{_mode};
}
=item isTestingMode - return True if $switch-E<gt>{_mode} eq 'testing'
=cut
sub isTestingMode {
my ($this) = @_;
return ( $this->getMode() eq 'testing' );
}
=item isIgnoreMode - return True if $switch-E<gt>{_mode} eq 'ignore'
=cut
sub isIgnoreMode {
my ($this) = @_;
return ( $this->getMode() eq 'ignore' );
}
=item isRegistrationMode - return True if $switch-E<gt>{_mode} eq 'registration'
=cut
sub isRegistrationMode {
my ($this) = @_;
return ( $this->getMode() eq 'registration' );
}
=item isProductionMode - return True if $switch-E<gt>{_mode} eq 'production'
=cut
sub isProductionMode {
my ($this) = @_;
return ( $this->getMode() eq 'production' );
}
=item isDiscoveryMode - return True if $switch-E<gt>{_mode} eq 'discovery'
=cut