-
Notifications
You must be signed in to change notification settings - Fork 6
/
OJSON.pbi
1581 lines (1384 loc) · 41.3 KB
/
OJSON.pbi
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
; +-------+--------------+
; | OJSON | Ordered JSON |
; +-------+--------------+
; | 2018-02-09 . Version 1.00 (adapted from JSON.pbi ver 1.20)
; ABOUT:
; This is adapted from JSON.pbi, an include/module written in 2014
; before PureBasic added its own JSON library in version 5.30.
;
; The main benefit over PB's JSON library is that the order of
; an Object's members is preserved - sometimes this is important!
;
; All custom constants and procedures here have been renamed
; "OJSON" (for Ordered JSON) to avoid compile conflicts in PB 5.30+.
;
; The names were based on PB's XML libary, which is why
; they are different from PB's later JSON library.
;-
CompilerIf (Not Defined(_OJSON_Included, #PB_Constant))
#_OJSON_Included = #True
CompilerIf (#PB_Compiler_IsMainFile)
EnableExplicit
CompilerEndIf
;- Constants (Public)
; OJSON module version (123 = 1.23)
#OJSON_Version = 100
; OJSON node types
CompilerIf (#PB_Compiler_Version >= 530)
#OJSON_Number = #PB_JSON_Number
#OJSON_String = #PB_JSON_String
#OJSON_Boolean = #PB_JSON_Boolean
#OJSON_Array = #PB_JSON_Array
#OJSON_Object = #PB_JSON_Object
#OJSON_Null = #PB_JSON_Null
#OJSON_Invalid = 6
CompilerElse
#OJSON_Number = 0
#OJSON_String = 1
#OJSON_Boolean = 2
#OJSON_Array = 3
#OJSON_Object = 4
#OJSON_Null = 5
#OJSON_Invalid = 6
CompilerEndIf
; SaveOJSON() formats
#OJSON_Compact = $0001
#OJSON_Indented = $0002
; Other OJSON constants
#OJSON_Default = -1
#OJSON_First = 0
#OJSON_Last = -1
;-
;- Declares (Public)
; OJSON management
Declare.i CreateOJSON(MainNodeType = #OJSON_Object)
Declare.i CatchOJSON(*Address, Length)
Declare.i LoadOJSON(File.s)
Declare.i SaveOJSON(*OJSON, File.s, Format = #OJSON_Default, IndentSize = 4)
Declare.i FreeOJSON(*OJSON)
; OJSON node management
Declare.i CreateOJSONNode(*Parent, Type = #OJSON_Object, Key.s = "", *Previous = #OJSON_Last)
Declare.i DeleteOJSONNode(*Node)
Declare.i AddOJSONString(*Parent, Text.s, Key.s = "", *Previous = #OJSON_Last)
Declare.i AddOJSONNumber(*Parent, Value.f, Key.s = "", *Previous = #OJSON_Last)
Declare.i AddOJSONBoolean(*Parent, Value, Key.s = "", *Previous = #OJSON_Last)
Declare.i AddOJSONNull(*Parent, Key.s = "", *Previous = #OJSON_Last)
Declare.i AddOJSONArray(*Parent, Key.s = "", *Previous = #OJSON_Last)
Declare.i AddOJSONObject(*Parent, Key.s = "", *Previous = #OJSON_Last)
; OJSON node iteration
Declare.i MainOJSONNode(*OJSON)
Declare.i ChildOJSONNode(*Node, Index = #OJSON_First)
Declare.i ParentOJSONNode(*Node)
Declare.i NextOJSONNode(*Node)
Declare.i PreviousOJSONNode(*Node)
Declare.i NamedOJSONNode(*Node, Path.s)
Declare.i FindOJSONNodeByID(*Node, Text.s, Key.s = "id")
; OJSON node access
Declare.s GetOJSONNodeText(*Node)
Declare.f GetOJSONNodeValue(*Node)
Declare.i GetOJSONNodeInteger(*Node)
Declare.s GetOJSONNodeKey(*Node)
Declare.i GetOJSONChildCount(*Node)
Declare.i GetOJSONNodeType(*Node)
Declare.s GetOJSONTypeName(Type)
; OJSON node modification
Declare.i SetOJSONNodeText(*Node, Text.s)
Declare.i SetOJSONNodeValue(*Node, Value.f)
Declare.i SetOJSONNodeKey(*Node, Key.s)
;-
;- Constants (Private)
; OJSON type constants
#_OJSON_Types = 7
; OJSON node flags
#_OJSON_IsRoot = $0001
;-
;- Structures (Private)
Structure OJSONNODE
*Parent.OJSONNODE
Key.s
Type.i
Raw.s
String.s
Number.f
Flags.i
;
*First.OJSONNODE
*Last.OJSONNODE
Children.i
;
*Next.OJSONNODE
*Prev.OJSONNODE
EndStructure
;-
;- Macros (Private)
CompilerIf (#PB_Compiler_Unicode)
Macro _Unicode()
(#True)
EndMacro
Macro _CharSize()
(2)
EndMacro
Macro _ToBytes(Chars)
((Chars) * 2)
EndMacro
Macro _ToChars(Bytes)
((Bytes) / 2)
EndMacro
CompilerElse
Macro _Unicode()
(#False)
EndMacro
Macro _CharSize()
(1)
EndMacro
Macro _ToBytes(Chars)
(Chars)
EndMacro
Macro _ToChars(Bytes)
(Bytes)
EndMacro
CompilerEndIf
;-
;- Declares (Private)
Declare.i _ParseOJSONString(*JN.OJSONNODE, *Start.CHARACTER, *End.CHARACTER, *Unescape.INTEGER = #Null)
Declare.i _ParseOJSONNode(*JN.OJSONNODE, *Address, Length.i)
;-
;- Procedures (Private)
Procedure.s _EscapeOJSONString(String.s)
Protected Build.s = ""
Protected *C.CHARACTER = @String
While (*C And *C\c)
Select (*C\c)
Case '"'
Build + "\" + #DQUOTE$
Case '\'
Build + "\\"
;Case '/'
; Build + "\/"
Case #BS
Build + "\b"
Case #FF
Build + "\f"
Case #LF
Build + "\n"
Case #CR
Build + "\r"
Case #TAB
Build + "\t"
Default
If ((*C\c >= $20) And (*C\c <= $FF))
Build + Chr(*C\c)
Else
Build + "\u" + RSet(Hex(*C\c), 4, "0")
EndIf
EndSelect
*C + _CharSize()
Wend
ProcedureReturn (Build)
EndProcedure
Procedure.s _UnescapeOJSONString(String.s)
Protected Result.s = ""
String = #DQUOTE$ + String + #DQUOTE$
Protected i.INTEGER
_ParseOJSONString(#Null, @String, @String + StringByteLength(String), @i)
If (i\i)
Result = PeekS(i\i)
FreeMemory(i\i)
EndIf
ProcedureReturn (Result)
EndProcedure
Procedure.i _AddOJSONNode(*JN.OJSONNODE, *Parent.OJSONNODE, *Previous.OJSONNODE)
If (*JN And *Parent)
*JN\Parent = *Parent
*Parent\Children + 1
If (*Parent\First)
If (*Previous = #OJSON_First)
*JN\Prev = #Null
*JN\Next = *Parent\First
*Parent\First\Prev = *JN
*Parent\First = *JN
ElseIf (*Previous = #OJSON_Last)
*JN\Prev = *Parent\Last
*JN\Next = #Null
*Parent\Last\Next = *JN
*Parent\Last = *JN
Else
If (*Previous\Parent = *Parent)
*JN\Prev = *Previous
*JN\Next = *Previous\Next
*Previous\Next = *JN
If (*JN\Next)
*JN\Next\Prev = *JN
Else
*Parent\Last = *JN
EndIf
Else
ProcedureReturn (#False)
EndIf
EndIf
Else
*JN\Prev = #Null
*JN\Next = #Null
*Parent\First = *JN
*Parent\Last = *JN
EndIf
ProcedureReturn (#True)
EndIf
ProcedureReturn (#False)
EndProcedure
Procedure.i _CreateOJSONNode(*Parent.OJSONNODE, Type.i, *Previous.OJSONNODE = #OJSON_Last)
Protected *JN.OJSONNODE = #Null
If ((Type >= 0) And (Type < #_OJSON_Types))
*JN = AllocateMemory(SizeOf(OJSONNODE))
If (*JN)
If (*Parent)
If (_AddOJSONNode(*JN, *Parent, *Previous))
*JN\Type = Type
Else
FreeMemory(*JN)
*JN = #Null
EndIf
Else
*JN\Type = #OJSON_Array
*JN\Flags = #_OJSON_IsRoot
EndIf
EndIf
EndIf
ProcedureReturn (*JN)
EndProcedure
Procedure.i _ParseOJSONString(*JN.OJSONNODE, *Start.CHARACTER, *End.CHARACTER, *Unescape.INTEGER = #Null)
Protected Type.i = #OJSON_Invalid
If ((*JN Or *Unescape) And *Start And (*End > *Start))
Type.i = #OJSON_String
Protected *C.CHARACTER = *Start
Protected *TokenEnd.CHARACTER = #Null
Protected i.i
Protected *Build = #Null
Protected *BC.CHARACTER = #Null
If (*Unescape)
*Unescape\i = #Null
EndIf
*Build = AllocateMemory((*End - *Start) + _CharSize(), #PB_Memory_NoClear)
If (*Build)
*BC = *Build
Protected Expecting.i = 0
While (*C < *End)
Select (Expecting)
; 0 = quote, 1 = characters, 2 = whitespace
Case 0
Select (*C\c)
Case '"'
Expecting = 1
Default
Type = #OJSON_Invalid
EndSelect
Case 1
Select (*C\c)
Case '"'
*TokenEnd = *C
Expecting = 2
Case '\'
If (_ToChars(*End - *C) >= 1 + 1)
*C + _CharSize()
Select (*C\c)
Case '"', '\', '/'
*BC\c = *C\c
Case 'b'
*BC\c = #BS
Case 'f'
*BC\c = #FF
Case 'n'
*BC\c = #LF
Case 'r'
*BC\c = #CR
Case 't'
*BC\c = #TAB
Case 'u'
If (_ToChars(*End - *C) >= 4 + 1)
Protected UValue.u = Val("$" + PeekS(*C + _CharSize(), 4))
For i = 1 To 4
*C + _CharSize()
Select (*C\c)
Case '0' To '9', 'a' To 'f', 'A' To 'F'
;
Default
Type = #OJSON_Invalid
Break
EndSelect
Next i
If (Type <> #OJSON_Invalid)
CompilerIf (_Unicode())
*BC\c = UValue
CompilerElse
If (UValue <= $FF)
*BC\c = UValue
Else
*BC\c = '?'
EndIf
CompilerEndIf
EndIf
Else
Type = #OJSON_Invalid
EndIf
Default
Type = #OJSON_Invalid
EndSelect
*BC + _CharSize()
Else
Type = #OJSON_Invalid
EndIf
Case $00 To $1F
Type = #OJSON_Invalid
Default
*BC\c = *C\c
*BC + _CharSize()
EndSelect
Case 2
Select (*C\c)
Case ' ', #TAB, #CR, #LF
;
Default
Type = #OJSON_Invalid
EndSelect
EndSelect
If (Type = #OJSON_Invalid)
Break
EndIf
*C + _CharSize()
Wend
If (*TokenEnd = #Null)
*TokenEnd = *End
EndIf
*BC\c = #NUL
If (Type <> #OJSON_Invalid)
If (Expecting = 2)
If (*JN)
*JN\Type = Type
*JN\Raw = PeekS(*Start + _CharSize(), _ToChars(*TokenEnd - *Start) - 1)
*JN\String = PeekS(*Build)
*JN\Number = 0.0
EndIf
Else
Type = #OJSON_Invalid
EndIf
EndIf
If (*Unescape And (Type = #OJSON_String))
*Unescape\i = *Build
Else
FreeMemory(*Build)
EndIf
EndIf
EndIf
ProcedureReturn (Type)
EndProcedure
Procedure.i _ParseOJSONNumber(*JN.OJSONNODE, *Start.CHARACTER, *End.CHARACTER)
Protected Type.i = #OJSON_Invalid
If (*Start And (*End > *Start))
Type.i = #OJSON_Number
Protected *C.CHARACTER = *Start
Protected *TokenEnd.CHARACTER = #Null
Protected IntDigits.i = 0
Protected FracDigits.i = -1
Protected ExpDigits.i = -1
Protected Expecting.i = 0
While (*C < *End)
Select (Expecting)
; 0 = sign, 1 = int, 2 = frac, 3 = expsign, 4 = exp, 5 = whitespace
Case 0
Select (*C\c)
Case '-'
Expecting = 1
Case '0' To '9'
IntDigits + 1
Expecting = 1
Default
Type = #OJSON_Invalid
EndSelect
Case 1
Select (*C\c)
Case '0' To '9'
IntDigits + 1
Case '.'
FracDigits = 0
Expecting = 2
Case 'e', 'E'
ExpDigits = 0
Expecting = 3
Case ' ', #TAB, #CR, #LF
*TokenEnd = *C
Expecting = 5
Default
Type = #OJSON_Invalid
EndSelect
Case 2
Select (*C\c)
Case '0' To '9'
FracDigits + 1
Case 'e', 'E'
ExpDigits = 0
Expecting = 3
Case ' ', #TAB, #CR, #LF
*TokenEnd = *C
Expecting = 5
Default
Type = #OJSON_Invalid
EndSelect
Case 3
Select (*C\c)
Case '0' To '9'
ExpDigits + 1
Expecting = 4
Case '+', '-'
Expecting = 4
Default
Type = #OJSON_Invalid
EndSelect
Case 4
Select (*C\c)
Case '0' To '9'
ExpDigits + 1
Case ' ', #TAB, #CR, #LF
*TokenEnd = *C
Expecting = 5
Default
Type = #OJSON_Invalid
EndSelect
Case 5
Select (*C\c)
Case ' ', #TAB, #CR, #LF
;
Default
Type = #OJSON_Invalid
EndSelect
EndSelect
If (Type = #OJSON_Invalid)
Break
EndIf
*C + _CharSize()
Wend
If (*TokenEnd = #Null)
*TokenEnd = *End
EndIf
If (Type <> #OJSON_Invalid)
If ((IntDigits > 0) And (FracDigits <> 0) And (ExpDigits <> 0))
If (*JN)
*JN\Type = Type
*JN\Raw = PeekS(*Start, _ToChars(*TokenEnd - *Start))
*JN\String = *JN\Raw
*JN\Number = ValF(*JN\String)
EndIf
Else
Type = #OJSON_Invalid
EndIf
EndIf
EndIf
ProcedureReturn (Type)
EndProcedure
Procedure.i _ParseOJSONWord(*JN.OJSONNODE, *Start.CHARACTER, *End.CHARACTER)
Protected Type.i = #OJSON_Invalid
If (*JN And *Start And (*End > *Start))
Type.i = #OJSON_Null
Protected *C.CHARACTER = *Start
Protected *TokenEnd.CHARACTER = #Null
Protected Expecting.i = 0
While (*C < *End)
Select (Expecting)
; 0 = characters, 1 = whitespace
Case 0
Select (*C\c)
Case 'a' To 'z', 'A' To 'Z', '0' To '9', '_'
;
Case ' ', #TAB, #CR, #LF
*TokenEnd = *C
Expecting = 1
Default
Type = #OJSON_Invalid
EndSelect
Case 1
Select (*C\c)
Case ' ', #TAB, #CR, #LF
;
Default
Type = #OJSON_Invalid
EndSelect
EndSelect
If (Type = #OJSON_Invalid)
Break
EndIf
*C + _CharSize()
Wend
If (*TokenEnd = #Null)
*TokenEnd = *End
EndIf
If (Type <> #OJSON_Invalid)
Protected Raw.s = PeekS(*Start, _ToChars(*TokenEnd - *Start))
Select (Raw)
Case "true"
Type = #OJSON_Boolean
*JN\Number = 1.0
Case "false"
Type = #OJSON_Boolean
*JN\Number = 0.0
Case "null"
Type = #OJSON_Null
*JN\Number = 0.0
Default
Type = #OJSON_Invalid
EndSelect
If (Type <> #OJSON_Invalid)
*JN\Type = Type
*JN\Raw = Raw
*JN\String = Raw
EndIf
EndIf
EndIf
ProcedureReturn (Type)
EndProcedure
Procedure.i _SkipOJSONWhitespace(*Start.CHARACTER, *End.CHARACTER)
If (*Start And (*End >= *Start))
While (*Start < *End)
Select (*Start\c)
Case ' ', #TAB, #CR, #LF
;
Default
Break
EndSelect
*Start + _CharSize()
Wend
Else
*Start = #Null
EndIf
ProcedureReturn (*Start)
EndProcedure
Procedure.i _IsOJSONWhitespace(*Start.CHARACTER, *End.CHARACTER)
If (*Start And (*End >= *Start))
ProcedureReturn (Bool(_SkipOJSONWhitespace(*Start, *End) = *End))
EndIf
ProcedureReturn (#False)
EndProcedure
Procedure.i _FindOJSONClose(*Start.CHARACTER, *End.CHARACTER, Symbol.c, AllowAfter.i)
Protected *Found.CHARACTER = #Null
If (*Start And (*End > *Start))
Protected *C.CHARACTER = *Start
Protected Sublevel.i = 0
Protected Expecting.i = 0
While (*C < *End)
Select (Expecting)
; 0 = data, 1 = inString, 2 = whitespace
Case 0
If ((*C\c = Symbol) And (Sublevel = 0))
*Found = *C
If (AllowAfter)
Break
Else
Expecting = 2
EndIf
Else
Select (*C\c)
Case '{', '['
Sublevel + 1
Case '}', ']'
Sublevel - 1
If (Sublevel < 0)
Break
EndIf
Case '"'
Expecting = 1
Default
;
EndSelect
EndIf
Case 1
Select (*C\c)
Case '"'
Expecting = 0
Case $00 To $1F
Break
Case '\'
If (_ToChars(*End - *C) >= 1 + 1)
*C + _CharSize()
Select (*C\c)
Case '"', '\', '/', 'b', 'f', 'r', 'n', 't'
;
Case 'u'
If (_ToChars(*End - *C) >= 4 + 1)
*C + 4 * _CharSize()
Else
Break
EndIf
Default
Break
EndSelect
Else
Break
EndIf
Default
;
EndSelect
Case 2
Select (*C\c)
Case ' ', #TAB, #CR, #LF
;
Default
*Found = #Null
Break
EndSelect
EndSelect
*C + _CharSize()
Wend
EndIf
ProcedureReturn (*Found)
EndProcedure
Procedure.i _ParseOJSONObject(*JN.OJSONNODE, *Start.CHARACTER, *End.CHARACTER)
Protected Type.i = #OJSON_Invalid
If (*JN And *Start And (*End > *Start))
If (*Start\c = '{')
Protected *NodeEnd.CHARACTER = _FindOJSONClose(*Start + _CharSize(), *End, '}', #False)
If (*NodeEnd)
Type = #OJSON_Object
*Start + _CharSize()
Protected *PairEnd.CHARACTER
Repeat
*Start = _SkipOJSONWhitespace(*Start, *NodeEnd)
*PairEnd = _FindOJSONClose(*Start, *NodeEnd, ',', #True)
If (Not *PairEnd)
If (Not _IsOJSONWhitespace(*Start, *NodeEnd))
*PairEnd = *NodeEnd
EndIf
EndIf
If (*PairEnd)
Type = #OJSON_Invalid
Protected *Divider.CHARACTER = _FindOJSONClose(*Start, *PairEnd - _CharSize(), ':', #True)
If ((*Divider > *Start) And (*Divider < *PairEnd))
Protected NamePtr.INTEGER
_ParseOJSONString(#Null, *Start, *Divider, @NamePtr)
If (NamePtr\i)
Protected *Child.OJSONNODE = _CreateOJSONNode(*JN, #OJSON_Invalid)
If (*Child)
*Divider + _CharSize()
If (_ParseOJSONNode(*Child, *Divider, *PairEnd - *Divider) <> #OJSON_Invalid)
*Child\Key = PeekS(NamePtr\i)
Type = #OJSON_Object
Else
DeleteOJSONNode(*Child)
EndIf
EndIf
FreeMemory(NamePtr\i)
EndIf
EndIf
*Start = *PairEnd + _CharSize()
EndIf
Until ((Not *PairEnd) Or (*Start >= *NodeEnd) Or (Type = #OJSON_Invalid))
If (Type = #OJSON_Object)
*JN\Type = Type
*JN\Raw = ""
*JN\String = ""
*JN\Number = 0.0
EndIf
EndIf
EndIf
EndIf
ProcedureReturn (Type)
EndProcedure
Procedure.i _ParseOJSONArray(*JN.OJSONNODE, *Start.CHARACTER, *End.CHARACTER)
Protected Type.i = #OJSON_Invalid
If (*JN And *Start And (*End > *Start))
If (*Start\c = '[')
Protected *NodeEnd.CHARACTER = _FindOJSONClose(*Start + _CharSize(), *End, ']', #False)
If (*NodeEnd)
Type = #OJSON_Array
*Start + _CharSize()
Protected *ItemEnd.CHARACTER
Repeat
*Start = _SkipOJSONWhitespace(*Start, *NodeEnd)
*ItemEnd = _FindOJSONClose(*Start, *NodeEnd, ',', #True)
If (Not *ItemEnd)
If (Not _IsOJSONWhitespace(*Start, *NodeEnd))
*ItemEnd = *NodeEnd
EndIf
EndIf
If (*ItemEnd)
Type = #OJSON_Invalid
Protected *Child.OJSONNODE = _CreateOJSONNode(*JN, #OJSON_Invalid)
If (*Child)
If (_ParseOJSONNode(*Child, *Start, *ItemEnd - *Start) <> #OJSON_Invalid)
Type = #OJSON_Array
Else
DeleteOJSONNode(*Child)
EndIf
EndIf
*Start = *ItemEnd + _CharSize()
EndIf
Until ((Not *ItemEnd) Or (*Start >= *NodeEnd) Or (Type = #OJSON_Invalid))
If (Type = #OJSON_Array)
*JN\Type = Type
*JN\Raw = ""
*JN\String = ""
*JN\Number = 0.0
EndIf
EndIf
EndIf
EndIf
ProcedureReturn (Type)
EndProcedure
Procedure.i _ParseOJSONNode(*JN.OJSONNODE, *Address, Length.i)
Protected Type.i = #OJSON_Invalid
If (*JN And (*JN\Type = #OJSON_Invalid))
If (*Address And (Length > 0))
Protected *End.CHARACTER = *Address + Length
Protected *C.CHARACTER = _SkipOJSONWhitespace(*Address, *End)
If (*C < *End)
Select (*C\c)
Case '{'
Type = _ParseOJSONObject(*JN, *C, *End)
Case '['
Type = _ParseOJSONArray(*JN, *C, *End)
Case '"'
Type = _ParseOJSONString(*JN, *C, *End)
Case '0' To '9', '-'
Type = _ParseOJSONNumber(*JN, *C, *End)
Case 'a' To 'z', 'A' To 'Z', '_'
Type = _ParseOJSONWord(*JN, *C, *End)
Default
;
EndSelect
EndIf
EndIf
EndIf
ProcedureReturn (Type)
EndProcedure
Procedure _WriteOJSONIndent(FN, Indent.i, Level.i)
If (IsFile(FN))
If (Indent > 0)
WriteString(FN, Space(Indent * Level), #PB_Ascii)
ElseIf (Indent < 0)
WriteString(FN, RSet("", -Indent * Level, #TAB$), #PB_Ascii)
EndIf
EndIf
EndProcedure
Procedure _WriteOJSONNode(FN.i, *JN.OJSONNODE, Format.i, Indent.i, Level.i = 0)
If (IsFile(FN) And *JN)
Protected EOL.s
Protected SP.s
If (Format & #OJSON_Indented)
CompilerIf (#PB_Compiler_OS = #PB_OS_Windows)
EOL = #CRLF$
CompilerElse
EOL = #LF$
CompilerEndIf
SP = " "
Else
EOL = ""
SP = ""
EndIf
;
_WriteOJSONIndent(FN, Indent, Level)
If (*JN\Key)
WriteString(FN, #DQUOTE$ + _EscapeOJSONString(*JN\Key) + #DQUOTE$ + ":" + SP, #PB_Ascii)
EndIf
Protected *Child.OJSONNODE
Select (*JN\Type)
Case #OJSON_Null
WriteString(FN, "null", #PB_Ascii)
Case #OJSON_Boolean
If (*JN\Number)
WriteString(FN, "true", #PB_Ascii)
Else
WriteString(FN, "false", #PB_Ascii)
EndIf
Case #OJSON_Number
WriteString(FN, *JN\Raw, #PB_Ascii)
Case #OJSON_String
WriteString(FN, #DQUOTE$ + *JN\Raw + #DQUOTE$, #PB_Ascii)
Case #OJSON_Object
WriteString(FN, "{" + EOL, #PB_Ascii)
*Child = *JN\First
If (*Child)
While (#True)
_WriteOJSONNode(FN, *Child, Format, Indent, Level + 1)
*Child = *Child\Next
If (*Child)
WriteString(FN, "," + EOL, #PB_Ascii)
Else
WriteString(FN, EOL, #PB_Ascii)
Break
EndIf
Wend
EndIf
_WriteOJSONIndent(FN, Indent, Level)
WriteString(FN, "}", #PB_Ascii)
Case #OJSON_Array
WriteString(FN, "[" + EOL, #PB_Ascii)
*Child = *JN\First
If (*Child)
While (#True)
_WriteOJSONNode(FN, *Child, Format, Indent, Level + 1)
*Child = *Child\Next
If (*Child)
WriteString(FN, "," + EOL, #PB_Ascii)
Else
WriteString(FN, EOL, #PB_Ascii)
Break
EndIf
Wend
EndIf
_WriteOJSONIndent(FN, Indent, Level)
WriteString(FN, "]", #PB_Ascii)
EndSelect
EndIf
EndProcedure
;-
Procedure.i DeleteOJSONNode(*JN.OJSONNODE)
If (*JN And (Not (*JN\Flags & #_OJSON_IsRoot)))
If ((*JN\Type = #OJSON_Array) Or (*JN\Type = #OJSON_Object))
Protected *Prev.OJSONNODE
Protected *Next.OJSONNODE
Protected *Child.OJSONNODE = *JN\First
While (*Child)
*Next = *Child\Next
DeleteOJSONNode(*Child)
*Child = *Next
Wend
EndIf
;
If (*JN\Parent)
*Prev = *JN\Prev
*Next = *JN\Next
If (*Prev)
*Prev\Next = *Next
EndIf
If (*Next)
*Next\Prev = *Prev
EndIf
If (*JN = *JN\Parent\First)
*JN\Parent\First = *Next
EndIf
If (*JN = *JN\Parent\Last)
*JN\Parent\Last = *Prev
EndIf
*JN\Parent\Children - 1
EndIf
FreeMemory(*JN)
EndIf
ProcedureReturn (#Null)
EndProcedure
Procedure.i CreateOJSONNode(*Parent.OJSONNODE, Type.i = #OJSON_Object, Key.s = "", *Previous.OJSONNODE = #OJSON_Last)
Protected *Child.OJSONNODE = #Null
If ((Type >= 0) And (Type < #_OJSON_Types) And (Type <> #OJSON_Invalid))
If (*Parent)
If ((*Parent\Type = #OJSON_Array) Or ((*Parent\Type = #OJSON_Object) And (Key)))
If ((*Parent\Children = 0) Or (Not (*Parent\Flags & #_OJSON_IsRoot)))
*Child = _CreateOJSONNode(*Parent, Type, *Previous)
If (*Child)
If (*Parent\Type = #OJSON_Object)
*Child\Key = Key
EndIf
Select (Type)
Case #OJSON_Boolean
*Child\String = "false"
*Child\Raw = *Child\String
Case #OJSON_Null
*Child\String = "null"
*Child\Raw = *Child\String
Case #OJSON_Number
*Child\String = "0"
*Child\Raw = *Child\String
EndSelect
EndIf
EndIf
EndIf
EndIf
EndIf
ProcedureReturn (*Child)
EndProcedure
Procedure.i AddOJSONString(*Parent.OJSONNODE, Text.s, Key.s = "", *Previous.OJSONNODE = #OJSON_Last)
Protected *New.OJSONNODE = #Null
*New = CreateOJSONNode(*Parent, #OJSON_String, Key, *Previous)
If (*New)
SetOJSONNodeText(*New, Text)
EndIf
ProcedureReturn (*New)
EndProcedure
Procedure.i AddOJSONNumber(*Parent.OJSONNODE, Value.f, Key.s = "", *Previous.OJSONNODE = #OJSON_Last)
Protected *New.OJSONNODE = #Null
*New = CreateOJSONNode(*Parent, #OJSON_Number, Key, *Previous)
If (*New)
SetOJSONNodeValue(*New, Value)