C standard library headers aren't available while building dependencies with C bindings

[monadix]

Describe the bug
Cannot build project, that depends on raylib bindings. Headers from C standard library are not available.

error message:

binding/../raylib/src/raylib.h:82:10: fatal error: 'stdarg.h' file not found
  thread 'main' panicked at /nix/store/fxbyqsaqw8f329i6ypw1f3xhvvga24k7-vendor-cargo-deps/c19b7c6f923b580ac259164a89f2577984ad5ab09ee9d583b888f934adbbe8d0/raylib-sys-5.0.0/build.rs:211:39:
  Unable to generate bindings: ClangDiagnostic("binding/../raylib/src/raylib.h:82:10: fatal error: 'stdarg.h' file not found

Reproduction
flake.nix

{
  description = "flake, that doesn't work";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    flake-utils.url = "github:numtide/flake-utils";

    crane = {
      url = "github:ipetkov/crane";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-utils.follows = "flake-utils";
      };
    };
  };

  outputs = { self, nixpkgs, flake-utils, crane, rust-overlay }: 
    flake-utils.lib.eachDefaultSystem (system:
    let
      pkgs = import nixpkgs {
        inherit system;
        overlays = [ 
          (import rust-overlay)
        ];
      };

      rustToolchain = pkgs.rust-bin.stable.latest.default;

      craneLib = (crane.mkLib pkgs).overrideToolchain rustToolchain;

      src = craneLib.cleanCargoSource (craneLib.path ./.);

      commonArgs = {
        inherit src;
        
        strictDeps = true;

        cargoVendorDir = craneLib.vendorMultipleCargoDeps {
          inherit (craneLib.findCargoFiles src) cargoConfigs;
          cargoLockList = [
            ./Cargo.lock
            "${rustToolchain.passthru.availableComponents.rust-src}/lib/rustlib/src/rust/Cargo.lock"
          ];
        };

        LIBCLANG_PATH="${pkgs.libclang.lib}/lib";

        buildInputs = with pkgs; [
          libGL
          xorg.libX11
          xorg.libXinerama
          xorg.libXcursor
          xorg.libXi
          xorg.libXrandr
        ];

        nativeBuildInputs = with pkgs; [
          cmake 
        ];
      };

      mainCrate = craneLib.buildPackage (
        commonArgs // { cargoArtifacts = craneLib.buildDepsOnly commonArgs; }
      );
    in 
    {
      checks = {
        inherit mainCrate;
      };

      packages.default = mainCrate;
      
      devShells = {
        default = craneLib.devShell {
          checks = self.checks.${system};
          packages = with pkgs; [
          ];
        };
      };
    });
}

and
raylib = { version = "5.0" }
in Cargo.toml

[ipetkov]

Hi @Chell4 ! If your derivation requires building with clang you can set stdenv = pkgs.clangStdenv; in commonArgs which appears to build fine for me. Hope this helps!

[monadix]

Thank you, it builds, but now it can't find Xlib at runtime. I just copied example from README of raylib-rs on github:

use raylib::prelude::*;

fn main() {
    let (mut rl, thread) = raylib::init()
        .size(640, 480)
        .title("Hello, World")
        .build();

    while !rl.window_should_close() {
        let mut d = rl.begin_drawing(&thread);

        d.clear_background(Color::WHITE);
        d.draw_text("Hello, world!", 12, 12, 20, Color::BLACK);
    }
}

It builds fine, but when I try to run it, i get this output:

INFO: Initializing raylib 5.0
INFO: Platform backend: DESKTOP (GLFW)
INFO: Supported raylib modules:
INFO:     > rcore:..... loaded (mandatory)
INFO:     > rlgl:...... loaded (mandatory)
INFO:     > rshapes:... loaded (optional)
INFO:     > rtextures:. loaded (optional)
INFO:     > rtext:..... loaded (optional)
INFO:     > rmodels:... loaded (optional)
INFO:     > raudio:.... loaded (optional)
WARNING: GLFW: Error: 65544 Description: X11: Failed to load Xlib
WARNING: GLFW: Failed to initialize GLFW

This happens even if I enter dev shell with all the same packages and explicitly set LD_LIBRARY_PATH (also using all the same packages with lib.makeLibraryPath)

Why can't it find Xlib?

[monadix]

Read other discussions and realized I need this to make libraries available at runtime

postInstall = ''
  wrapProgram $out/bin/${pname} \
  --prefix LD_LIBRARY_PATH : ${pkgs.lib.makeLibraryPath commonArgs.buildInputs}
'';

doesn't it make sense to make it default behavior, because buildInputs represent runtime dependencies of the package?

[ipetkov]

It's difficult to apply something like this as "default behavior" because it's not always clear how to get it right. There are many projects which use static linking and don't need their binary wrapped. Other projects might have multiple binaries and some might want wrapping while others don't.

In general crane tries to focus on vendoring cargo dependencies and minimize all other magic/default configuration as to avoid surprises for the project maintainer