Add a general analyzer for postfix generics

CHANGELOG.md

@@ -3,7 +3,8 @@
 ## Unreleased
 
 ### Changed
-* Reworks `ReplaceOptionGetWithGracefulHandlingAnalyzer` to handle ValueOption's and `.Value` member access. 
+* Reworks `ReplaceOptionGetWithGracefulHandlingAnalyzer` to handle ValueOption's and `.Value` member access. [#33](https://github.com/ionide/ionide-analyzers/pull/33) 
+* Reworks `SquareBracketArrayAnalyzer` to handle all generic types that should be postfixed. [#39](https://github.com/ionide/ionide-analyzers/pull/39)
 
 ## 0.4.0 - 2023-11-15
 

docs/style/002.md

@@ -1,19 +1,24 @@
 ---
-title: SquareBracketArrayAnalyzer
+title: PostfixGenericsAnalyzer
 category: style
 categoryindex: 3
 index: 1
 ---
 
-# SquareBracketArrayAnalyzer
+# PostfixGenericsAnalyzer
 
 ## Problem
 
-Using the older array type syntax (`string[]`) is discouraged by the [style guide](https://learn.microsoft.com/en-us/dotnet/fsharp/style-guide/formatting#for-types-prefer-prefix-syntax-for-generics-foot-with-some-specific-exceptions).
+Generally, the .NET style should be used for generics. However, it is suggested to use the postfix syntax for arrays, lists, sequences, options, value options, and reference cells in the F# [style guide](https://learn.microsoft.com/en-us/dotnet/fsharp/style-guide/formatting#for-types-prefer-prefix-syntax-for-generics-foot-with-some-specific-exceptions).
 
 ```fsharp
 // Triggers analyzer
 let a: string[] = Array.empty
+let b: list<string> = List.empty
+let c: seq<string> = Seq.empty
+let d: option<string> = None
+let e: voption<string> = ValueNone
+let f: ref<string> = ref ""
 ```
 
 ## Fix
@@ -22,4 +27,9 @@ The `postfix` syntax is preferred:
 
 ```fsharp
 let a: string array = Array.empty
+let b: string list = List.empty
+let c: string seq = Seq.empty
+let d: string option = None
+let e: string voption = ValueNone
+let f: string ref = ref ""
 ```

src/Ionide.Analyzers/Ionide.Analyzers.fsproj

@@ -18,7 +18,7 @@
         <Compile Include="Suggestion\UnnamedDiscriminatedUnionFieldAnalyzer.fs"/>
         <Compile Include="Suggestion\EmptyStringAnalyzer.fs"/>
         <Compile Include="Suggestion\HandleOptionGracefullyAnalyzer.fs"/>
-        <Compile Include="Style\SquareBracketArrayAnalyzer.fs"/>
+        <Compile Include="Style\PostfixGenericsAnalyzer.fs"/>
     </ItemGroup>
 
     <ItemGroup Condition="'$(UseLocalAnalyzersSDK)' == 'true'">

src/Ionide.Analyzers/Style/PostfixGenericsAnalyzer.fs

@@ -0,0 +1,52 @@
+module Ionide.Analyzers.Style.PostfixGenericsAnalyzer
+
+open FSharp.Compiler.Text
+open FSharp.Compiler.Syntax
+open FSharp.Analyzers.SDK
+open FSharp.Analyzers.SDK.ASTCollecting
+
+[<CliAnalyzer("PostfixGenericsAnalyzer",
+              "Detect if generic type should be in the postfix position.",
+              "https://ionide.io/ionide-analyzers/style/002.html")>]
+let postfixGenericsAnalyzer: Analyzer<CliContext> =
+    fun (context: CliContext) ->
+        async {
+            let ts = ResizeArray<string * range>()
+
+            let collector =
+                { new SyntaxCollectorBase() with
+                    override x.WalkType(t: SynType) =
+                        match t with
+                        | SynType.Array _ -> ts.Add("Prefer postfix syntax for arrays.", t.Range)
+                        | SynType.App(typeName = SynType.LongIdent synLongIdent; isPostfix = false) ->
+                            match synLongIdent.LongIdent with
+                            | [ ident ] ->
+                                match ident.idText with
+                                | "array" -> ts.Add("Prefer postfix syntax for arrays.", t.Range)
+                                | "seq" -> ts.Add("Prefer postfix syntax for sequences.", t.Range)
+                                | "list" -> ts.Add("Prefer postfix syntax for lists.", t.Range)
+                                | "option" -> ts.Add("Prefer postfix syntax for options.", t.Range)
+                                | "voption" -> ts.Add("Prefer postfix syntax for value options.", t.Range)
+                                | "Ref"
+                                | "ref" -> ts.Add("Prefer postfix syntax for reference cells.", t.Range)
+                                | _ -> ()
+                            | _ -> ()
+                        | _ -> ()
+                }
+
+            walkAst collector context.ParseFileResults.ParseTree
+
+            return
+                ts
+                |> Seq.map (fun (message, range) ->
+                    {
+                        Type = "PostfixGenericsAnalyzer"
+                        Message = message
+                        Code = "IONIDE-002"
+                        Severity = Info
+                        Range = range
+                        Fixes = []
+                    }
+                )
+                |> Seq.toList
+        }

tests/Ionide.Analyzers.Tests/Ionide.Analyzers.Tests.fsproj

@@ -14,7 +14,7 @@
     <Compile Include="Suggestion\UnnamedDiscriminatedUnionFieldAnalyzerTests.fs" />
     <Compile Include="Suggestion\EmptyStringAnalyzerTests.fs" />
     <Compile Include="Suggestion\HandleOptionGracefullyAnalyzerTests.fs" />
-    <Compile Include="Style\SquareBracketArrayAnalyzerTests.fs" />
+    <Compile Include="Style\PostfixGenericsAnalyzerTests.fs" />
     <Compile Include="Program.fs" />
   </ItemGroup>