feat: added Payment Session Headless

feat #207

src/Window.res

@@ -125,3 +125,6 @@ let isSandbox = hostname === "beta.hyperswitch.io"
 let isInteg = hostname === "dev.hyperswitch.io"
 
 let isProd = hostname === "checkout.hyperswitch.io"
+
+type location = {replace: (. string) => unit}
+@val @scope("window") external location: location = "location"

src/orca-loader/Hyper.res

@@ -488,6 +488,34 @@ let make = (publishableKey, options: option<Js.Json.t>, analyticsInfo: option<Js
         Window.paymentRequest(methodData, details, optionsForPaymentRequest)
       }
 
+      let initPaymentSession = paymentSessionOptions => {
+        open Promise
+
+        let clientSecretId =
+          paymentSessionOptions
+          ->Js.Json.decodeObject
+          ->Belt.Option.flatMap(x => x->Js.Dict.get("clientSecret"))
+          ->Belt.Option.flatMap(Js.Json.decodeString)
+          ->Belt.Option.getWithDefault("")
+        clientSecret := clientSecretId
+        Js.Promise.make((~resolve, ~reject as _) => {
+          logger.setClientSecret(clientSecretId)
+          resolve(. Js.Json.null)
+        })
+        ->then(_ => {
+          logger.setLogInfo(~value=Window.href, ~eventName=PAYMENT_SESSION_INITIATED, ())
+          resolve()
+        })
+        ->ignore
+
+        PaymentSession.make(
+          paymentSessionOptions,
+          ~clientSecret={clientSecretId},
+          ~publishableKey,
+          ~logger=Some(logger),
+        )
+      }
+
       let returnObject = {
         confirmOneClickPayment,
         confirmPayment,
@@ -496,6 +524,7 @@ let make = (publishableKey, options: option<Js.Json.t>, analyticsInfo: option<Js
         confirmCardPayment: confirmCardPaymentFn,
         retrievePaymentIntent: retrievePaymentIntentFn,
         paymentRequest,
+        initPaymentSession,
       }
       Window.setHyper(Window.window, returnObject)
       returnObject

src/orca-loader/HyperLoader.res

@@ -9,6 +9,7 @@ let loadStripe = (str, option) => {
 
 @val external window: {..} = "window"
 window["Hyper"] = Hyper.make
+window["Hyper"]["init"] = Hyper.make
 
 let isWordpress = window["wp"] !== Js.Json.null
 if !isWordpress {

src/orca-loader/LoaderPaymentElement.res

@@ -6,9 +6,6 @@ open OrcaUtils
 
 external eventToJson: Types.eventData => Js.Json.t = "%identity"
 
-type location = {replace: (. string) => unit}
-@val @scope("window") external location: location = "location"
-
 @val @scope(("navigator", "clipboard"))
 external writeText: string => Js.Promise.t<'a> = "writeText"
 
@@ -196,7 +193,7 @@ let make = (componentType, options, setIframeRef, iframeRef, mountPostMessage) =
         switch eventDataObject->getOptionalJsonFromJson("openurl") {
         | Some(val) => {
             let url = val->getStringfromjson("")
-            location.replace(. url)
+            Window.location.replace(. url)
           }
         | None => ()
         }

src/orca-loader/PaymentSession.res

@@ -0,0 +1,156 @@
+open Types
+
+let make = (options, ~clientSecret, ~publishableKey, ~logger: option<OrcaLogger.loggerMake>) => {
+  open Promise
+  let logger = logger->Belt.Option.getWithDefault(OrcaLogger.defaultLoggerConfig)
+  let switchToCustomPod =
+    GlobalVars.isInteg &&
+    options
+    ->Js.Json.decodeObject
+    ->Belt.Option.flatMap(x => x->Js.Dict.get("switchToCustomPod"))
+    ->Belt.Option.flatMap(Js.Json.decodeBoolean)
+    ->Belt.Option.getWithDefault(false)
+  let endpoint = ApiEndpoint.getApiEndPoint(~publishableKey, ())
+
+  let defaultPaymentMethodList = ref(Js.Json.null)
+
+  let customerDetailsPromise = PaymentHelpers.useCustomerDetails(
+    ~clientSecret,
+    ~publishableKey,
+    ~endpoint,
+    ~switchToCustomPod,
+    ~optLogger=Some(logger),
+  )
+
+  let getDefaultPaymentMethod = () => {
+    customerDetailsPromise
+    ->then(customerDetails => {
+      let customerPaymentMethods =
+        customerDetails
+        ->Js.Json.decodeObject
+        ->Belt.Option.flatMap(x => x->Js.Dict.get("customer_payment_methods"))
+        ->Belt.Option.flatMap(Js.Json.decodeArray)
+        ->Belt.Option.getWithDefault([])
+        ->Js.Array2.filter(customerPaymentMethod => {
+          customerPaymentMethod
+          ->Js.Json.decodeObject
+          ->Belt.Option.flatMap(x => x->Js.Dict.get("default_payment_method_set"))
+          ->Belt.Option.flatMap(Js.Json.decodeBoolean)
+          ->Belt.Option.getWithDefault(false)
+        })
+      let isGuestCustomer =
+        customerDetails
+        ->Js.Json.decodeObject
+        ->Belt.Option.flatMap(x => x->Js.Dict.get("is_guest_customer"))
+        ->Belt.Option.getWithDefault(Js.Json.null)
+      let updatedCustomerDetails =
+        [
+          ("customer_payment_methods", customerPaymentMethods->Js.Json.array),
+          ("is_guest_customer", isGuestCustomer),
+        ]
+        ->Js.Dict.fromArray
+        ->Js.Json.object_
+      defaultPaymentMethodList := updatedCustomerDetails
+      updatedCustomerDetails->resolve
+    })
+    ->catch(_err => {
+      let dict =
+        [("customer_payment_methods", []->Js.Json.array)]->Js.Dict.fromArray->Js.Json.object_
+      let msg = [("customerPaymentMethods", dict)]->Js.Dict.fromArray
+      resolve(msg->Js.Json.object_)
+    })
+  }
+
+  let confirmWithDefault = payload => {
+    let customerPaymentMethod =
+      defaultPaymentMethodList.contents
+      ->Utils.getDictFromJson
+      ->Js.Dict.get("customer_payment_methods")
+      ->Belt.Option.flatMap(Js.Json.decodeArray)
+      ->Belt.Option.getWithDefault([])
+      ->Belt.Array.get(0)
+      ->Belt.Option.flatMap(Js.Json.decodeObject)
+      ->Belt.Option.getWithDefault(Js.Dict.empty())
+    let paymentToken = customerPaymentMethod->Utils.getJsonFromDict("payment_token", Js.Json.null)
+    let paymentMethod = customerPaymentMethod->Utils.getJsonFromDict("payment_method", Js.Json.null)
+    let paymentMethodType =
+      customerPaymentMethod->Utils.getJsonFromDict("payment_method_type", Js.Json.null)
+
+    let confirmParams =
+      payload
+      ->Js.Json.decodeObject
+      ->Belt.Option.flatMap(x => x->Js.Dict.get("confirmParams"))
+      ->Belt.Option.getWithDefault(Js.Json.null)
+
+    let returnUrl =
+      confirmParams
+      ->Js.Json.decodeObject
+      ->Belt.Option.flatMap(x => x->Js.Dict.get("return_url"))
+      ->Belt.Option.flatMap(Js.Json.decodeString)
+      ->Belt.Option.getWithDefault("")
+
+    let confirmParam: ConfirmType.confirmParams = {
+      return_url: returnUrl,
+      publishableKey,
+    }
+
+    let paymentIntentID = Js.String2.split(clientSecret, "_secret_")[0]
+    let endpoint = ApiEndpoint.getApiEndPoint(
+      ~publishableKey=confirmParam.publishableKey,
+      ~isConfirmCall=true,
+      (),
+    )
+    let uri = `${endpoint}/payments/${paymentIntentID}/confirm`
+    let headers = [("Content-Type", "application/json"), ("api-key", confirmParam.publishableKey)]
+
+    let paymentType: PaymentHelpers.payment = switch paymentMethodType
+    ->Js.Json.decodeString
+    ->Belt.Option.getWithDefault("") {
+    | "apple_pay" => Applepay
+    | "google_pay" => Gpay
+    | "debit"
+    | "credit"
+    | "" =>
+      Card
+    | _ => Other
+    }
+
+    let broswerInfo = BrowserSpec.broswerInfo()
+
+    let body = [
+      ("client_secret", clientSecret->Js.Json.string),
+      ("payment_method", paymentMethod),
+      ("payment_token", paymentToken),
+      ("payment_method_type", paymentMethodType),
+    ]
+
+    let bodyStr =
+      body->Js.Array2.concat(broswerInfo)->Js.Dict.fromArray->Js.Json.object_->Js.Json.stringify
+
+    PaymentHelpers.intentCall(
+      ~fetchApi=Utils.fetchApi,
+      ~uri,
+      ~headers,
+      ~bodyStr,
+      ~confirmParam: ConfirmType.confirmParams,
+      ~clientSecret,
+      ~optLogger=Some(logger),
+      ~handleUserError=false,
+      ~paymentType,
+      ~iframeId="",
+      ~fetchMethod=Fetch.Post,
+      ~setIsManualRetryEnabled={(. _) => ()},
+      ~switchToCustomPod=false,
+      ~sdkHandleOneClickConfirmPayment=false,
+      ~counter=0,
+      ~isPaymentSession=true,
+      (),
+    )
+  }
+
+  let returnObject = {
+    getDefaultPaymentMethod,
+    confirmWithDefault,
+  }
+  returnObject
+}

src/orca-loader/Types.res

@@ -39,6 +39,11 @@ type element = {
   create: (Js.Dict.key, Js.Json.t) => paymentElement,
 }
 
+type initPaymentSession = {
+  getDefaultPaymentMethod: unit => Promise.t<Js.Json.t>,
+  confirmWithDefault: Js.Json.t => Promise.t<Js.Json.t>,
+}
+
 type confirmParams = {return_url: string}
 
 type confirmPaymentParams = {
@@ -56,6 +61,7 @@ type hyperInstance = {
   retrievePaymentIntent: string => Js.Promise.t<Js.Json.t>,
   widgets: Js.Json.t => element,
   paymentRequest: Js.Json.t => Js.Json.t,
+  initPaymentSession: Js.Json.t => initPaymentSession,
 }
 
 let oneClickConfirmPaymentFn = (_, _) => {
@@ -115,6 +121,19 @@ let defaultElement = {
   create,
 }
 
+let getDefaultPaymentMethod = () => {
+  Js.Promise.resolve(Js.Dict.empty()->Js.Json.object_)
+}
+
+let confirmWithDefault = _confirmParams => {
+  Js.Promise.resolve(Js.Dict.empty()->Js.Json.object_)
+}
+
+let defaultInitPaymentSession: initPaymentSession = {
+  getDefaultPaymentMethod,
+  confirmWithDefault,
+}
+
 let defaultHyperInstance = {
   confirmOneClickPayment: oneClickConfirmPaymentFn,
   confirmPayment: confirmPaymentFn,
@@ -123,6 +142,7 @@ let defaultHyperInstance = {
   elements: _ev => defaultElement,
   widgets: _ev => defaultElement,
   paymentRequest: _ev => Js.Json.null,
+  initPaymentSession: _ev => defaultInitPaymentSession,
 }
 
 type eventType =

src/orca-log-catcher/OrcaLogger.res

@@ -56,6 +56,7 @@ type eventName =
   | DISPLAY_VOUCHER
   | PAYMENT_METHODS_RESPONSE
   | LOADER_CHANGED
+  | PAYMENT_SESSION_INITIATED
 
 let eventNameToStrMapper = eventName => {
   switch eventName {
@@ -113,6 +114,7 @@ let eventNameToStrMapper = eventName => {
   | DISPLAY_VOUCHER => "DISPLAY_VOUCHER"
   | PAYMENT_METHODS_RESPONSE => "PAYMENT_METHODS_RESPONSE"
   | LOADER_CHANGED => "LOADER_CHANGED"
+  | PAYMENT_SESSION_INITIATED => "PAYMENT_SESSION_INITIATED"
   }
 }