This repository has been archived by the owner on May 18, 2022. It is now read-only.
-
Notifications
You must be signed in to change notification settings - Fork 75
/
KIP37.sol
610 lines (532 loc) · 17.7 KB
/
KIP37.sol
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
// SPDX-License-Identifier: MIT
pragma solidity ^0.5.0;
import "./IKIP37.sol";
import "./IKIP37MetadataURI.sol";
import "./IKIP37Receiver.sol";
import "./IERC1155Receiver.sol";
import "../../GSN/Context.sol";
import "../../introspection/KIP13.sol";
import "../../math/SafeMath.sol";
import "../../utils/Address.sol";
/**
*
* @dev Implementation of the basic standard multi-token.
* Originally based on code by Enjin: https://github.com/enjin/erc-1155
*/
contract KIP37 is Context, KIP13, IKIP37, IKIP37MetadataURI {
using SafeMath for uint256;
using Address for address;
// Mapping from token ID to account balances
mapping(uint256 => mapping(address => uint256)) private _balances;
// Mapping from account to operator approvals
mapping(address => mapping(address => bool)) private _operatorApprovals;
// Mapping from token ID to the total supply of the token
mapping(uint256 => uint256) private _totalSupply;
// Used as the URI for all token types by relying on ID substition, e.g. https://token-cdn-domain/{id}.json
string internal _uri;
/*
* bytes4(keccak256('balanceOf(address,uint256)')) == 0x00fdd58e
* bytes4(keccak256('balanceOfBatch(address[],uint256[])')) == 0x4e1273f4
* bytes4(keccak256('setApprovalForAll(address,bool)')) == 0xa22cb465
* bytes4(keccak256('isApprovedForAll(address,address)')) == 0xe985e9c5
* bytes4(keccak256('safeTransferFrom(address,address,uint256,uint256,bytes)')) == 0xf242432a
* bytes4(keccak256('safeBatchTransferFrom(address,address,uint256[],uint256[],bytes)')) == 0x2eb2c2d6
* bytes4(keccak256('totalSupply(uint256)')) == 0xbd85b039
*
* => 0x00fdd58e ^ 0x4e1273f4 ^ 0xa22cb465 ^
* 0xe985e9c5 ^ 0xf242432a ^ 0x2eb2c2d6 ^ 0xbd85b039 == 0x6433ca1f
*/
bytes4 private constant _INTERFACE_ID_KIP37 = 0x6433ca1f;
/*
* bytes4(keccak256('uri(uint256)')) == 0x0e89341c
*/
bytes4 private constant _INTERFACE_ID_KIP37_METADATA_URI = 0x0e89341c;
bytes4 private constant _INTERFACE_ID_KIP37_TOKEN_RECEIVER = 0x7cc2d017;
bytes4 private constant _INTERFACE_ID_ERC1155_TOKEN_RECEIVER = 0x4e2312e0;
// Equals to `bytes4(keccak256("onKIP37Received(address,address,uint256,uint256,bytes)"))`
// which can be also obtained as `IKIP37Receiver(0).onKIP37Received.selector`
bytes4 private constant _KIP37_RECEIVED = 0xe78b3325;
// Equals to `bytes4(keccak256("onERC1155Received(address,address,uint256,uint256,bytes)"))`
// which can be also obtained as `IERC1155Receiver(0).onERC1155Received.selector`
bytes4 private constant _ERC1155_RECEIVED = 0xf23a6e61;
// Equals to `bytes4(keccak256("onKIP37BatchReceived(address,address,uint256[],uint256[],bytes)"))`
// which can be also obtained as `IKIP37Receiver(0).onKIP37BatchReceived.selector`
bytes4 private constant _KIP37_BATCH_RECEIVED = 0x9b49e332;
// Equals to `bytes4(keccak256("onERC1155BatchReceived(address,address,uint256[],uint256[],bytes)"))`
// which can be also obtained as `IERC1155Receiver(0).onERC1155BatchReceived.selector`
bytes4 private constant _ERC1155_BATCH_RECEIVED = 0xbc197c81;
/**
* @dev See {_setURI}.
*/
constructor(string memory uri) public {
_setURI(uri);
// register the supported interfaces to conform to KIP37 via KIP13
_registerInterface(_INTERFACE_ID_KIP37);
// register the supported interfaces to conform to KIP37MetadataURI via KIP13
_registerInterface(_INTERFACE_ID_KIP37_METADATA_URI);
}
/**
* @dev See {IKIP37MetadataURI-uri}.
*
* This implementation returns the same URI for *all* token types. It relies
* on the token type ID substituion mechanism
* http://kips.klaytn.com/KIPs/kip-37#metadata
*
* Clients calling this function must replace the `\{id\}` substring with the
* actual token type ID.
*/
function uri(uint256) external view returns (string memory) {
return _uri;
}
/**
* @dev See {IKIP37-balanceOf}.
*
* Requirements:
*
* - `account` cannot be the zero address.
*/
function balanceOf(address account, uint256 id)
public
view
returns (uint256)
{
require(
account != address(0),
"KIP37: balance query for the zero address"
);
return _balances[id][account];
}
/**
* @dev See {IKIP37-balanceOfBatch}.
*
* Requirements:
*
* - `accounts` and `ids` must have the same length.
*/
function balanceOfBatch(address[] memory accounts, uint256[] memory ids)
public
view
returns (uint256[] memory)
{
require(
accounts.length == ids.length,
"KIP37: accounts and ids length mismatch"
);
uint256[] memory batchBalances = new uint256[](accounts.length);
for (uint256 i = 0; i < accounts.length; ++i) {
require(
accounts[i] != address(0),
"KIP37: batch balance query for the zero address"
);
batchBalances[i] = _balances[ids[i]][accounts[i]];
}
return batchBalances;
}
/**
* @dev See {IKIP37-setApprovalForAll}.
*/
function setApprovalForAll(address operator, bool approved) public {
require(
_msgSender() != operator,
"KIP37: setting approval status for self"
);
_operatorApprovals[_msgSender()][operator] = approved;
emit ApprovalForAll(_msgSender(), operator, approved);
}
/**
* @dev See {IKIP37-isApprovedForAll}.
*/
function isApprovedForAll(address account, address operator)
public
view
returns (bool)
{
return _operatorApprovals[account][operator];
}
function totalSupply(uint256 _tokenId) public view returns (uint256) {
return _totalSupply[_tokenId];
}
/**
* @dev See {IKIP37-safeTransferFrom}.
*/
function safeTransferFrom(
address from,
address to,
uint256 id,
uint256 amount,
bytes memory data
) public {
require(to != address(0), "KIP37: transfer to the zero address");
require(
from == _msgSender() || isApprovedForAll(from, _msgSender()),
"KIP37: caller is not owner nor approved"
);
address operator = _msgSender();
_beforeTokenTransfer(
operator,
from,
to,
_asSingletonArray(id),
_asSingletonArray(amount),
data
);
_balances[id][from] = _balances[id][from].sub(
amount,
"KIP37: insufficient balance for transfer"
);
_balances[id][to] = _balances[id][to].add(amount);
emit TransferSingle(operator, from, to, id, amount);
require(
_doSafeTransferAcceptanceCheck(
operator,
from,
to,
id,
amount,
data
),
"KIP37: transfer to non KIP37Receiver implementer"
);
}
/**
* @dev See {IKIP37-safeBatchTransferFrom}.
*/
function safeBatchTransferFrom(
address from,
address to,
uint256[] memory ids,
uint256[] memory amounts,
bytes memory data
) public {
require(
ids.length == amounts.length,
"KIP37: ids and amounts length mismatch"
);
require(to != address(0), "KIP37: transfer to the zero address");
require(
from == _msgSender() || isApprovedForAll(from, _msgSender()),
"KIP37: transfer caller is not owner nor approved"
);
address operator = _msgSender();
_beforeTokenTransfer(operator, from, to, ids, amounts, data);
for (uint256 i = 0; i < ids.length; ++i) {
uint256 id = ids[i];
uint256 amount = amounts[i];
_balances[id][from] = _balances[id][from].sub(
amount,
"KIP37: insufficient balance for transfer"
);
_balances[id][to] = _balances[id][to].add(amount);
}
emit TransferBatch(operator, from, to, ids, amounts);
require(
_doSafeBatchTransferAcceptanceCheck(
operator,
from,
to,
ids,
amounts,
data
),
"KIP37: batch transfer to non KIP37Receiver implementer"
);
}
/**
* @dev Sets a new URI for all token types, by relying on the token type ID
* substituion mechanism
* http://kips.klaytn.com/KIPs/kip-37#metadata.
*
* By this mechanism, any occurence of the `\{id\}` substring in either the
* URI or any of the amounts in the JSON file at said URI will be replaced by
* clients with the token type ID.
*
* For example, the `https://token-cdn-domain/\{id\}.json` URI would be
* interpreted by clients as
* `https://token-cdn-domain/000000000000000000000000000000000000000000000000000000000004cce0.json`
* for token type ID 0x4cce0.
*
* See {uri}.
*
* Because these URIs cannot be meaningfully represented by the {URI} event,
* this function emits no events.
*/
function _setURI(string memory newuri) internal {
_uri = newuri;
}
/**
* @dev Creates `amount` tokens of token type `id`, and assigns them to `account`.
*
* Emits a {TransferSingle} event.
*
* Requirements:
*
* - `account` cannot be the zero address.
* - If `to` refers to a smart contract, it must implement {IKIP37Receiver-onKIP37Received} and return the
* acceptance magic value.
*/
function _mint(
address account,
uint256 id,
uint256 amount,
bytes memory data
) internal {
require(account != address(0), "KIP37: mint to the zero address");
address operator = _msgSender();
_beforeTokenTransfer(
operator,
address(0),
account,
_asSingletonArray(id),
_asSingletonArray(amount),
data
);
_balances[id][account] = _balances[id][account].add(amount);
_totalSupply[id] = _totalSupply[id].add(amount);
emit TransferSingle(operator, address(0), account, id, amount);
require(
_doSafeTransferAcceptanceCheck(
operator,
address(0),
account,
id,
amount,
data
),
"KIP37: transfer to non KIP37Receiver implementer"
);
}
/**
* @dev Batch-operations version of {_mint}.
*
* Requirements:
*
* - `ids` and `amounts` must have the same length.
* - If `to` refers to a smart contract, it must implement {IKIP37Receiver-onKIP37BatchReceived} and return the
* acceptance magic value.
*/
function _mintBatch(
address to,
uint256[] memory ids,
uint256[] memory amounts,
bytes memory data
) internal {
require(to != address(0), "KIP37: mint to the zero address");
require(
ids.length == amounts.length,
"KIP37: ids and amounts length mismatch"
);
address operator = _msgSender();
_beforeTokenTransfer(operator, address(0), to, ids, amounts, data);
for (uint256 i = 0; i < ids.length; i++) {
_balances[ids[i]][to] = amounts[i].add(_balances[ids[i]][to]);
_totalSupply[ids[i]] = amounts[i].add(_totalSupply[ids[i]]);
}
emit TransferBatch(operator, address(0), to, ids, amounts);
require(
_doSafeBatchTransferAcceptanceCheck(
operator,
address(0),
to,
ids,
amounts,
data
),
"KIP37: batch transfer to non KIP37Receiver implementer"
);
}
/**
* @dev Destroys `amount` tokens of token type `id` from `account`
*
* Requirements:
*
* - `account` cannot be the zero address.
* - `account` must have at least `amount` tokens of token type `id`.
*/
function _burn(
address account,
uint256 id,
uint256 amount
) internal {
require(account != address(0), "KIP37: burn from the zero address");
address operator = _msgSender();
_beforeTokenTransfer(
operator,
account,
address(0),
_asSingletonArray(id),
_asSingletonArray(amount),
""
);
_balances[id][account] = _balances[id][account].sub(
amount,
"KIP37: burn amount exceeds balance"
);
_totalSupply[id] = _totalSupply[id].sub(
amount,
"KIP37: burn amount exceeds total supply"
);
emit TransferSingle(operator, account, address(0), id, amount);
}
/**
* @dev Batch-operations version of {_burn}.
*
* Requirements:
*
* - `ids` and `amounts` must have the same length.
*/
function _burnBatch(
address account,
uint256[] memory ids,
uint256[] memory amounts
) internal {
require(account != address(0), "KIP37: burn from the zero address");
require(
ids.length == amounts.length,
"KIP37: ids and amounts length mismatch"
);
address operator = _msgSender();
_beforeTokenTransfer(operator, account, address(0), ids, amounts, "");
for (uint256 i = 0; i < ids.length; i++) {
_balances[ids[i]][account] = _balances[ids[i]][account].sub(
amounts[i],
"KIP37: burn amount exceeds balance"
);
_totalSupply[ids[i]] = _totalSupply[ids[i]].sub(
amounts[i],
"KIP37: burn amount exceeds total supply"
);
}
emit TransferBatch(operator, account, address(0), ids, amounts);
}
/**
* @dev Hook that is called before any token transfer. This includes minting
* and burning, as well as batched variants.
*
* The same hook is called on both single and batched variants. For single
* transfers, the length of the `id` and `amount` arrays will be 1.
*
* Calling conditions (for each `id` and `amount` pair):
*
* - When `from` and `to` are both non-zero, `amount` of ``from``'s tokens
* of token type `id` will be transferred to `to`.
* - When `from` is zero, `amount` tokens of token type `id` will be minted
* for `to`.
* - when `to` is zero, `amount` of ``from``'s tokens of token type `id`
* will be burned.
* - `from` and `to` are never both zero.
* - `ids` and `amounts` have the same, non-zero length.
*
* To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
*/
function _beforeTokenTransfer(
address operator,
address from,
address to,
uint256[] memory ids,
uint256[] memory amounts,
bytes memory data
) internal {}
function _doSafeTransferAcceptanceCheck(
address operator,
address from,
address to,
uint256 id,
uint256 amount,
bytes memory data
) private returns (bool) {
bool success;
bytes memory returndata;
if (!to.isContract()) {
return true;
}
(success, returndata) = to.call(
abi.encodeWithSelector(
_ERC1155_RECEIVED,
operator,
from,
id,
amount,
data
)
);
if (
returndata.length != 0 &&
abi.decode(returndata, (bytes4)) == _ERC1155_RECEIVED
) {
return true;
}
(success, returndata) = to.call(
abi.encodeWithSelector(
_KIP37_RECEIVED,
operator,
from,
id,
amount,
data
)
);
if (
returndata.length != 0 &&
abi.decode(returndata, (bytes4)) == _KIP37_RECEIVED
) {
return true;
}
return false;
}
function _doSafeBatchTransferAcceptanceCheck(
address operator,
address from,
address to,
uint256[] memory ids,
uint256[] memory amounts,
bytes memory data
) private returns (bool) {
bool success;
bytes memory returndata;
if (!to.isContract()) {
return true;
}
(success, returndata) = to.call(
abi.encodeWithSelector(
_ERC1155_BATCH_RECEIVED,
operator,
from,
ids,
amounts,
data
)
);
if (
returndata.length != 0 &&
abi.decode(returndata, (bytes4)) == _ERC1155_BATCH_RECEIVED
) {
return true;
}
(success, returndata) = to.call(
abi.encodeWithSelector(
_KIP37_BATCH_RECEIVED,
operator,
from,
ids,
amounts,
data
)
);
if (
returndata.length != 0 &&
abi.decode(returndata, (bytes4)) == _KIP37_BATCH_RECEIVED
) {
return true;
}
return false;
}
function _asSingletonArray(uint256 element)
private
pure
returns (uint256[] memory)
{
uint256[] memory array = new uint256[](1);
array[0] = element;
return array;
}
}