* add mobile-broadband-provider-info

mobile-broadband-provider-info/PKGBUILD

@@ -0,0 +1,43 @@
+# POWER Maintainer: Alexander Baldeck <alex.bldck@gmail.com>
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+# Maintainer: Jan de Groot <jgc@archlinux.org>
+
+pkgname=mobile-broadband-provider-info
+pkgver=20190116
+pkgrel=1
+pkgdesc="Network Management daemon"
+url="https://gitlab.gnome.org/GNOME/mobile-broadband-provider-info"
+arch=(any)
+license=(custom)
+makedepends=(git)
+checkdepends=(libxml2)
+_commit=c7def60ba50d9cc30a90f69f89d7e82243501e86  # tags/20190116^0
+source=("git+https://gitlab.gnome.org/GNOME/mobile-broadband-provider-info.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
+}