* add cfitiso

cfitiso/PKGBUILD

@@ -0,0 +1,40 @@
+# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
+# Maintainer:
+# Contributor: Andrea Scarpino <andrea@archlinux.org>
+# Contributor: Tobias Powalowski <tpowa@archlinux.org>
+
+pkgname=cfitsio
+pkgver=3.450
+pkgrel=1
+pkgdesc="A library of C and Fortran subroutines for reading and writing data files in FITS (Flexible Image Transport System) data format"
+arch=(x86_64 powerpc64le)
+url="https://heasarc.gsfc.nasa.gov/fitsio/"
+license=(custom)
+depends=(curl)
+source=("https://heasarc.gsfc.nasa.gov/FTP/software/fitsio/c/${pkgname}${pkgver/./}.tar.gz")
+sha256sums=('bf6012dbe668ecb22c399c4b7b2814557ee282c74a7d5dc704eb17c30d9fb92e')
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --enable-reentrant
+  make shared
+  make utils
+}
+
+check() {
+  cd $pkgname
+  LD_LIBRARY_PATH=. ./testprog > testprog.lis
+  [[ -z $(diff testprog.lis testprog.out) ]] || return 1
+  [[ -z $(cmp testprog.fit testprog.std) ]] || return 1
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+
+  install -D -m644 License.txt \
+    "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+
+# Fix conflicts with ccfits and smem
+  rm "$pkgdir"/usr/bin/{cookbook,smem,testprog}
+}