-
Notifications
You must be signed in to change notification settings - Fork 0
/
form128.asm
251 lines (195 loc) · 5.41 KB
/
form128.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
;==================================================================================
; Contents of this file are copyright Grant Searle
;
; You have permission to use this for NON COMMERCIAL USE ONLY
; If you wish to use it elsewhere, please include an acknowledgement to myself.
;
; http://searle.hostei.com/grant/index.html
;
; eMail: home.micros01@btinternet.com
;
; If the above don't work, please perform an Internet search to see if I have
; updated the web page hosting service.
;
;==================================================================================
numDrives .EQU 15 ; Not including A:
; CF registers
CF_DATA .EQU $10
CF_FEATURES .EQU $11
CF_ERROR .EQU $11
CF_SECCOUNT .EQU $12
CF_SECTOR .EQU $13
CF_CYL_LOW .EQU $14
CF_CYL_HI .EQU $15
CF_HEAD .EQU $16
CF_STATUS .EQU $17
CF_COMMAND .EQU $17
CF_LBA0 .EQU $13
CF_LBA1 .EQU $14
CF_LBA2 .EQU $15
CF_LBA3 .EQU $16
;CF Features
CF_8BIT .EQU 1
CF_NOCACHE .EQU 082H
;CF Commands
CF_READ_SEC .EQU 020H
CF_WRITE_SEC .EQU 030H
CF_SET_FEAT .EQU 0EFH
LF .EQU 0AH ;line feed
FF .EQU 0CH ;form feed
CR .EQU 0DH ;carriage RETurn
;====================================================================================
.ORG 5000H ; Format program origin.
CALL printInline
.TEXT "CP/M Formatter by G. Searle 2012"
.DB CR,LF,0
LD A,'A'
LD (drvName),A
CALL cfWait
LD A,CF_8BIT ; Set IDE to be 8bit
OUT (CF_FEATURES),A
LD A,CF_SET_FEAT
OUT (CF_COMMAND),A
CALL cfWait
LD A,CF_NOCACHE ; No write cache
OUT (CF_FEATURES),A
LD A,CF_SET_FEAT
OUT (CF_COMMAND),A
; There are 512 directory entries per disk, 4 DIR entries per sector
; So 128 x 128 byte sectors are to be initialised
; The drive uses 512 byte sectors, so 32 x 512 byte sectors per disk
; require initialisation
;Drive 0 (A:) is slightly different due to reserved track, so DIR sector starts at 32
LD A,(drvName)
RST 08H ; Print drive letter
INC A
LD (drvName),A
LD A,$20
LD (secNo),A
processSectorA:
CALL cfWait
LD A,(secNo)
OUT (CF_LBA0),A
LD A,0
OUT (CF_LBA1),A
LD A,0
OUT (CF_LBA2),A
LD a,$E0
OUT (CF_LBA3),A
LD A,1
OUT (CF_SECCOUNT),A
call writeDir
LD A,(secNo)
INC A
LD (secNo),A
CP $40
JR NZ, processSectorA
;Drive 1 onwards (B: etc) don't have reserved tracks, so sector starts at 0
LD DE,$0040 ; HL increment
LD HL,$0040 ; H = LBA2, L=LBA1, initialise for drive 1 (B:)
LD B,numDrives
processDirs:
LD A,(drvName)
RST 08H ; Print drive letter
INC A
LD (drvName),A
LD A,0
LD (secNo),A
processSector:
CALL cfWait
LD A,(secNo)
OUT (CF_LBA0),A
LD A,L
OUT (CF_LBA1),A
LD A,H
OUT (CF_LBA2),A
LD a,0E0H
OUT (CF_LBA3),A
LD A,1
OUT (CF_SECCOUNT),A
call writeDir
LD A,(secNo)
INC A
LD (secNo),A
CP $20
JR NZ, processSector
ADD HL,DE
DEC B
JR NZ,processDirs
CALL printInline
.DB CR,LF
.TEXT "Formatting complete"
.DB CR,LF,0
RET
;================================================================================================
; Write physical sector to host
;================================================================================================
writeDir:
PUSH AF
PUSH BC
PUSH HL
CALL cfWait
LD A,CF_WRITE_SEC
OUT (CF_COMMAND),A
CALL cfWait
LD c,4
wr4secs:
LD HL,dirData
LD b,128
wrByte: LD A,(HL)
nop
nop
OUT (CF_DATA),A
iNC HL
dec b
JR NZ, wrByte
dec c
JR NZ,wr4secs
POP HL
POP BC
POP AF
RET
;================================================================================================
; Utilities
;================================================================================================
printInline:
EX (SP),HL ; PUSH HL and put RET ADDress into HL
PUSH AF
PUSH BC
nextILChar: LD A,(HL)
CP 0
JR Z,endOfPrint
RST 08H
INC HL
JR nextILChar
endOfPrint: INC HL ; Get past "null" terminator
POP BC
POP AF
EX (SP),HL ; PUSH new RET ADDress on stack and restore HL
RET
;================================================================================================
; Wait for disk to be ready (busy=0,ready=1)
;================================================================================================
; Steve's TstBusy/TstReady version
; see https://groups.google.com/forum/#!topic/rc2014-z80/FcLLSKSbRp4
cfWait:
TstBusy: IN A,(CF_STATUS) ;Read status register
BIT 7,A ;Test Busy flag
JR NZ,TstBusy ;High so busy
TstReady: IN A,(CF_STATUS) ;Read status register
BIT 6,A ;Test Ready flag
JR Z,TstReady ;Low so not Ready
RET
secNo .db 0
drvName .db 0
; Directory data for 1 x 128 byte sector
dirData:
.DB $E5,$20,$20,$20,$20,$20,$20,$20,$20,$20,$20,$20,$00,$00,$00,$00
.DB $00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00
.DB $E5,$20,$20,$20,$20,$20,$20,$20,$20,$20,$20,$20,$00,$00,$00,$00
.DB $00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00
.DB $E5,$20,$20,$20,$20,$20,$20,$20,$20,$20,$20,$20,$00,$00,$00,$00
.DB $00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00
.DB $E5,$20,$20,$20,$20,$20,$20,$20,$20,$20,$20,$20,$00,$00,$00,$00
.DB $00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00,$00
.END