This repository has been archived by the owner on Nov 9, 2017. It is now read-only.
-
Notifications
You must be signed in to change notification settings - Fork 7
/
WireSurface.as
256 lines (223 loc) · 7.13 KB
/
WireSurface.as
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
////////////////////////////////////////////////////////////////////////////////
//
// Copyright (c) 2009 Josh Tynjala
//
// Permission is hereby granted, free of charge, to any person obtaining a copy
// of this software and associated documentation files (the "Software"), to
// deal in the Software without restriction, including without limitation the
// rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
// sell copies of the Software, and to permit persons to whom the Software is
// furnished to do so, subject to the following conditions:
//
// The above copyright notice and this permission notice shall be included in
// all copies or substantial portions of the Software.
//
// THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
// IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
// FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
// AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
// LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
// FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
// IN THE SOFTWARE.
//
////////////////////////////////////////////////////////////////////////////////
package com.flextoolbox.controls
{
import com.flextoolbox.controls.wireClasses.DefaultWireRenderer;
import com.flextoolbox.events.WireManagerEvent;
import com.flextoolbox.managers.IWireManager;
import com.flextoolbox.managers.WireManager;
import mx.core.ClassFactory;
import mx.core.IFactory;
import mx.core.UIComponent;
import mx.styles.CSSStyleDeclaration;
import mx.styles.StyleManager;
[Exclude("wireRenderer")]
//--------------------------------------
// Styles
//--------------------------------------
/**
* The renderer class used by this WireSurface.
*/
[Style(name="wireSkin", type="Class")]
//--------------------------------------
// Events
//--------------------------------------
/**
* Dispatched when a registered WireJack wants to make a connection with
* another WireJack. Generally, compatible WireJack instances are expected
* to highlight themselves so that the user knows where a connection can be
* made.
*
* @eventType com.flextoolbox.events.WireManagerEvent.BEGIN_CONNECTION_REQUEST
*/
[Event(name="beginConnectionRequest",type="com.flextoolbox.events.WireManagerEvent")]
/**
* Dispatched when a registered WireJack wants to end a connection request.
* Generally, compatible WireJack instances are expected to remove their
* highlight at this time.
*
* @eventType com.flextoolbox.events.WireManagerEvent.END_CONNECTION_REQUEST
*/
[Event(name="endConnectionRequest",type="com.flextoolbox.events.WireManagerEvent")]
/**
* Dispatched when a connection is made between two WireJack instances. May
* be cancelled.
*
* @eventType com.flextoolbox.events.WireManagerEvent.CREATE_CONNECTION
*/
[Event(name="createConnection",type="com.flextoolbox.events.WireManagerEvent")]
/**
* Dispatched when a connection is deleted between two WireJack instances.
*
* @eventType com.flextoolbox.events.WireManagerEvent.DELETE_CONNECTION
*/
[Event(name="deleteConnection",type="com.flextoolbox.events.WireManagerEvent")]
/**
* A surface for displaying wires connecting WireJacks. By default, the main
* WireManager uses a layer on the PopUpManager to display its wires. A
* WireSurface allows developers to place wires anywhere in the display list
* hierarchy.
*
* <p>To use, bind the WireSurface to a jack's <code>wireManager</code> property.</p>
*
* @author Josh Tynjala (joshblog.net)
*/
public class WireSurface extends UIComponent implements IWireManager
{
//--------------------------------------
// Static Methods
//--------------------------------------
/**
* @private
* Sets the default styles for the WireSurface
*/
private static function initializeStyles():void
{
var styles:CSSStyleDeclaration = StyleManager.getStyleDeclaration("WireSurface");
if(!styles)
{
styles = new CSSStyleDeclaration();
}
styles.defaultFactory = function():void
{
this.wireSkin = DefaultWireRenderer;
}
StyleManager.setStyleDeclaration("WireSurface", styles, false);
}
initializeStyles();
//--------------------------------------
// Constructor
//--------------------------------------
/**
* Constructor.
*/
public function WireSurface()
{
super();
this.manager = new WireManager(this);
this.manager.addEventListener(WireManagerEvent.BEGIN_CONNECTION_REQUEST, managerEventHandler);
this.manager.addEventListener(WireManagerEvent.END_CONNNECTION_REQUEST, managerEventHandler);
this.manager.addEventListener(WireManagerEvent.CREATING_CONNECTION, managerEventHandler);
this.manager.addEventListener(WireManagerEvent.CREATE_CONNECTION, managerEventHandler);
this.manager.addEventListener(WireManagerEvent.DELETE_CONNECTION, managerEventHandler);
}
//--------------------------------------
// Properties
//--------------------------------------
/**
* @private
* The real wire manager.
*/
protected var manager:IWireManager;
/**
* @inheritDoc
*/
public function get wireRenderer():IFactory
{
return this.manager.wireRenderer;
}
/**
* @private
*/
public function set wireRenderer(value:IFactory):void
{
this.manager.wireRenderer = value;
}
/**
* @inheritDoc
*/
public function get hasActiveConnectionRequest():Boolean
{
return this.manager.hasActiveConnectionRequest;
}
//--------------------------------------
// Public Methods
//--------------------------------------
/**
* @inheritDoc
*/
public function registerJack(jack:WireJack):void
{
this.manager.registerJack(jack);
}
/**
* @inheritDoc
*/
public function deleteJack(jack:WireJack):void
{
this.manager.deleteJack(jack);
}
/**
* @inheritDoc
*/
public function beginConnectionRequest(startJack:WireJack):void
{
this.manager.beginConnectionRequest(startJack);
}
/**
* @inheritDoc
*/
public function endConnectionRequest(startJack:WireJack):void
{
this.manager.endConnectionRequest(startJack);
}
/**
* @inheritDoc
*/
public function connect(startJack:WireJack, endJack:WireJack):Boolean
{
return this.manager.connect(startJack, endJack);
}
/**
* @inheritDoc
*/
public function disconnect(startJack:WireJack, endJack:WireJack):void
{
this.manager.disconnect(startJack, endJack);
}
/**
* @private
*/
override public function styleChanged(styleProp:String):void
{
var allStyles:Boolean = !styleProp || styleProp == "styleName";
if(allStyles || styleProp == "wireSkin")
{
var wireSkin:Class = this.getStyle("wireSkin");
this.wireRenderer = new ClassFactory(wireSkin);
}
}
//--------------------------------------
// Protected Event Handlers
//--------------------------------------
/**
* @private
* Re-dispatches events from the wrapped wire manager.
*/
protected function managerEventHandler(event:WireManagerEvent):void
{
this.dispatchEvent(event);
}
}
}