-
Notifications
You must be signed in to change notification settings - Fork 1
/
loader.s
1949 lines (1778 loc) · 58.2 KB
/
loader.s
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;-------------------------------------------------------------------------------
; COVERT BITOPS Autoconfiguring Loader/Depacker V2.25
; with 1541/1571/1581/CMD FD/CMD HD/IDE64/Fastdrive-emu autodetection & support
;
; EXOMIZER 2 depack by Magnus Lind & Krill
; PUCRUNCH depack by Pasi Ojala
; 1581/CMD FD/CMD HD information from Ninja & DocBacardi /The Dreams
; 2MHz 2-bit transfer delay code by MagerValp
; Rest by Lasse Öörni
;
; Thanks to K.M/TABOO for inspiration on badline detection and 1-bit transfer,
; and Marko Mäkelä for his original irqloader.s (huge inspiration)
;-------------------------------------------------------------------------------
.define processor 6502
.export initloader
.export getbyte
.export openfile
.export loadfile
.segment "CODE"
;-------------------------------------------------------------------------------
; Include your loader configuration file at this point!
;-------------------------------------------------------------------------------
.include "cfg_2bit.s"
;-------------------------------------------------------------------------------
; Defines derived from the compile options (need not be changed)
;-------------------------------------------------------------------------------
.if ADDITIONAL_ZEROPAGE>0
loadtempreg = zpbase2+0 ;Temp variables for the loader
bufferstatus = zpbase2+1 ;Bytes in fastload buffer
fileopen = zpbase2+2 ;File open indicator
fastloadstatus = zpbase2+3 ;Fastloader active indicator
.endif
destlo = zpbase+0
desthi = zpbase+1
;-------------------------------------------------------------------------------
; Other defines
;-------------------------------------------------------------------------------
MW_LENGTH = 32 ;Bytes in one M-W command
status = $90 ;Kernal zeropage variables
messages = $9d
fa = $ba
acsbf = $01 ;Diskdrive variables: Buffer 1 command
trkbf = $08 ;Buffer 1 track
sctbf = $09 ;Buffer 1 sector
iddrv0 = $12 ;Disk drive ID
drvtemp = $06 ;Temp variable
id = $16 ;Disk ID
buf = $0400 ;Sector data buffer
drvstart = $0500 ;Start of drivecode
initialize = $d005 ;Initialize routine in 1541 ROM
ciout = $ffa8 ;Kernal routines
listen = $ffb1
second = $ff93
unlsn = $ffae
talk = $ffb4
tksa = $ff96
untlk = $ffab
acptr = $ffa5
chkin = $ffc6
chkout = $ffc9
chrin = $ffcf
chrout = $ffd2
close = $ffc3
open = $ffc0
setmsg = $ff90
setnam = $ffbd
setlfs = $ffba
clrchn = $ffcc
getin = $ffe4
load = $ffd5
save = $ffd8
;-------------------------------------------------------------------------------
; Resident portion of loader (routines that you're going to use at runtime)
;-------------------------------------------------------------------------------
.if LOADFILE_UNPACKED>0
;-------------------------------------------------------------------------------
; LOADFILE
;
; Loads an unpacked file
;
; Parameters: X (low),Y (high): Address of null-terminated filename
; Returns: C=0 OK, C=1 error (A holds errorcode)
; Modifies: A,X,Y
;-------------------------------------------------------------------------------
loadfile: jsr openfile
jsr getbyte ;Get startaddress lowbyte
bcs loadfile_fail ;If EOF at first byte, error
sta destlo
jsr getbyte ;Get startaddress highbyte
sta desthi
ldy #$00
loadfile_loop: jsr getbyte
bcs loadfile_eof
.if LOAD_UNDER_IO>0
jsr disableio ;Allow loading under I/O area
.endif
sta (destlo),y
.if LOAD_UNDER_IO>0
jsr enableio
.endif
iny
bne loadfile_loop
inc desthi
jmp loadfile_loop
loadfile_eof: cmp #$01 ;Returncode 0 = OK, others error
loadfile_fail: rts
.endif
.if LOADFILE_EXOMIZER>0
;-------------------------------------------------------------------------------
; LOADFILE_EXOMIZER
;
; Loads a file packed with EXOMIZERx
;
; Parameters: X (low),Y (high): Address of null-terminated filename
; Returns: C=0 OK, C=1 error (A holds errorcode)
; Modifies: A,X,Y
;-------------------------------------------------------------------------------
tabl_bi = depackbuffer
tabl_lo = depackbuffer+52
tabl_hi = depackbuffer+104
zp_len_lo = zpbase+0
zp_src_lo = zpbase+1
zp_src_hi = zpbase+2
zp_bits_lo = zpbase+3
zp_bits_hi = zpbase+4
zp_bitbuf = zpbase+5
zp_dest_lo = zpbase+6
zp_dest_hi = zpbase+7
loadfile_exomizer:
jsr openfile
tsx
stx exomizer_stackptr+1
; -------------------------------------------------------------------
; This source code is altered and is not the original version found on
; the Exomizer homepage.
; It contains modifications made by Krill/Plush to depack a packed file
; crunched forward and to work with his loader.
;
; Further modification (error handling, loading under IO area) &
; bugfixing of the forward decruncher by Lasse Öörni
; -------------------------------------------------------------------
;
; Copyright (c) 2002 - 2005 Magnus Lind.
;
; This software is provided 'as-is', without any express or implied warranty.
; In no event will the authors be held liable for any damages arising from
; the use of this software.
;
; Permission is granted to anyone to use this software for any purpose,
; including commercial applications, and to alter it and redistribute it
; freely, subject to the following restrictions:
;
; 1. The origin of this software must not be misrepresented; you must not
; claim that you wrote the original software. If you use this software in a
; product, an acknowledgment in the product documentation would be
; appreciated but is not required.
;
; 2. Altered source versions must be plainly marked as such, and must not
; be misrepresented as being the original software.
;
; 3. This notice may not be removed or altered from any distribution.
;
; 4. The names of this software and/or it's copyright holders may not be
; used to endorse or promote products derived from this software without
; specific prior written permission.
;
; -------------------------------------------------------------------
; no code below this comment has to be modified in order to generate
; a working decruncher of this source file.
; However, you may want to relocate the tables last in the file to a
; more suitable address.
; -------------------------------------------------------------------
; -------------------------------------------------------------------
; jsr this label to decrunch, it will in turn init the tables and
; call the decruncher
; no constraints on register content, however the
; decimal flag has to be #0 (it almost always is, otherwise do a cld)
exomizer:
.if FORWARD_DECRUNCHING>0
; -------------------------------------------------------------------
; init zeropage, x and y regs.
;
ldx #3
ldy #0
init_zp:
jsr getbyte
bcs exomizer_error
sta zp_bitbuf-1,x
dex
bne init_zp
; -------------------------------------------------------------------
; calculate tables (50 bytes)
; x and y must be #0 when entering
;
nextone:
inx
tya
and #$0f
beq shortcut ; start with new sequence
txa ; this clears reg a
lsr ; and sets the carry flag
ldx tabl_bi-1,y
rolle:
rol
rol zp_bits_hi
dex
bpl rolle ; c = 0 after this (rol zp_bits_hi)
adc tabl_lo-1,y
tax
lda zp_bits_hi
adc tabl_hi-1,y
shortcut:
sta tabl_hi,y
txa
sta tabl_lo,y
ldx #4
jsr get_bits ; clears x-reg.
sta tabl_bi,y
iny
cpy #52
bne nextone
beq begin
; -------------------------------------------------------------------
; get bits (29 bytes)
;
; args:
; x = number of bits to get
; returns:
; a = #bits_lo
; x = #0
; c = 0
; z = 1
; zp_bits_hi = #bits_hi
; notes:
; y is untouched
; -------------------------------------------------------------------
get_bits:
lda #$00
sta zp_bits_hi
cpx #$01
bcc bits_done
bits_next:
lsr zp_bitbuf
bne bits_ok
pha
jsr getbyte
bcs exomizer_error
sec
ror
sta zp_bitbuf
pla
bits_ok:
rol
rol zp_bits_hi
dex
bne bits_next
bits_done:
rts
exomizer_ok:
clc
exomizer_error:
exomizer_stackptr:
ldx #$ff
txs
rts
; -------------------------------------------------------------------
; literal sequence handling
;
.if LITERAL_SEQUENCES_NOT_USED=0
literal_start:
ldx #$10 ; these 16 bits
jsr get_bits; tell the length of the sequence
ldx zp_bits_hi
.endif
literal_start1: ; if literal byte, a = 1, zp_bits_hi = 0
sta zp_len_lo
; -------------------------------------------------------------------
; main copy loop
; x = length hi
; y = length lo
;
copy_start:
ldy #$00
copy_next:
bcs copy_noliteral
jsr getbyte
bcs exomizer_error
copy_noliteral:
.if LOAD_UNDER_IO>0
jsr disableio
.endif
bcc copy_store
lda (zp_src_lo),y
copy_store:
sta (zp_dest_lo),y
.if LOAD_UNDER_IO>0
jsr enableio
.endif
iny
bne copy_skiphi
dex
inc zp_dest_hi
inc zp_src_hi
copy_skiphi:
tya
eor zp_len_lo
bne copy_next
txa
bne copy_next
tya
clc
adc zp_dest_lo
sta zp_dest_lo
bcc copy_skiphi2
inc zp_dest_hi
copy_skiphi2:
; -------------------------------------------------------------------
; decruncher entry point, needs calculated tables (21(13) bytes)
; x and y must be #0 when entering
;
begin:
inx
jsr get_bits
tay
bne literal_start1; if bit set, get a literal byte
getgamma:
inx
jsr bits_next
lsr
iny
bcc getgamma
cpy #$11
beq exomizer_ok ; gamma = 17 : end of file
.if LITERAL_SEQUENCES_NOT_USED=0
bcs literal_start ; gamma = 18 : literal sequence
.endif
; gamma = 1..16: sequence
; -------------------------------------------------------------------
; calulate length of sequence (zp_len) (11 bytes)
;
ldx tabl_bi-1,y
jsr get_bits
adc tabl_lo-1,y ; we have now calculated zp_len_lo
sta zp_len_lo
; -------------------------------------------------------------------
; now do the hibyte of the sequence length calculation (6 bytes)
lda zp_bits_hi
adc tabl_hi-1,y ; c = 0 after this.
pha
; -------------------------------------------------------------------
; here we decide what offset table to use (20 bytes)
; x is 0 here
;
bne nots123
ldy zp_len_lo
cpy #$04
bcc size123
nots123:
ldy #$03
size123:
ldx tabl_bit-1,y
jsr get_bits
adc tabl_off-1,y ; c = 0 after this.
tay ; 1 <= y <= 52 here
; -------------------------------------------------------------------
; calulate absolute offset (zp_src)
;
ldx tabl_bi,y
jsr get_bits
adc tabl_lo,y
bcc skipcarry
inc zp_bits_hi
skipcarry:
sec
eor #$ff
adc zp_dest_lo
sta zp_src_lo
lda zp_dest_hi
sbc zp_bits_hi
sbc tabl_hi,y
sta zp_src_hi
; -------------------------------------------------------------------
; prepare for copy loop (8(6) bytes)
;
pla
tax
sec
jmp copy_start
.else
; -------------------------------------------------------------------
; init zeropage, x and y regs. (12 bytes)
;
ldy #0
ldx #3
init_zp:
jsr getbyte
bcs exomizer_error
sta zp_bitbuf-1,x
dex
bne init_zp
; -------------------------------------------------------------------
; calculate tables (50 bytes)
; x and y must be #0 when entering
;
nextone:
inx
tya
and #$0f
beq shortcut ; starta på ny sekvens
txa ; this clears reg a
lsr ; and sets the carry flag
ldx tabl_bi-1,y
rolle:
rol
rol zp_bits_hi
dex
bpl rolle ; c = 0 after this (rol zp_bits_hi)
adc tabl_lo-1,y
tax
lda zp_bits_hi
adc tabl_hi-1,y
shortcut:
sta tabl_hi,y
txa
sta tabl_lo,y
ldx #4
jsr get_bits ; clears x-reg.
sta tabl_bi,y
iny
cpy #52
bne nextone
ldy #0
beq begin
; -------------------------------------------------------------------
; get bits (29 bytes)
;
; args:
; x = number of bits to get
; returns:
; a = #bits_lo
; x = #0
; c = 0
; z = 1
; zp_bits_hi = #bits_hi
; notes:
; y is untouched
; -------------------------------------------------------------------
get_bits:
lda #$00
sta zp_bits_hi
cpx #$01
bcc bits_done
bits_next:
lsr zp_bitbuf
bne bits_ok
pha
literal_get_byte:
php
jsr getbyte
bcs exomizer_error
plp
bcc literal_byte_gotten
ror
sta zp_bitbuf
pla
bits_ok:
rol
rol zp_bits_hi
dex
bne bits_next
bits_done:
rts
exomizer_ok:
clc
exomizer_error:
exomizer_stackptr:
ldx #$ff
txs
rts
; -------------------------------------------------------------------
; main copy loop (18(16) bytes)
;
copy_next_hi:
dex
dec zp_dest_hi
dec zp_src_hi
copy_next:
dey
.if LITERAL_SEQUENCES_NOT_USED = 0
bcc literal_get_byte
.endif
literal_byte_gotten:
.if LOAD_UNDER_IO>0
jsr disableio
.endif
bcc copy_store
lda (zp_src_lo),y
copy_store:
sta (zp_dest_lo),y
.if LOAD_UNDER_IO>0
jsr enableio
.endif
copy_start:
tya
bne copy_next
begin:
txa
bne copy_next_hi
; -------------------------------------------------------------------
; decruncher entry point, needs calculated tables (21(13) bytes)
; x and y must be #0 when entering
;
.if LITERAL_SEQUENCES_NOT_USED = 0
inx
jsr get_bits
tay
bne literal_start1
.else
dey
.endif
begin2:
inx
jsr bits_next
lsr
iny
bcc begin2
.if LITERAL_SEQUENCES_NOT_USED > 0
beq literal_start
.endif
cpy #$11
.if LITERAL_SEQUENCES_NOT_USED = 0
bcc sequence_start
beq exomizer_ok
; -------------------------------------------------------------------
; literal sequence handling (13(2) bytes)
;
ldx #$10
jsr get_bits
literal_start1:
sta zp_len_lo
ldx zp_bits_hi
ldy #0
bcc literal_start
sequence_start:
.else
bcs exomizer_ok
.endif
; -------------------------------------------------------------------
; calulate length of sequence (zp_len) (11 bytes)
;
ldx tabl_bi-1,y
jsr get_bits
adc tabl_lo-1,y ; we have now calculated zp_len_lo
sta zp_len_lo
; -------------------------------------------------------------------
; now do the hibyte of the sequence length calculation (6 bytes)
lda zp_bits_hi
adc tabl_hi-1,y ; c = 0 after this.
pha
; -------------------------------------------------------------------
; here we decide what offset table to use (20 bytes)
; x is 0 here
;
bne nots123
ldy zp_len_lo
cpy #$04
bcc size123
nots123:
ldy #$03
size123:
ldx tabl_bit-1,y
jsr get_bits
adc tabl_off-1,y ; c = 0 after this.
tay ; 1 <= y <= 52 here
; -------------------------------------------------------------------
; Here we do the dest_lo -= len_lo subtraction to prepare zp_dest
; but we do it backwards: a - b == (b - a - 1) ^ ~0 (C-syntax)
; (16(16) bytes)
lda zp_len_lo
literal_start:
sbc zp_dest_lo ; literal enters here with y = 0, c = 1
bcc noborrow
dec zp_dest_hi
noborrow:
eor #$ff
sta zp_dest_lo
cpy #$01 ; y < 1 then literal
.if LITERAL_SEQUENCES_NOT_USED = 0
bcc pre_copy
.else
bcc literal_get_byte
.endif
; -------------------------------------------------------------------
; calulate absolute offset (zp_src) (27 bytes)
;
ldx tabl_bi,y
jsr get_bits;
adc tabl_lo,y
bcc skipcarry
inc zp_bits_hi
clc
skipcarry:
adc zp_dest_lo
sta zp_src_lo
lda zp_bits_hi
adc tabl_hi,y
adc zp_dest_hi
sta zp_src_hi
; -------------------------------------------------------------------
; prepare for copy loop (8(6) bytes)
;
pla
tax
sec
.if LITERAL_SEQUENCES_NOT_USED = 0
pre_copy:
ldy zp_len_lo
jmp copy_start
.else
ldy zp_len_lo
bcs copy_start
.endif
.endif
; -------------------------------------------------------------------
; two small static tables (6(6) bytes)
;
tabl_bit:
.byte 2,4,4
tabl_off:
.byte 48,32,16
; -------------------------------------------------------------------
; end of decruncher
; -------------------------------------------------------------------
.endif
.if LOADFILE_PUCRUNCH>0
;-------------------------------------------------------------------------------
; LOADFILE_PUCRUNCH
;
; Loads a file packed with PUCRUNCH
;
; Parameters: X (low),Y (high): Address of null-terminated filename
; Returns: C=0 OK, C=1 error (A holds errorcode)
; Modifies: A,X,Y
;-------------------------------------------------------------------------------
lzpos = zpbase
bitstr = zpbase+2
table = depackbuffer
loadfile_pucrunch:
jsr openfile
tsx
stx pucrunch_stackptr+1
jsr getbyte ;Throw away file startaddress
jsr getbyte
;-------------------------------------------------------------------------------
; PUCRUNCH DECOMPRESSOR by Pasi Ojala
;
; SHORT+IRQLOAD 354 bytes
; no rle =~ -83 bytes -> 271
; fixed params =~ -48 bytes -> 306
; 223 bytes
; Parameters: -
; Returns: -
; Modifies: A,X,Y
;-------------------------------------------------------------------------------
ldx #5
@222: jsr getbyt ; skip 'p', 'u', endAddr HI&LO, leave starting escape in A
dex
bne @222
sta esc+1 ; starting escape
jsr getbyt ; read startAddr
sta outpos+1
jsr getbyt
sta outpos+2
jsr getbyt ; read # of escape bits
sta escB0+1
sta escB1+1
lda #8
sec
sbc escB1+1
sta noesc+1 ; 8-escBits
jsr getbyt
sta mg+1 ; maxGamma + 1
lda #9
sec
sbc mg+1 ; 8 - maxGamma == (8 + 1) - (maxGamma + 1)
sta longrle+1
jsr getbyt
sta mg1+1 ; (1<<maxGamma)
asl
clc
sbc #0
sta mg21+1 ; (2<<maxGamma) - 1
jsr getbyt
sta elzpb+1
ldx #$03
@2: jsr getbyt ; Get 3 bytes, 2 unused (exec address)
dex ; and rleUsed. X is 0 after this loop
bne @2
;jsr getbyt ; exec address
;sta lo+1 ; lo
;jsr getbyt
;sta hi+1 ; hi
;
;jsr getbyt ; rleUsed
;ldx #0
tay
sty bitstr
@0: beq @1 ; Y == 0 ?
jsr getbyt
sta table,x
inx
dey
bne @0
@1: ; setup bit store - $80 means empty
lda #$80
sta bitstr
jmp main
getbyt jsr getnew
lda bitstr
ror
rts
newesc ldy esc+1 ; remember the old code (top bits for escaped byte)
escB0 ldx #2 ; ** PARAMETER 0..8
jsr getchkf ; get & save the new escape code
sta esc+1
tya ; pre-set the bits
; Fall through and get the rest of the bits.
noesc ldx #6 ; ** PARAMETER 8..0
jsr getchkf
jsr putch ; output the escaped/normal byte
; Fall through and check the escape bits again
main ldy #0 ; Reset to a defined state
tya ; A = 0
escB1 ldx #2 ; ** PARAMETER 0..8
jsr getchkf ; X = 0
esc cmp #0
bne noesc
; Fall through to packed code
jsr getval ; X = 0
sta lzpos ; xstore - save the length for a later time
lsr ; cmp #1 ; LEN == 2 ? (A is never 0)
bne lz77 ; LEN != 2 -> LZ77
;tya ; A = 0
jsr get1bit ; X = 0
lsr ; bit -> C, A = 0
bcc lz77_2 ; A=0 -> LZPOS+1
;***FALL THRU***
; e..e01
jsr get1bit ; X = 0
lsr ; bit -> C, A = 0
bcc newesc ; e..e010
;***FALL THRU***
; e..e011
srle iny ; Y is 1 bigger than MSB loops
jsr getval ; Y is 1, get len, X = 0
sta lzpos ; xstore - Save length LSB
mg1 cmp #64 ; ** PARAMETER 63-64 -> C clear, 64-64 -> C set..
bcc chrcode ; short RLE, get bytecode
longrle ldx #2 ; ** PARAMETER 111111xxxxxx
jsr getbits ; get 3/2/1 more bits to get a full byte, X = 0
sta lzpos ; xstore - Save length LSB
jsr getval ; length MSB, X = 0
tay ; Y is 1 bigger than MSB loops
chrcode jsr getval ; Byte Code, X = 0
tax ; this is executed most of the time anyway
lda table-1,x ; Saves one jump if done here (loses one txa)
cpx #32 ; 31-32 -> C clear, 32-32 -> C set..
bcc @1 ; 1..31, we got the right byte from the table
; Ranks 32..64 (11111°xxxxx), get byte..
txa ; get back the value (5 valid bits)
ldx #3
jsr getbits ; get 3 more bits to get a full byte, X = 0
@1: ldx lzpos ; xstore - get length LSB
inx ; adjust for cpx#$ff;bne -> bne
dorle jsr putch
dex
bne dorle ; xstore 0..255 -> 1..256
dey
bne dorle ; Y was 1 bigger than wanted originally
mainbeq beq main ; reverse condition -> jump always
lz77 jsr getval ; X = 0
mg21 cmp #127 ; ** PARAMETER Clears carry (is maximum value)
bne noeof
eof: clc ; Loading ended OK
rts
noeof sbc #0 ; C is clear -> subtract 1 (1..126 -> 0..125)
elzpb ldx #0 ; ** PARAMETER (more bits to get)
jsr getchkf ; clears Carry, X = 0
lz77_2 sta lzpos+1 ; offset MSB
jsr getbyt2 ; clears Carry, X = 0
; Note: Already eor:ed in the compressor..
;eor #255 ; offset LSB 2's complement -1 (i.e. -X = ~X+1)
adc outpos+1 ; -offset -1 + curpos (C is clear)
ldx lzpos ; xstore = LZLEN (read before it's overwritten)
sta lzpos
lda outpos+2
sbc lzpos+1 ; takes C into account
sta lzpos+1 ; copy X+1 number of chars from LZPOS to outpos+1
;ldy #0 ; Y was 0 originally, we don't change it
inx ; adjust for cpx#$ff;bne -> bne
lzslow .if LOAD_UNDER_IO>0
jsr disableio
.endif
lda (lzpos),y ; using abs,y is 3 bytes longer, only 1 cycle/byte faster
jsr outpos
iny ; Y does not wrap because X=0..255 and Y initially 0
dex
bne lzslow ; X loops, (256,1..255)
jmp main
putch .if LOAD_UNDER_IO>0
jsr disableio
.endif
outpos sta $aaaa ; ** parameter
inc outpos+1 ; ZP
bne putchok
inc outpos+2 ; ZP
putchok .if LOAD_UNDER_IO>0
jmp enableio
.else
rts
.endif
getnew pha ; 1 Byte/3 cycles
jsr getbyte
bcs pucrunch_fail
@0: sec
rol ; Shift out the next bit and
; shift in C=1 (last bit marker)
sta bitstr ; bitstr initial value = $80 == empty
pla ; 1 Byte/4 cycles
rts
; 25+12 = 37
; getval : Gets a 'static huffman coded' value
n; ** Scratches X, returns the value in A **
getval inx ; X <- 1
txa ; set the top bit (value is 1..255)
gv0 asl bitstr
bne @1
jsr getnew
@1: bcc getchk ; got 0-bit
inx
mg cpx #7 ; ** PARAMETER unary code maximum length + 1
bne gv0
beq getchk ; inverse condition -> jump always
; getval: 18 bytes
; 15 + 17*n + 6+15*n+12 + 36*n/8 = 33 + 32*n + 36*n/8 cycles
; getbits: Gets X bits from the stream
; ** Scratches X, returns the value in A **
getbyt2 ldx #7
get1bit inx ;2
getbits asl bitstr
bne @1
jsr getnew
@1: rol ;2
getchk dex ;2 more bits to get ?
getchkf bne getbits ;2/3
clc ;2 return carry cleared
rts ;6+6
pucrunch_fail: ;A premature EOF is treated as an
pucrunch_stackptr: ;error; return directly to caller
ldx #$00
txs
rts
.endif
;-------------------------------------------------------------------------------
; OPENFILE
;
; Opens a file either with slow or fast loader. If a file is already open, does
; nothing!
;
; Parameters: X (low),Y (high): Address of null-terminated filename
; Returns: -
; Modifies: A,X,Y
;-------------------------------------------------------------------------------
openfile: lda fileopen ;A file already open?
beq open_ok
rts
open_ok: .if LONG_NAMES>0
stx destlo
sty desthi
.else
stx filename
sty filename+1
.endif
inc fileopen ;File opened
lda usefastload
bne fastopen
;-------------------------------------------------------------------------------
; SLOWOPEN
;
; Opens a file without fastloader.
;
; Parameters: A:0 (it always is at this point)
; Returns: -
; Modifies: A,X,Y
;-------------------------------------------------------------------------------
slowopen: .if LONG_NAMES>0
tay
.endif
jsr kernalon
.if LONG_NAMES>0
slowopen_nameloop:
iny
lda (destlo),y
bne slowopen_nameloop
tya
ldx destlo
ldy desthi
.else
lda #$03
ldx #<filename
ldy #>filename
.endif
jsr setnam
lda #$02
ldy #$00
jsr setlfsdevice
jsr open