feat: Add antq.util.async/fn-with-timeout

cf. #158

src/antq/util/async.clj

@@ -0,0 +1,22 @@
+(ns antq.util.async
+  (:require
+   [clojure.core.async :as async]))
+
+(defn fn-with-timeout
+  [f timeout-ms]
+  (fn [& args]
+    (let [ch (async/chan)]
+      (async/go
+        (let [ret (try
+                    (apply f args)
+                    (catch Throwable ex
+                      [::exception ex]))]
+          (async/>! ch ret)))
+      (let [ret (-> [ch
+                     (async/timeout timeout-ms)]
+                    (async/alts!!)
+                    (first))]
+
+        (if (and (vector? ret) (= ::exception (first ret)))
+          (throw (second ret))
+          ret)))))

test/antq/util/async_test.clj

@@ -0,0 +1,28 @@
+(ns antq.util.async-test
+  (:require
+   [antq.util.async :as sut]
+   [clojure.core.async :as async]
+   [clojure.test :as t]))
+
+(def ^:private test-async-fn
+  (sut/fn-with-timeout
+   (fn [x]
+     (cond
+       (= ::error x)
+       (throw (Exception. "test error"))
+
+       (= ::timeout x)
+       (do (async/<!! (async/timeout 500))
+           x)
+
+       :else
+       x))
+   100))
+
+(t/deftest fn-with-timeout-test
+  (t/is (= 10 (test-async-fn 10)))
+  (t/is (nil? (test-async-fn ::timeout)))
+  (t/is (thrown-with-msg? Exception #"^test error$"
+          (test-async-fn ::error))))
+
+