migrating to kotlin dsl and gradle 4.10

app/build.gradle.kts

@@ -0,0 +1,65 @@
+import org.jetbrains.kotlin.config.KotlinCompilerVersion
+
+plugins {
+    id("com.android.application")
+    id("kotlin-android")
+    id("kotlin-android-extensions")
+    id("kotlin-kapt")
+}
+
+android {
+    compileSdkVersion(27)
+    buildToolsVersion = "27.0.3"
+
+    defaultConfig {
+        applicationId = "com.droidcba.kedditbysteps"
+        minSdkVersion(16)
+        targetSdkVersion(27)
+        versionCode = 1
+        versionName = "1.0"
+        testInstrumentationRunner = "android.support.test.runner.AndroidJUnitRunner"
+    }
+    buildTypes {
+        getByName("release") {
+            isMinifyEnabled = false
+            proguardFiles(getDefaultProguardFile("proguard-android.txt"), "proguard-rules.pro")
+        }
+    }
+    packagingOptions.exclude("META-INF/main.kotlin_module")
+}
+
+dependencies {
+    implementation(fileTree(mapOf("dir" to "libs", "include" to listOf("*.jar"))))
+    implementation("com.android.support:appcompat-v7:27.1.1")
+    implementation("com.android.support:design:27.1.1")
+    implementation(kotlin("stdlib-jdk7", KotlinCompilerVersion.VERSION))
+
+    implementation("com.squareup.picasso:picasso:2.5.2")
+
+
+    // Retrofit
+    implementation("com.squareup.retrofit2:retrofit:2.4.0")
+    implementation("com.squareup.retrofit2:converter-moshi:2.0.0")
+
+    // Dagger 2
+    implementation("com.google.dagger:dagger:2.11")
+    kapt("com.google.dagger:dagger-compiler:2.11")
+    compileOnly("org.glassfish:javax.annotation:10.0-b28")
+
+    // Coroutines
+    implementation("org.jetbrains.kotlinx:kotlinx-coroutines-core:0.23.0")
+    implementation("org.jetbrains.kotlinx:kotlinx-coroutines-android:0.23.0")
+    // Coroutines - Retrofit extention
+    implementation("com.jakewharton.retrofit:retrofit2-kotlin-coroutines-experimental-adapter:1.0.0")
+
+    // Tests
+    testImplementation("junit:junit:4.12")
+    testImplementation("com.nhaarman.mockitokotlin2:mockito-kotlin:2.0.0-alpha04")
+    testImplementation("org.jetbrains.spek:spek:1.0.25")
+    testImplementation("org.jetbrains.kotlin:kotlin-stdlib:${KotlinCompilerVersion.VERSION}")
+}
+
+repositories {
+    mavenCentral()
+    maven("http://repository.jetbrains.com/all")
+}

app/proguard-rules.pro

@@ -2,7 +2,7 @@
 # By default, the flags in this file are appended to flags specified
 # in /Users/juancho/Documents/android_sdk/sdk/tools/proguard/proguard-android.txt
 # You can edit the include path and order by changing the proguardFiles
-# directive in build.gradle.
+# directive in build.gradle.kts.
 #
 # For more details, see
 #   http://developer.android.com/guide/developing/tools/proguard.html

build.gradle → build.gradle.kts

@@ -1,30 +1,26 @@
 // Top-level build file where you can add configuration options common to all sub-projects/modules.
 
 buildscript {
-    ext.kotlin_version = '1.2.41'
     repositories {
         jcenter()
         google()
     }
     dependencies {
-        classpath 'com.android.tools.build:gradle:3.1.3'
-        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
-
+        classpath("com.android.tools.build:gradle:3.1.4")
+        classpath("org.jetbrains.kotlin:kotlin-gradle-plugin:1.2.61")
         // NOTE: Do not place your application dependencies here; they belong
         // in the individual module build.gradle files
     }
 }
 
 allprojects {
     repositories {
-        maven {
-            url 'https://maven.google.com'
-        }
+        maven("https://maven.google.com")
         jcenter()
         google()
     }
 }
 
-task clean(type: Delete) {
-    delete rootProject.buildDir
+tasks.register("clean", Delete::class.java) {
+    delete(rootProject.buildDir)
 }

gradle.properties

@@ -18,5 +18,4 @@
 # org.gradle.parallel=true
 
 # Kotlin
-kotlin.incremental=true
 kotlin.coroutines=enable

gradle/wrapper/gradle-wrapper.properties

@@ -3,4 +3,4 @@ distributionBase=GRADLE_USER_HOME
 distributionPath=wrapper/dists
 zipStoreBase=GRADLE_USER_HOME
 zipStorePath=wrapper/dists
-distributionUrl=https\://services.gradle.org/distributions/gradle-4.4-all.zip
+distributionUrl=https\://services.gradle.org/distributions/gradle-4.10-all.zip

settings.gradle.kts

@@ -0,0 +1 @@
+include(":app")