forked from Mardoxx/skyrimui
-
Notifications
You must be signed in to change notification settings - Fork 0
/
BSScrollingList.as
528 lines (461 loc) · 15.1 KB
/
BSScrollingList.as
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
import Shared.GlobalFunc;
import gfx.ui.InputDetails;
import gfx.ui.NavigationCode;
import gfx.events.EventDispatcher;
/*
Method summary:
function BSScrollingList()
function ClearList(): Void
function GetClipByIndex(aiIndex: Number): MovieClip
function handleInput(details: InputDetails, pathToFocus: Array): Boolean
function set selectedIndex(aiNewIndex: Number): Void
function set listAnimating(abFlag: Boolean): Void
function doSetSelectedIndex(aiNewIndex:Number, aiKeyboardOrMouse: Number): Void
function set scrollPosition(aiNewPosition: Number): Void
function updateScrollPosition(aiPosition: Number): Void
function UpdateList(): Void
function InvalidateData(): Void
function SetScrollbarVisibility(): Void
function CalculateMaxScrollPosition(): Void
function GetEntryHeight(aiEntryIndex: Number): Number
function moveSelectionUp(): Void
function moveSelectionDown(): Void
function onLoad(): Void
function onMouseWheel(delta: Number): Void
function onItemPress(aiKeyboardOrMouse: Number): Void
function onItemPressAux(aiKeyboardOrMouse: Number, aiButtonIndex: Number)
function onScroll(event: Object): Void
function SetEntry(aEntryClip: MovieClip, aEntryObject: Object): Void
function SetEntryText(aEntryClip: MovieClip, aEntryObject: Object): Void
Getters/Setters:
function get selectedIndex(): Number
function get listAnimating(): Boolean
function get selectedEntry(): Object
function get scrollPosition(): Number
function get maxScrollPosition(): Number
function get entryList(): Array
function get disableSelection(): Boolean
function get disableInput(): Boolean
function get maxEntries(): Number
function get textOption(): Number
*/
class Shared.BSScrollingList extends MovieClip
{
static var TEXT_OPTION_NONE: Number = 0;
static var TEXT_OPTION_SHRINK_TO_FIT: Number = 1;
static var TEXT_OPTION_MULTILINE: Number = 2;
var EntriesA: Array;
var scrollbar: Object;
var ListScrollbar: Object;
var ScrollDown: MovieClip;
var ScrollUp: MovieClip;
var border: MovieClip;
var bDisableInput: Boolean;
var bDisableSelection: Boolean;
var bListAnimating: Boolean;
var bMouseDrivenNav: Boolean;
var dispatchEvent: Function;
var onMousePress: Function;
var fListHeight: Number;
var iListItemsShown: Number;
var iMaxItemsShown: Number;
var iMaxScrollPosition: Number;
var iPlatform: Number;
var iScrollPosition: Number;
var iScrollbarDrawTimerID: Number;
var iSelectedIndex: Number;
var iHighlightedIndex: Number; // new
var iTextOption: Number;
var itemIndex: Number;
function BSScrollingList()
{
super();
EntriesA = new Array();
bDisableSelection = false;
bDisableInput = false;
bMouseDrivenNav = false;
EventDispatcher.initialize(this);
Mouse.addListener(this);
iSelectedIndex = -1;
iHighlightedIndex = -1;
iScrollPosition = 0;
iMaxScrollPosition = 0;
iListItemsShown = 0;
iPlatform = 1;
fListHeight = border._height;
ListScrollbar = scrollbar;
iMaxItemsShown = 0;
for (var item: MovieClip = GetClipByIndex(iMaxItemsShown); item != undefined; item = GetClipByIndex(++iMaxItemsShown)) {
item.clipIndex = iMaxItemsShown;
item.onRollOver = function ()
{
if (!_parent.listAnimating && !_parent.bDisableInput && itemIndex != undefined) {
//GlobalFunc.getInstance().Deebug("onRollOver() doSetSelectedIndex " + itemIndex);
_parent.doSetSelectedIndex(itemIndex, 0, true);
_parent.bMouseDrivenNav = true;
}
};
item.onPress = function (aiMouseIndex, aiKeyboardOrMouse)
{
if (itemIndex != undefined) {
//GlobalFunc.getInstance().Deebug("item::onPress() " + aiKeyboardOrMouse);
_parent.onItemPress(aiKeyboardOrMouse);
if (!_parent.bDisableInput && onMousePress != undefined)
onMousePress();
}
};
item.onPressAux = function (aiMouseIndex, aiKeyboardOrMouse, aiButtonIndex)
{
if (itemIndex != undefined)
_parent.onItemPressAux(aiKeyboardOrMouse, aiButtonIndex);
};
}
}
function onLoad(): Void
{
if (ListScrollbar != undefined) {
ListScrollbar.position = 0;
ListScrollbar.addEventListener("scroll", this, "onScroll");
}
}
function ClearList(): Void
{
EntriesA.splice(0, EntriesA.length);
}
function GetClipByIndex(aiIndex: Number): MovieClip
{
return this["Entry" + aiIndex];
}
function handleInput(details: InputDetails, pathToFocus: Array): Boolean
{
//GlobalFunc.getInstance().Deebug("handleInput() BSScrollingList");
var bHandledInput: Boolean = false;
if (!bDisableInput) {
var item: MovieClip = GetClipByIndex(selectedIndex - scrollPosition);
bHandledInput = item != undefined && item.handleInput != undefined && item.handleInput(details, pathToFocus.slice(1));
if (!bHandledInput && GlobalFunc.IsKeyPressed(details)) {
if (details.navEquivalent == NavigationCode.UP) {
moveSelectionUp();
bHandledInput = true;
} else if (details.navEquivalent == NavigationCode.DOWN) {
moveSelectionDown();
bHandledInput = true;
} else if (!bDisableSelection && details.navEquivalent == NavigationCode.ENTER) {
onItemPress();
bHandledInput = true;
}
}
}
return bHandledInput;
}
function onMouseWheel(delta: Number): Void
{
if (!bDisableInput) {
for (var target = Mouse.getTopMostEntity(); target && target != undefined; target = target._parent) {
if (target == this) {
doSetSelectedIndex(-1,0);
if (delta < 0)
scrollPosition = scrollPosition + 1;
else if (delta > 0)
scrollPosition = scrollPosition - 1;
}
}
}
}
function get selectedIndex(): Number
{
return iSelectedIndex;
}
function set selectedIndex(aiNewIndex: Number): Void
{
doSetSelectedIndex(aiNewIndex);
}
function get listAnimating(): Boolean
{
return bListAnimating;
}
function set listAnimating(abFlag: Boolean): Void
{
bListAnimating = abFlag;
}
//fabd++ The function can now set mouse highlight (visual) separately from the selected state
function doSetSelectedIndex(aiNewIndex:Number, aiKeyboardOrMouse: Number, abMouseFocus: Boolean): Void
{
// current focus is selectedindex, or mouse highlighted index (decoupled from selection)
var iCurHighlightIndex = iHighlightedIndex; // abMouseFocus ? iHighlightedIndex : iSelectedIndex;
if (!bDisableSelection) {
// change selectedIndex, unless explicitly doing the mouse highlighting
if (abMouseFocus !== true) {
iSelectedIndex = aiNewIndex;
}
if (aiNewIndex != iCurHighlightIndex) {
var iCurrentIndex: Number = iHighlightedIndex;
iHighlightedIndex = aiNewIndex;
//GlobalFunc.getInstance().Deebug("iHighlightedIndex = " + iHighlightedIndex);
if (iCurrentIndex != -1)
SetEntry(GetClipByIndex(EntriesA[iCurrentIndex].clipIndex), EntriesA[iCurrentIndex]);
if (iHighlightedIndex != -1) {
if (iPlatform != 0) {
if (iHighlightedIndex < iScrollPosition)
scrollPosition = iHighlightedIndex;
else if (iHighlightedIndex >= iScrollPosition + iListItemsShown)
scrollPosition = Math.min(iHighlightedIndex - iListItemsShown + 1, iMaxScrollPosition);
else
SetEntry(GetClipByIndex(EntriesA[iHighlightedIndex].clipIndex),EntriesA[iHighlightedIndex]);
} else {
SetEntry(GetClipByIndex(EntriesA[iHighlightedIndex].clipIndex),EntriesA[iHighlightedIndex]);
}
}
// note: this could have unwanted effects here, since highlighted is not always *selected*
// note: OR... dispatch only when selectedIndex changes... usually would want highlight change
dispatchEvent({type:"selectionChange", index:iHighlightedIndex, keyboardOrMouse:aiKeyboardOrMouse});
}
}
}
//fabd-- the old code for reference
/*
function doSetSelectedIndex(aiNewIndex:Number, aiKeyboardOrMouse: Number): Void
{
if (!bDisableSelection && aiNewIndex != iSelectedIndex) {
var iCurrentIndex: Number = iSelectedIndex;
iSelectedIndex = aiNewIndex;
if (iCurrentIndex != -1)
SetEntry(GetClipByIndex(EntriesA[iCurrentIndex].clipIndex),EntriesA[iCurrentIndex]);
if (iSelectedIndex != -1) {
if (iPlatform != 0) {
if (iSelectedIndex < iScrollPosition)
scrollPosition = iSelectedIndex;
else if (iSelectedIndex >= iScrollPosition + iListItemsShown)
scrollPosition = Math.min(iSelectedIndex - iListItemsShown + 1, iMaxScrollPosition);
else
SetEntry(GetClipByIndex(EntriesA[iSelectedIndex].clipIndex),EntriesA[iSelectedIndex]);
} else {
SetEntry(GetClipByIndex(EntriesA[iSelectedIndex].clipIndex),EntriesA[iSelectedIndex]);
}
}
dispatchEvent({type:"selectionChange", index:iSelectedIndex, keyboardOrMouse:aiKeyboardOrMouse});
}
}
*/
function get scrollPosition(): Number
{
return iScrollPosition;
}
function get maxScrollPosition(): Number
{
return iMaxScrollPosition;
}
function set scrollPosition(aiNewPosition: Number): Void
{
if (aiNewPosition != iScrollPosition && aiNewPosition >= 0 && aiNewPosition <= iMaxScrollPosition) {
if (ListScrollbar == undefined)
updateScrollPosition(aiNewPosition);
else
ListScrollbar.position = aiNewPosition;
}
}
function updateScrollPosition(aiPosition: Number): Void
{
iScrollPosition = aiPosition;
UpdateList();
}
function get selectedEntry(): Object
{
return EntriesA[iSelectedIndex];
}
function get entryList(): Array
{
return EntriesA;
}
function set entryList(anewArray: Array): Void
{
EntriesA = anewArray;
}
function get disableSelection(): Boolean
{
return bDisableSelection;
}
function set disableSelection(abFlag: Boolean): Void
{
bDisableSelection = abFlag;
}
function get disableInput(): Boolean
{
return bDisableInput;
}
function set disableInput(abFlag: Boolean): Void
{
bDisableInput = abFlag;
}
function get maxEntries(): Number
{
return iMaxItemsShown;
}
function get textOption(): Number
{
return iTextOption;
}
function set textOption(strNewOption: String): Void
{
if (strNewOption == "None")
iTextOption = Shared.BSScrollingList.TEXT_OPTION_NONE;
else if (strNewOption == "Shrink To Fit")
iTextOption = Shared.BSScrollingList.TEXT_OPTION_SHRINK_TO_FIT;
else if (strNewOption == "Multi-Line")
iTextOption = Shared.BSScrollingList.TEXT_OPTION_MULTILINE;
}
function UpdateList(): Void
{
var iFirstItemy: Number = GetClipByIndex(0)._y;
var iItemHeightSum: Number = 0;
var i: Number = 0;
while (i < iScrollPosition) {
EntriesA[i].clipIndex = undefined;
++i;
}
iListItemsShown = 0;
i = iScrollPosition;
while (i < EntriesA.length && iListItemsShown < iMaxItemsShown && iItemHeightSum <= fListHeight) {
var item: MovieClip = GetClipByIndex(iListItemsShown);
SetEntry(item, EntriesA[i]);
EntriesA[i].clipIndex = iListItemsShown;
item.itemIndex = i;
item._y = iFirstItemy + iItemHeightSum;
item._visible = true;
iItemHeightSum += item._height;
if (iItemHeightSum <= fListHeight && iListItemsShown < iMaxItemsShown)
++iListItemsShown;
++i;
}
var iLastItemIndex: Number = iListItemsShown;
while (iLastItemIndex < iMaxItemsShown) {
GetClipByIndex(iLastItemIndex)._visible = false;
++iLastItemIndex;
}
if (ScrollUp != undefined)
ScrollUp._visible = scrollPosition > 0;
if (ScrollDown != undefined)
ScrollDown._visible = scrollPosition < iMaxScrollPosition;
}
function InvalidateData(): Void
{
var iMaxScrollPos: Number = iMaxScrollPosition;
fListHeight = border._height;
CalculateMaxScrollPosition();
if (ListScrollbar != undefined) {
if (iMaxScrollPos == iMaxScrollPosition) {
SetScrollbarVisibility();
} else {
ListScrollbar._visible = false;
ListScrollbar.setScrollProperties(iMaxItemsShown, 0, iMaxScrollPosition);
if (iScrollbarDrawTimerID != undefined)
clearInterval(iScrollbarDrawTimerID);
iScrollbarDrawTimerID = setInterval(this, "SetScrollbarVisibility", 50);
}
}
if (iSelectedIndex >= EntriesA.length)
iSelectedIndex = EntriesA.length - 1;
if (iScrollPosition > iMaxScrollPosition)
iScrollPosition = iMaxScrollPosition;
UpdateList();
}
function SetScrollbarVisibility(): Void
{
clearInterval(iScrollbarDrawTimerID);
iScrollbarDrawTimerID = undefined;
ListScrollbar._visible = iMaxScrollPosition > 0;
}
function CalculateMaxScrollPosition(): Void
{
var iItemHeightSum: Number = 0;
var iLastItemIndex: Number = EntriesA.length - 1;
while (iLastItemIndex >= 0 && iItemHeightSum <= fListHeight) {
iItemHeightSum += GetEntryHeight(iLastItemIndex);
if (iItemHeightSum <= fListHeight)
--iLastItemIndex;
}
iMaxScrollPosition = iLastItemIndex + 1;
}
function GetEntryHeight(aiEntryIndex: Number): Number
{
var item: MovieClip = GetClipByIndex(0);
SetEntry(item, EntriesA[aiEntryIndex]);
return item._height;
}
function moveSelectionUp(): Void
{
if (!bDisableSelection) {
if (selectedIndex > 0)
selectedIndex = selectedIndex - 1;
return;
}
scrollPosition = scrollPosition - 1;
}
function moveSelectionDown(): Void
{
if (!bDisableSelection) {
if (selectedIndex < EntriesA.length - 1)
selectedIndex = selectedIndex + 1;
return;
}
scrollPosition = scrollPosition + 1;
}
/**
* MovieClip onPress() aiKeyboardOrMouse == 0
*
* If keyboard (handleInput), aiKeyboardOrMouse is undefined.
*
*/
function onItemPress(aiKeyboardOrMouse: Number): Void
{
if (!bDisableInput && !bDisableSelection && iSelectedIndex != -1) {
//GlobalFunc.getInstance().Deebug("onItemPress() aiKeyboardOrMouse = " + aiKeyboardOrMouse);
dispatchEvent({type: "itemPress", index: iSelectedIndex, entry: EntriesA[iSelectedIndex], keyboardOrMouse: aiKeyboardOrMouse});
return;
}
dispatchEvent({type: "listPress"});
}
function onItemPressAux(aiKeyboardOrMouse: Number, aiButtonIndex: Number)
{
if (!bDisableInput && !bDisableSelection && iSelectedIndex != -1 && aiButtonIndex == 1)
dispatchEvent({type: "itemPressAux", index: iSelectedIndex, entry: EntriesA[iSelectedIndex], keyboardOrMouse: aiKeyboardOrMouse});
}
// New: aSelectedEntry is based on highlighted index, which is not always selected index
function SetEntry(aEntryClip: MovieClip, aEntryObject: Object): Void
{
var aSelectedEntry: Object = EntriesA[iHighlightedIndex];
if (aEntryClip != undefined) {
if (aEntryObject == aSelectedEntry)
aEntryClip.gotoAndStop("Selected");
else
aEntryClip.gotoAndStop("Normal");
SetEntryText(aEntryClip, aEntryObject);
}
}
function SetEntryText(aEntryClip: MovieClip, aEntryObject: Object): Void
{
if (aEntryClip.textField != undefined) {
if (textOption == Shared.BSScrollingList.TEXT_OPTION_SHRINK_TO_FIT)
aEntryClip.textField.textAutoSize = "shrink";
else if (textOption == Shared.BSScrollingList.TEXT_OPTION_MULTILINE)
aEntryClip.textField.verticalAutoSize = "top";
if (aEntryObject.text == undefined)
aEntryClip.textField.SetText(" ");
else
aEntryClip.textField.SetText(aEntryObject.text);
if (aEntryObject.enabled != undefined)
aEntryClip.textField.textColor = aEntryObject.enabled == false ? 0x606060 : 0xFFFFFF;
if (aEntryObject.disabled != undefined)
aEntryClip.textField.textColor = aEntryObject.disabled == true ? 0x606060 : 0xFFFFFF;
}
}
function SetPlatform(aiPlatform: Number, abPS3Switch: Boolean): Void
{
iPlatform = aiPlatform;
bMouseDrivenNav = iPlatform == 0;
}
function onScroll(event: Object): Void
{
updateScrollPosition(Math.floor(event.position + 0.5));
}
}