-
Notifications
You must be signed in to change notification settings - Fork 66
/
TransitiveDependencyUnavailableOnRemovingServiceTestCase.btm
104 lines (98 loc) · 4.4 KB
/
TransitiveDependencyUnavailableOnRemovingServiceTestCase.btm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
#
# JBoss, Home of Professional Open Source.
# Copyright 2012, Red Hat, Inc., and individual contributors
# as indicated by the @author tags. See the copyright.txt file in the
# distribution for a full listing of individual contributors.
#
# This is free software; you can redistribute it and/or modify it
# under the terms of the GNU Lesser General Public License as
# published by the Free Software Foundation; either version 2.1 of
# the License, or (at your option) any later version.
#
# This software is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
# Lesser General Public License for more details.
#
# You should have received a copy of the GNU Lesser General Public
# License along with this software; if not, write to the Free
# Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA
# 02110-1301 USA, or see the FSF site: http://www.fsf.org.
#
RULE service D on REMOVE mode
CLASS org.jboss.msc.service.ServiceControllerImpl
METHOD setMode
AT ENTRY
BIND serviceName = $0.primaryRegistration.name.getSimpleName();
IF serviceName.equals("D") AND $1.toString().equals("REMOVE")
DO
debug("flagging service D on REMOVE mode"),
flag("service D on REMOVE mode")
ENDRULE
RULE before ServiceControllerImpl.transitiveDependencyUnavailable
CLASS org.jboss.msc.service.ServiceControllerImpl
METHOD transitiveDependencyUnavailable
AT ENTRY
BIND serviceName = $0.primaryRegistration.name.getSimpleName();
IF flagged("service D on REMOVE mode") AND serviceName.equals("B") AND incrementCounter("run once before ServiceControllerImpl.transitiveDependencyUnavailable") == 1
DO
debug("wait for service enter REMOVING state: " + $0),
waitFor("service REMOVING", 10000),
debug("proceed with transitiveDependencyUnavailable")
ENDRULE
RULE after ServiceControllerImpl.transitiveDependencyUnavailable
CLASS org.jboss.msc.service.ServiceControllerImpl
METHOD transitiveDependencyUnavailable
AT EXIT
BIND serviceName = $0.primaryRegistration.name.getSimpleName();
IF flagged("service D on REMOVE mode") AND serviceName.equals("B") AND incrementCounter("run once after ServiceControllerImpl.transitiveDependencyUnavailable") == 1
DO
debug("finished transitiveDependencyUnavailable on service " + $0),
signalWake("transitiveDependencyUnavailable notified", true)
ENDRULE
RULE service B REMOVING
CLASS org.jboss.msc.service.ServiceControllerImpl
METHOD doExecute
AT ENTRY
BIND serviceName = $0.primaryRegistration.name.getSimpleName()
IF flagged("service D on REMOVE mode") AND $0.state.toString().equals("REMOVING") AND serviceName.equals("B") AND incrementCounter("run once service B REMOVING") == 1
DO
debug("signaling transitiveDependencyUnavailable" + $0),
signalWake("service REMOVING", true),
waitFor("transitiveDependencyUnavailable notified"),
debug("signaled transitiveDependencyUnavailable")
ENDRULE
RULE prevent deadlock with UndemandDependenciesTask - I
CLASS org.jboss.msc.service.ServiceRegistrationImpl
METHOD removeDemand
AT EXIT
IF flagged("service D on REMOVE mode") AND $0.name.getSimpleName().equals("C") AND incrementCounter("run once prevent deadlock I") == 1
DO
debug("unlocking C.immediateDepedencyUnavailable thread"),
flag("service C undemanded"),
signalWake("service C undemanded")
ENDRULE
RULE prevent deadlock with UndemandDependenciesTask - II
CLASS org.jboss.msc.service.ServiceControllerImpl
METHOD immediateDependencyUnavailable
AT ENTRY
IF !flagged ("service C undemanded") AND flagged("service D on REMOVE mode") AND $0.primaryRegistration.name.getSimpleName().equals("C") AND incrementCounter("run once prevent deadlock II") == 1
DO
debug("waiting for service c to be undemanded before proceeding with service C immediateDependencyUnavailable - to avoid a deadlock"),
waitFor("service C undemanded", 1000)
ENDRULE
RULE clear counters and flags
CLASS org.jboss.msc.service.AbstractServiceTest
METHOD tearDown
AT EXIT
IF TRUE
DO
debug("clearing counters and flags"),
clear("service D on REMOVE mode"),
clear("service C undemanded"),
deleteCounter("run once before ServiceControllerImpl.transitiveDependencyUnavailable"),
deleteCounter("run once after ServiceControllerImpl.transitiveDependencyUnavailable"),
deleteCounter("run once service B REMOVING"),
deleteCounter("run once prevent deadlock I"),
deleteCounter("run once prevent deadlock II")
ENDRULE