-
Notifications
You must be signed in to change notification settings - Fork 0
/
Asociatividad_de_la_concatenacion_de_listas.thy
93 lines (83 loc) · 2.8 KB
/
Asociatividad_de_la_concatenacion_de_listas.thy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
(* Asociatividad_de_la_concatenacion_de_listas.thy
-- Asociatividad de la concatenación de listas
-- José A. Alonso Jiménez
-- Sevilla, 8 de septiembre de 2021
-- ------------------------------------------------------------------ *)
(* ---------------------------------------------------------------------
-- En Isabelle/HOL la operación de concatenación de listas se representa
-- por (@) y está caracterizada por los siguientes lemas
-- append_Nil : [] @ ys = ys
-- append_Cons : (x # xs) @ y = x # (xs @ ys)
--
-- Demostrar que la concatenación es asociativa; es decir,
-- xs @ (ys @ zs) = (xs @ ys) @ zs
-- ------------------------------------------------------------------ *)
theory Asociatividad_de_la_concatenacion_de_listas
imports Main
begin
(* 1\<ordfeminine> demostración *)
lemma "xs @ (ys @ zs) = (xs @ ys) @ zs"
proof (induct xs)
have "[] @ (ys @ zs) = ys @ zs"
by (simp only: append_Nil)
also have "\<dots> = ([] @ ys) @ zs"
by (simp only: append_Nil)
finally show "[] @ (ys @ zs) = ([] @ ys) @ zs"
by this
next
fix x xs
assume HI : "xs @ (ys @ zs) = (xs @ ys) @ zs"
have "(x # xs) @ (ys @ zs) = x # (xs @ (ys @ zs))"
by (simp only: append_Cons)
also have "\<dots> = x # ((xs @ ys) @ zs)"
by (simp only: HI)
also have "\<dots> = (x # (xs @ ys)) @ zs"
by (simp only: append_Cons)
also have "\<dots> = ((x # xs) @ ys) @ zs"
by (simp only: append_Cons)
finally show "(x # xs) @ (ys @ zs) = ((x # xs) @ ys) @ zs"
by this
qed
(* 2\<ordfeminine> demostración *)
lemma "xs @ (ys @ zs) = (xs @ ys) @ zs"
proof (induct xs)
have "[] @ (ys @ zs) = ys @ zs" by simp
also have "\<dots> = ([] @ ys) @ zs" by simp
finally show "[] @ (ys @ zs) = ([] @ ys) @ zs" .
next
fix x xs
assume HI : "xs @ (ys @ zs) = (xs @ ys) @ zs"
have "(x # xs) @ (ys @ zs) = x # (xs @ (ys @ zs))" by simp
also have "\<dots> = x # ((xs @ ys) @ zs)" by simp
also have "\<dots> = (x # (xs @ ys)) @ zs" by simp
also have "\<dots> = ((x # xs) @ ys) @ zs" by simp
finally show "(x # xs) @ (ys @ zs) = ((x # xs) @ ys) @ zs" .
qed
(* 3\<ordfeminine> demostración *)
lemma "xs @ (ys @ zs) = (xs @ ys) @ zs"
proof (induct xs)
show "[] @ (ys @ zs) = ([] @ ys) @ zs" by simp
next
fix x xs
assume "xs @ (ys @ zs) = (xs @ ys) @ zs"
then show "(x # xs) @ (ys @ zs) = ((x # xs) @ ys) @ zs" by simp
qed
(* 4\<ordfeminine> demostración *)
lemma "xs @ (ys @ zs) = (xs @ ys) @ zs"
proof (induct xs)
case Nil
then show ?case by simp
next
case (Cons a xs)
then show ?case by simp
qed
(* 5\<ordfeminine> demostración *)
lemma "xs @ (ys @ zs) = (xs @ ys) @ zs"
by (rule append_assoc [symmetric])
(* 6\<ordfeminine> demostración *)
lemma "xs @ (ys @ zs) = (xs @ ys) @ zs"
by (induct xs) simp_all
(* 7\<ordfeminine> demostración *)
lemma "xs @ (ys @ zs) = (xs @ ys) @ zs"
by simp
end