-
Notifications
You must be signed in to change notification settings - Fork 83
/
watch.clj
336 lines (293 loc) · 13.2 KB
/
watch.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
(ns kaocha.watch
(:refer-clojure :exclude [symbol])
(:require [clojure.java.io :as io]
[clojure.set :as set]
[clojure.spec.alpha :as s]
[clojure.stacktrace :as st]
[clojure.string :as str]
[clojure.test :as t]
[hawk.core :as hawk]
[kaocha.api :as api]
[kaocha.config :as config]
[kaocha.core-ext :refer :all]
[kaocha.load :as load]
[kaocha.output :as output]
[kaocha.plugin :refer [defplugin]]
[kaocha.plugin :as plugin]
[kaocha.result :as result]
[kaocha.stacktrace :as stacktrace]
[kaocha.testable :as testable]
[kaocha.util :as util]
[lambdaisland.tools.namespace.dir :as ctn-dir]
[lambdaisland.tools.namespace.file :as ctn-file]
[lambdaisland.tools.namespace.parse :as ctn-parse]
[lambdaisland.tools.namespace.reload :as ctn-reload]
[lambdaisland.tools.namespace.track :as ctn-track]
[nextjournal.beholder :as beholder])
(:import [java.nio.file FileSystems]
[java.util.concurrent ArrayBlockingQueue BlockingQueue]))
(defn make-queue []
(ArrayBlockingQueue. 1024))
(defn qput [^BlockingQueue q x]
(.put q x))
(defn qpoll [^BlockingQueue q]
(.poll q))
(defn qtake [^BlockingQueue q]
(.take q))
(defn drain-queue! [q]
(doall (take-while identity (repeatedly #(qpoll q)))))
(defn- try-run [config focus tracker]
(let [config (if (seq focus)
(assoc config :kaocha.filter/focus focus)
config)
config (-> config
(assoc ::focus focus)
(assoc ::tracker tracker)
(update :kaocha/plugins #(cons ::plugin %)))
result (try
(api/run config)
(catch Throwable t
(println "[watch] Fatal error in test run" t)))]
(println)
result))
(defn track-reload! [tracker]
(ctn-reload/track-reload (assoc tracker ::ctn-file/load-error {})))
(defn print-scheduled-operations! [tracker focus]
(let [unload (set (::ctn-track/unload tracker))
load (set (::ctn-track/load tracker))
reload (set/intersection unload load)
unload (set/difference unload reload)
load (set/difference load reload)]
(when (seq unload)
(println "[watch] Unloading" unload))
(when (seq load)
(println "[watch] Loading" load))
(when (seq reload)
(println "[watch] Reloading" reload))
(when (seq focus)
(println "[watch] Re-running failed tests" (set focus)))))
(defn drain-and-rescan! [q tracker watch-paths]
(drain-queue! q)
(ctn-dir/scan-dirs tracker watch-paths))
(defn glob?
"Does path match any of the glob patterns.
See [FileSystem/getPathMatcher](https://docs.oracle.com/javase/7/docs/api/java/nio/file/FileSystem.html#getPathMatcher(java.lang.String))
for a description of the patterns, these are similar but not the same as
typical shell glob patterns."
[path patterns]
(let [fs (FileSystems/getDefault)
patterns (map #(.getPathMatcher fs (str "glob:" %)) patterns)]
(some #(.matches % path) patterns)))
(defn convert
"Converts a Git-style ignore pattern into the equivalent pattern that Java PathMatcher uses."
[pattern]
(let [cleaned (-> pattern
;; If a Git pattern has a trailing space, it should be stripped (unless escaped)
;; Example: 'src/test ' => 'src/test'
(str/replace #"([^\\]) +$" "$1")
;; If a Git pattern contains a double star bordering no path
;; separators, it basically functions as a single star, AFAICT:
;; Per the man page: "Other consecutive asterisks are
;; considered regular asterisks and will match according to the
;; previous rules." ("other consecutive asterisks" = not
;; preceded, followed, or surounded by separators)
;;
(str/replace #"[^/][*][*][^/]" "*")
;; If a Git pattern contains a double star between path
;; separators, that means zero or more intervening directories.
;;(Java treats this as at least one directory because the path
;; separators are interpreted literally.)
;; Exmple: 'src/**/test' => 'src**test'
(str/replace #"/[*][*]/" "**")
;; If a Git pattern contains braces, those should be treated literally
;; Example: src/{ill-advised-filename}.clj => src/\{ill-advised-filename\}.clj
;; (re-find #"[{}]" pattern) (str/replace pattern #"\{(.*)\}" "\\\\{$1\\\\}" )
(str/replace #"\{(.*)\}" "\\\\{$1\\\\}"))]
(cond->> cleaned
;; If it starts with a single *, it should have **
;; Example: *.html => **.html
(re-find #"^\*[^*]" cleaned) (format "*%s")
;; If a Git pattern ends with a slash, that represents everything underneath
;; Example: src/ => src/**
(re-find #"/$" cleaned) (format "%s**")
;; Otherwise, it should have the same behavior
)))
(s/fdef convert :args (s/cat :pattern string?) :ret string?)
(defn parse-ignore-file
"Parses an individual ignore file."
[file]
(->> (slurp file)
(str/split-lines)
;; filter out comments, which need to be ignored, and negated patterns, which need to be handled separately:
(filter #(not (re-find #"^[!#]" %)))
(map #(convert %))))
(defn find-ignore-files
"Finds ignore files in the local directory and the system."
[dir]
(let [absolute-files [(io/file (str (System/getProperty "user.home") "/.config/git/ignore"))]
relative-files (filter #(glob? (.toPath %) ["**.gitignore" "**.ignore"]) (file-seq (io/file dir)))]
(into absolute-files relative-files)))
(defn merge-ignore-files
"Combines and parses ignore files."
[dir]
(let [all-files (find-ignore-files dir)]
(mapcat #(when (.exists (io/file %)) (parse-ignore-file %)) all-files)))
(s/fdef merge-ignore-files
:args (s/cat :dir string?)
:ret (s/coll-of string?))
(defn wait-and-rescan! [q tracker watch-paths ignore]
(let [f (qtake q)]
(cond
(and (file? f) (glob? (.toPath f) ignore))
(recur q tracker watch-paths ignore)
(directory? f)
(recur q tracker watch-paths ignore)
(= :finish f)
[tracker f]
:else
[(drain-and-rescan! q tracker watch-paths) f])))
(defn reload-config [config plugin-chain]
(if-let [config-file (get-in config [:kaocha/cli-options :config-file])]
(let [{:kaocha/keys [cli-options cli-args]} config
config (-> config-file
(config/load-config)
(config/apply-cli-opts cli-options)
(config/apply-cli-args cli-args))
plugin-chain (plugin/load-all (concat (:kaocha/plugins config) (:plugin cli-options)))]
[config plugin-chain])
[config plugin-chain]))
(defn run-loop [finish? config tracker q watch-paths]
(loop [tracker tracker
config config
plugin-chain plugin/*current-chain*
focus nil]
(when-not @finish?
(let [result (try-run config focus tracker)
tracker (::tracker result)
error? (::error? result)
ignore (if (::use-ignore-file config)
(into (::ignore config)
(merge-ignore-files "."))
(::ignore config))]
(cond
error?
(do
(println "[watch] Error reloading, all tests skipped.")
(let [[tracker _] (wait-and-rescan! q tracker watch-paths ignore)
[config plugin-chain] (reload-config config plugin-chain)]
(recur tracker config plugin-chain nil)))
(and (seq focus) (not (result/failed? result)))
(do
(println "[watch] Failed tests pass, re-running all tests.")
(recur (drain-and-rescan! q tracker watch-paths) config plugin-chain nil))
:else
(let [[tracker trigger] (wait-and-rescan! q tracker watch-paths ignore)
[config plugin-chain] (reload-config config plugin-chain)
focus (when-not (= :enter trigger)
(->> result
testable/test-seq
(filter result/failed-one?)
(map ::testable/id)))]
(recur tracker config plugin-chain focus)))))))
(defplugin kaocha.watch/plugin
"This is an internal plugin, don't use it directly.
Behind the scenes we add this plugin to the start of the plugin chain. It takes
care of reloading namespaces inside a Kaocha run, so we can report any load
errors as test errors."
(pre-load [{::keys [tracker focus] :as config}]
(print-scheduled-operations! tracker focus)
(let [tracker (track-reload! tracker)
config (assoc config ::tracker tracker)
error (::ctn-reload/error tracker)
error-ns (::ctn-reload/error-ns tracker)
load-error (::ctn-file/load-error tracker)]
(if (and error error-ns)
(let [[file line] (util/compiler-exception-file-and-line error)]
(-> config
(assoc ::error? true)
(update :kaocha/tests
(fn [suites]
;; We don't really know which suite the load error
;; belongs to, it could well be in a file shared by all
;; suites, so we arbitrarily put the load error on the
;; first and skip the rest, so that it gets reported
;; properly.
(into [(assoc (first suites)
::testable/load-error error
::testable/load-error-file (or file (util/ns-file error-ns))
::testable/load-error-line line
::testable/load-error-message (str "Failed reloading " error-ns ":"))]
(map #(assoc % ::testable/skip true))
(rest suites))))))
config))))
(defn watch-paths [config]
(into #{}
(comp (remove :kaocha.testable/skip)
(map (juxt :kaocha/test-paths :kaocha/source-paths))
cat
cat
(map io/file))
(:kaocha/tests config)))
(defmulti watch! :type)
(defmethod watch! :hawk [{:keys [q watch-paths opts]}]
(hawk/watch! opts
[{:paths watch-paths
:handler (fn [ctx event]
(when (= (:kind event) :modify)
(qput q (:file event))))}]))
(defmethod watch! :beholder [{:keys [q watch-paths]}]
(apply beholder/watch
(fn [{:keys [type path]}]
(when (contains? #{:modify :create} type)
(qput q path)))
(map str watch-paths)))
(defn run* [config finish? q]
(let [watcher-type (::type config :beholder)
watcher-opts (condp = watcher-type
:hawk (::hawk-opts config {})
:beholder {} ;; beholder does not take opts
{})
watch-paths (if (:kaocha.watch/use-ignore-file config)
(set/union (watch-paths config)
(set (map #(.getParentFile (.getCanonicalFile %)) (find-ignore-files "."))))
(watch-paths config))
tracker (-> (ctn-track/tracker)
(ctn-dir/scan-dirs watch-paths)
(dissoc :lambdaisland.tools.namespace.track/unload
:lambdaisland.tools.namespace.track/load))]
(when (or (= watcher-type :hawk) (::hawk-opts config))
(output/warn "Hawk watcher is deprecated in favour of Beholder. Kaocha will soon get rid of Hawk completely."))
(watch! {:type watcher-type
:q q
:watch-paths watch-paths
:opts watcher-opts})
(when-let [config-file (get-in config [:kaocha/cli-options :config-file])]
(when (.exists (io/file config-file))
(watch! {:type watcher-type
:q q
:watch-paths #{config-file}
:opts watcher-opts})))
(future
(let [stdin (io/reader System/in)]
(while (not @finish?)
(if (and (.ready stdin) (= (.read stdin) (long \newline)))
(qput q :enter)
(Thread/sleep 100)))))
(run-loop finish? config tracker q watch-paths)))
(defn run [config]
(let [finish? (atom false)
q (make-queue)
finish! (fn []
(reset! finish? true)
(qput q :finish))
bfn (bound-fn []
(try
(run* config finish? q)
0
(catch Throwable t
(st/print-cause-trace t)
-3)
(finally
(println "[watch] watching stopped."))))
exit-code (future (bfn))]
[exit-code finish!]))