-
Notifications
You must be signed in to change notification settings - Fork 5
/
vhd-btlck.bat
89 lines (72 loc) · 1.57 KB
/
vhd-btlck.bat
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
@echo off
setlocal
rem vhd-btlck.bat
rem -John Taylor
rem Dec-13-2015
rem
rem Mount and unmount a bitlocker encrypted VHD file as a drive letter
rem Modify VDISK and VHDDRIVE accordingly
rem
rem How to create a 4 GB VHD
rem ------------------------
rem create vdisk file="C:\example.vhd" maximum=4096
rem attach vdisk
rem create partition primary
rem assign letter=v
rem
rem then use one of the following...
rem
rem format label="Example VHD"
rem format label="Example VHD" QUICK
rem format fs=FAT32 label="Example VHD" QUICK
rem
rem
rem How to encrypt a VHD
rem --------------------
rem manage-bde.exe -protectors -add -pw v:
rem
rem -----------------------------------------------------------------
set VDISK="C:\example.vhd"
set VHDDRIVE=v:
set TMPFILE=%TEMP%\dpart.%RANDOM%.%RANDOM%.tmp
set OP=%1
if not defined OP goto USAGE
net session > nul 2>&1
IF %ERRORLEVEL% NEQ 0 (
@echo.
@echo You did not "Run as Administrator"
@echo.
goto END
)
if "%OP%"=="mount" (
if exist %VHDDRIVE%\nul (
@echo.
@echo Drive already mounted: %VHDDRIVE%
@echo.
goto END
)
@echo select vdisk file=%VDISK%>> %TMPFILE%
@echo attach vdisk >> %TMPFILE%
diskpart.exe /s %TMPFILE%
del %TMPFILE%
:BITLOCK
manage-bde.exe -unlock %VHDDRIVE% -password
if not exist %VHDDRIVE%\nul goto BITLOCK
goto END
)
if "%OP%"=="unmount" (
manage-bde.exe -lock %VHDDRIVE%
@echo.
@echo select vdisk file=%VDISK% >> %TMPFILE%
@echo detach vdisk >> %TMPFILE%
diskpart.exe /s %TMPFILE%
del %TMPFILE%
goto END
)
:USAGE
@echo.
@echo %~n0%~x0 [ mount ^| unmount ]
@echo.
goto END
:END
endlocal