-
Notifications
You must be signed in to change notification settings - Fork 251
/
InvariantForm.lean
208 lines (177 loc) · 8.36 KB
/
InvariantForm.lean
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
/-
Copyright (c) 2024 Johan Commelin. All rights reserved.
Released under Apache 2.0 license as described in the file LICENSE.
Authors: Johan Commelin
-/
import Mathlib.Algebra.Lie.Semisimple.Defs
import Mathlib.LinearAlgebra.BilinearForm.Orthogonal
/-!
# Lie algebras with non-degenerate invariant bilinear forms are semisimple
In this file we prove that a finite-dimensional Lie algebra over a field is semisimple
if it does not have non-trivial abelian ideals and it admits a
non-degenerate reflexive invariant bilinear form.
Here a form is *invariant* if it invariant under the Lie bracket
in the sense that `⁅x, Φ⁆ = 0` for all `x` or equivalently, `Φ ⁅x, y⁆ z = Φ x ⁅y, z⁆`.
## Main results
* `LieAlgebra.InvariantForm.orthogonal`: given a Lie submodule `N` of a Lie module `M`,
we define its orthogonal complement with respect to a non-degenerate invariant bilinear form `Φ`
as the Lie ideal of elements `x` such that `Φ n x = 0` for all `n ∈ N`.
* `LieAlgebra.InvariantForm.isSemisimple_of_nondegenerate`: the main result of this file;
a finite-dimensional Lie algebra over a field is semisimple
if it does not have non-trivial abelian ideals and admits
a non-degenerate invariant reflexive bilinear form.
## References
We follow the short and excellent paper [dieudonne1953].
-/
namespace LieAlgebra
namespace InvariantForm
section ring
variable {R L M : Type*}
variable [CommRing R] [LieRing L] [LieAlgebra R L]
variable [AddCommGroup M] [Module R M] [LieRingModule L M]
variable (Φ : LinearMap.BilinForm R M) (hΦ_nondeg : Φ.Nondegenerate)
variable (L) in
/--
A bilinear form on a Lie module `M` of a Lie algebra `L` is *invariant* if
for all `x : L` and `y z : M` the condition `Φ ⁅x, y⁆ z = -Φ y ⁅x, z⁆` holds.
-/
def _root_.LinearMap.BilinForm.lieInvariant : Prop :=
∀ (x : L) (y z : M), Φ ⁅x, y⁆ z = -Φ y ⁅x, z⁆
lemma _root_.LinearMap.BilinForm.lieInvariant_iff [LieModule R L M] :
Φ.lieInvariant L ↔ Φ ∈ LieModule.maxTrivSubmodule R L (LinearMap.BilinForm R M) := by
refine ⟨fun h x ↦ ?_, fun h x y z ↦ ?_⟩
· ext y z
rw [LieHom.lie_apply, LinearMap.sub_apply, Module.Dual.lie_apply, LinearMap.zero_apply,
LinearMap.zero_apply, h, sub_self]
· replace h := LinearMap.congr_fun₂ (h x) y z
simp only [LieHom.lie_apply, LinearMap.sub_apply, Module.Dual.lie_apply,
LinearMap.zero_apply, sub_eq_zero] at h
simp [← h]
variable (hΦ_inv : Φ.lieInvariant L)
/--
The orthogonal complement of a Lie submodule `N` with respect to an invariant bilinear form `Φ` is
the Lie submodule of elements `y` such that `Φ x y = 0` for all `x ∈ N`.
-/
@[simps!]
def orthogonal (N : LieSubmodule R L M) : LieSubmodule R L M where
__ := Φ.orthogonal N
lie_mem {x y} := by
suffices (∀ n ∈ N, Φ n y = 0) → ∀ n ∈ N, Φ n ⁅x, y⁆ = 0 by
simpa only [LinearMap.BilinForm.isOrtho_def, -- and some default simp lemmas
AddSubsemigroup.mem_carrier, AddSubmonoid.mem_toSubsemigroup, Submodule.mem_toAddSubmonoid,
LinearMap.BilinForm.mem_orthogonal_iff, LieSubmodule.mem_coeSubmodule]
intro H a ha
rw [← neg_eq_zero, ← hΦ_inv]
exact H _ <| N.lie_mem ha
@[simp]
lemma orthogonal_toSubmodule (N : LieSubmodule R L M) :
(orthogonal Φ hΦ_inv N).toSubmodule = Φ.orthogonal N.toSubmodule := rfl
lemma mem_orthogonal (N : LieSubmodule R L M) (y : M) :
y ∈ orthogonal Φ hΦ_inv N ↔ ∀ x ∈ N, Φ x y = 0 := by
simp [orthogonal, LinearMap.BilinForm.isOrtho_def, LinearMap.BilinForm.mem_orthogonal_iff]
lemma orthogonal_disjoint
(Φ : LinearMap.BilinForm R L) (hΦ_nondeg : Φ.Nondegenerate) (hΦ_inv : Φ.lieInvariant L)
-- TODO: replace the following assumption by a typeclass assumption `[HasNonAbelianAtoms]`
(hL : ∀ I : LieIdeal R L, IsAtom I → ¬IsLieAbelian I)
(I : LieIdeal R L) (hI : IsAtom I) :
Disjoint I (orthogonal Φ hΦ_inv I) := by
rw [disjoint_iff, ← hI.lt_iff, lt_iff_le_and_ne]
suffices ¬I ≤ orthogonal Φ hΦ_inv I by simpa
intro contra
apply hI.1
rw [eq_bot_iff, ← lie_eq_self_of_isAtom_of_nonabelian I hI (hL I hI),
LieSubmodule.lieIdeal_oper_eq_span, LieSubmodule.lieSpan_le]
rintro _ ⟨x, y, rfl⟩
simp only [LieSubmodule.bot_coe, Set.mem_singleton_iff]
apply hΦ_nondeg
intro z
rw [hΦ_inv, neg_eq_zero]
have hyz : ⁅(x : L), z⁆ ∈ I := lie_mem_left _ _ _ _ _ x.2
exact contra hyz y y.2
end ring
section field
variable {K L M : Type*}
variable [Field K] [LieRing L] [LieAlgebra K L]
variable [AddCommGroup M] [Module K M] [LieRingModule L M]
variable [Module.Finite K L]
variable (Φ : LinearMap.BilinForm K L) (hΦ_nondeg : Φ.Nondegenerate)
variable (hΦ_inv : Φ.lieInvariant L) (hΦ_refl : Φ.IsRefl)
-- TODO: replace the following assumption by a typeclass assumption `[HasNonAbelianAtoms]`
variable (hL : ∀ I : LieIdeal K L, IsAtom I → ¬IsLieAbelian I)
open FiniteDimensional Submodule in
lemma orthogonal_isCompl_coe_submodule (I : LieIdeal K L) (hI : IsAtom I) :
IsCompl I.toSubmodule (orthogonal Φ hΦ_inv I).toSubmodule := by
rw [orthogonal_toSubmodule, LinearMap.BilinForm.isCompl_orthogonal_iff_disjoint hΦ_refl,
← orthogonal_toSubmodule _ hΦ_inv, ← LieSubmodule.disjoint_iff_coe_toSubmodule]
exact orthogonal_disjoint Φ hΦ_nondeg hΦ_inv hL I hI
open FiniteDimensional Submodule in
lemma orthogonal_isCompl (I : LieIdeal K L) (hI : IsAtom I) :
IsCompl I (orthogonal Φ hΦ_inv I) := by
rw [LieSubmodule.isCompl_iff_coe_toSubmodule]
exact orthogonal_isCompl_coe_submodule Φ hΦ_nondeg hΦ_inv hΦ_refl hL I hI
lemma restrict_nondegenerate (I : LieIdeal K L) (hI : IsAtom I) :
(Φ.restrict I).Nondegenerate := by
rw [LinearMap.BilinForm.restrict_nondegenerate_iff_isCompl_orthogonal hΦ_refl]
exact orthogonal_isCompl_coe_submodule Φ hΦ_nondeg hΦ_inv hΦ_refl hL I hI
lemma restrict_orthogonal_nondegenerate (I : LieIdeal K L) (hI : IsAtom I) :
(Φ.restrict (orthogonal Φ hΦ_inv I)).Nondegenerate := by
rw [LinearMap.BilinForm.restrict_nondegenerate_iff_isCompl_orthogonal hΦ_refl]
simp only [LieIdeal.coe_to_lieSubalgebra_to_submodule, orthogonal_toSubmodule,
LinearMap.BilinForm.orthogonal_orthogonal hΦ_nondeg hΦ_refl]
exact (orthogonal_isCompl_coe_submodule Φ hΦ_nondeg hΦ_inv hΦ_refl hL I hI).symm
open FiniteDimensional Submodule in
lemma atomistic : ∀ I : LieIdeal K L, sSup {J : LieIdeal K L | IsAtom J ∧ J ≤ I} = I := by
intro I
apply le_antisymm
· apply sSup_le
rintro J ⟨-, hJ'⟩
exact hJ'
by_cases hI : I = ⊥
· exact hI.le.trans bot_le
obtain ⟨J, hJ, hJI⟩ := (eq_bot_or_exists_atom_le I).resolve_left hI
let J' := orthogonal Φ hΦ_inv J
suffices I ≤ J ⊔ (J' ⊓ I) by
refine this.trans ?_
apply sup_le
· exact le_sSup ⟨hJ, hJI⟩
rw [← atomistic (J' ⊓ I)]
apply sSup_le_sSup
simp only [le_inf_iff, Set.setOf_subset_setOf, and_imp]
tauto
suffices J ⊔ J' = ⊤ by rw [← sup_inf_assoc_of_le _ hJI, this, top_inf_eq]
exact (orthogonal_isCompl Φ hΦ_nondeg hΦ_inv hΦ_refl hL J hJ).codisjoint.eq_top
termination_by I => finrank K I
decreasing_by
apply finrank_lt_finrank_of_lt
suffices ¬I ≤ J' by simpa
intro hIJ'
apply hJ.1
rw [eq_bot_iff]
exact orthogonal_disjoint Φ hΦ_nondeg hΦ_inv hL J hJ le_rfl (hJI.trans hIJ')
open LieSubmodule in
/--
A finite-dimensional Lie algebra over a field is semisimple
if it does not have non-trivial abelian ideals and it admits a
non-degenerate reflexive invariant bilinear form.
Here a form is *invariant* if it is compatible with the Lie bracket: `Φ ⁅x, y⁆ z = Φ x ⁅y, z⁆`.
-/
theorem isSemisimple_of_nondegenerate : IsSemisimple K L := by
refine ⟨?_, ?_, hL⟩
· simpa using atomistic Φ hΦ_nondeg hΦ_inv hΦ_refl hL ⊤
intro I hI
apply (orthogonal_disjoint Φ hΦ_nondeg hΦ_inv hL I hI).mono_right
apply sSup_le
simp only [Set.mem_diff, Set.mem_setOf_eq, Set.mem_singleton_iff, and_imp]
intro J hJ hJI
rw [← lie_eq_self_of_isAtom_of_nonabelian J hJ (hL J hJ), lieIdeal_oper_eq_span, lieSpan_le]
rintro _ ⟨x, y, rfl⟩
simp only [orthogonal_carrier, Φ.isOrtho_def, Set.mem_setOf_eq]
intro z hz
rw [← neg_eq_zero, ← hΦ_inv]
suffices ⁅(x : L), z⁆ = 0 by simp only [this, map_zero, LinearMap.zero_apply]
rw [← LieSubmodule.mem_bot (R := K) (L := L), ← (hJ.disjoint_of_ne hI hJI).eq_bot]
apply lie_le_inf
exact lie_mem_lie _ _ x.2 hz
end field
end InvariantForm
end LieAlgebra