-
Notifications
You must be signed in to change notification settings - Fork 11.6k
/
rle.ll
1283 lines (1123 loc) · 43.1 KB
/
rle.ll
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
; NOTE: Assertions have been autogenerated by utils/update_test_checks.py
; RUN: opt < %s -data-layout="e-p:32:32:32-p1:16:16:16-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:32:64-f32:32:32-f64:32:64-n8:16:32" -basic-aa -gvn -S -dce | FileCheck %s --check-prefixes=CHECK,LE
; RUN: opt < %s -data-layout="E-p:32:32:32-p1:16:16:16-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:32:64-f32:32:32-f64:64:64-n32" -basic-aa -gvn -S -dce | FileCheck %s --check-prefixes=CHECK,BE
;; Trivial RLE test.
define i32 @test0(i32 %V, i32* %P) {
; CHECK-LABEL: @test0(
; CHECK-NEXT: store i32 [[V:%.*]], i32* [[P:%.*]], align 4
; CHECK-NEXT: ret i32 [[V]]
;
store i32 %V, i32* %P
%A = load i32, i32* %P
ret i32 %A
}
;;===----------------------------------------------------------------------===;;
;; Tests for crashers
;;===----------------------------------------------------------------------===;;
;; PR5016
define i8 @crash0({i32, i32} %A, {i32, i32}* %P) {
; CHECK-LABEL: @crash0(
; CHECK-NEXT: store { i32, i32 } [[A:%.*]], { i32, i32 }* [[P:%.*]], align 4
; CHECK-NEXT: [[X:%.*]] = bitcast { i32, i32 }* [[P]] to i8*
; CHECK-NEXT: [[Y:%.*]] = load i8, i8* [[X]], align 1
; CHECK-NEXT: ret i8 [[Y]]
;
store {i32, i32} %A, {i32, i32}* %P
%X = bitcast {i32, i32}* %P to i8*
%Y = load i8, i8* %X
ret i8 %Y
}
;; No PR filed, crashed in CaptureTracker.
declare void @helper()
define void @crash1() {
; CHECK-LABEL: @crash1(
; CHECK-NEXT: tail call void @llvm.memcpy.p0i8.p0i8.i64(i8* undef, i8* undef, i64 undef, i1 false) #[[ATTR3:[0-9]+]]
; CHECK-NEXT: ret void
;
tail call void @llvm.memcpy.p0i8.p0i8.i64(i8* undef, i8* undef, i64 undef, i1 false) nounwind
%ttmp = load i8, i8* bitcast (void ()* @helper to i8*)
%x = icmp eq i8 %ttmp, 15
ret void
}
;;===----------------------------------------------------------------------===;;
;; Store -> Load and Load -> Load forwarding where src and dst are different
;; types, but where the base pointer is a must alias.
;;===----------------------------------------------------------------------===;;
;; i32 -> f32 forwarding.
define float @coerce_mustalias1(i32 %V, i32* %P) {
; CHECK-LABEL: @coerce_mustalias1(
; CHECK-NEXT: store i32 [[V:%.*]], i32* [[P:%.*]], align 4
; CHECK-NEXT: [[TMP1:%.*]] = bitcast i32 [[V]] to float
; CHECK-NEXT: ret float [[TMP1]]
;
store i32 %V, i32* %P
%P2 = bitcast i32* %P to float*
%A = load float, float* %P2
ret float %A
}
;; i32* -> float forwarding.
define float @coerce_mustalias2(i32* %V, i32** %P) {
; CHECK-LABEL: @coerce_mustalias2(
; CHECK-NEXT: store i32* [[V:%.*]], i32** [[P:%.*]], align 4
; CHECK-NEXT: [[TMP1:%.*]] = ptrtoint i32* [[V]] to i32
; CHECK-NEXT: [[TMP2:%.*]] = bitcast i32 [[TMP1]] to float
; CHECK-NEXT: ret float [[TMP2]]
;
store i32* %V, i32** %P
%P2 = bitcast i32** %P to float*
%A = load float, float* %P2
ret float %A
}
;; float -> i32* forwarding.
define i32* @coerce_mustalias3(float %V, float* %P) {
; CHECK-LABEL: @coerce_mustalias3(
; CHECK-NEXT: store float [[V:%.*]], float* [[P:%.*]], align 4
; CHECK-NEXT: [[TMP1:%.*]] = bitcast float [[V]] to i32
; CHECK-NEXT: [[TMP2:%.*]] = inttoptr i32 [[TMP1]] to i32*
; CHECK-NEXT: ret i32* [[TMP2]]
;
store float %V, float* %P
%P2 = bitcast float* %P to i32**
%A = load i32*, i32** %P2
ret i32* %A
}
;; i32 -> f32 load forwarding.
define float @coerce_mustalias4(i32* %P, i1 %cond) {
; CHECK-LABEL: @coerce_mustalias4(
; CHECK-NEXT: [[A:%.*]] = load i32, i32* [[P:%.*]], align 4
; CHECK-NEXT: [[TMP1:%.*]] = bitcast i32 [[A]] to float
; CHECK-NEXT: br i1 [[COND:%.*]], label [[T:%.*]], label [[F:%.*]]
; CHECK: T:
; CHECK-NEXT: ret float [[TMP1]]
; CHECK: F:
; CHECK-NEXT: ret float [[TMP1]]
;
%A = load i32, i32* %P
%P2 = bitcast i32* %P to float*
%B = load float, float* %P2
br i1 %cond, label %T, label %F
T:
ret float %B
F:
%X = bitcast i32 %A to float
ret float %X
}
;; i32 -> i8 forwarding
define i8 @coerce_mustalias5(i32 %V, i32* %P) {
; LE-LABEL: @coerce_mustalias5(
; LE-NEXT: store i32 [[V:%.*]], i32* [[P:%.*]], align 4
; LE-NEXT: [[TMP1:%.*]] = trunc i32 [[V]] to i8
; LE-NEXT: ret i8 [[TMP1]]
;
; BE-LABEL: @coerce_mustalias5(
; BE-NEXT: store i32 [[V:%.*]], i32* [[P:%.*]], align 4
; BE-NEXT: [[TMP1:%.*]] = lshr i32 [[V]], 24
; BE-NEXT: [[TMP2:%.*]] = trunc i32 [[TMP1]] to i8
; BE-NEXT: ret i8 [[TMP2]]
;
store i32 %V, i32* %P
%P2 = bitcast i32* %P to i8*
%A = load i8, i8* %P2
ret i8 %A
}
;; i64 -> float forwarding
define float @coerce_mustalias6(i64 %V, i64* %P) {
; LE-LABEL: @coerce_mustalias6(
; LE-NEXT: store i64 [[V:%.*]], i64* [[P:%.*]], align 4
; LE-NEXT: [[TMP1:%.*]] = trunc i64 [[V]] to i32
; LE-NEXT: [[TMP2:%.*]] = bitcast i32 [[TMP1]] to float
; LE-NEXT: ret float [[TMP2]]
;
; BE-LABEL: @coerce_mustalias6(
; BE-NEXT: store i64 [[V:%.*]], i64* [[P:%.*]], align 4
; BE-NEXT: [[TMP1:%.*]] = lshr i64 [[V]], 32
; BE-NEXT: [[TMP2:%.*]] = trunc i64 [[TMP1]] to i32
; BE-NEXT: [[TMP3:%.*]] = bitcast i32 [[TMP2]] to float
; BE-NEXT: ret float [[TMP3]]
;
store i64 %V, i64* %P
%P2 = bitcast i64* %P to float*
%A = load float, float* %P2
ret float %A
}
;; i64 -> i8* (32-bit) forwarding
define i8* @coerce_mustalias7(i64 %V, i64* %P) {
; LE-LABEL: @coerce_mustalias7(
; LE-NEXT: store i64 [[V:%.*]], i64* [[P:%.*]], align 4
; LE-NEXT: [[TMP1:%.*]] = trunc i64 [[V]] to i32
; LE-NEXT: [[TMP2:%.*]] = inttoptr i32 [[TMP1]] to i8*
; LE-NEXT: ret i8* [[TMP2]]
;
; BE-LABEL: @coerce_mustalias7(
; BE-NEXT: store i64 [[V:%.*]], i64* [[P:%.*]], align 4
; BE-NEXT: [[TMP1:%.*]] = lshr i64 [[V]], 32
; BE-NEXT: [[TMP2:%.*]] = trunc i64 [[TMP1]] to i32
; BE-NEXT: [[TMP3:%.*]] = inttoptr i32 [[TMP2]] to i8*
; BE-NEXT: ret i8* [[TMP3]]
;
store i64 %V, i64* %P
%P2 = bitcast i64* %P to i8**
%A = load i8*, i8** %P2
ret i8* %A
}
; memset -> i16 forwarding.
define signext i16 @memset_to_i16_local(i16* %A) nounwind ssp {
; CHECK-LABEL: @memset_to_i16_local(
; CHECK-NEXT: entry:
; CHECK-NEXT: [[CONV:%.*]] = bitcast i16* [[A:%.*]] to i8*
; CHECK-NEXT: tail call void @llvm.memset.p0i8.i64(i8* [[CONV]], i8 1, i64 200, i1 false)
; CHECK-NEXT: ret i16 257
;
entry:
%conv = bitcast i16* %A to i8*
tail call void @llvm.memset.p0i8.i64(i8* %conv, i8 1, i64 200, i1 false)
%arrayidx = getelementptr inbounds i16, i16* %A, i64 42
%ttmp2 = load i16, i16* %arrayidx
ret i16 %ttmp2
}
; memset -> float forwarding.
define float @memset_to_float_local(float* %A, i8 %Val) nounwind ssp {
; CHECK-LABEL: @memset_to_float_local(
; CHECK-NEXT: entry:
; CHECK-NEXT: [[CONV:%.*]] = bitcast float* [[A:%.*]] to i8*
; CHECK-NEXT: tail call void @llvm.memset.p0i8.i64(i8* [[CONV]], i8 [[VAL:%.*]], i64 400, i1 false)
; CHECK-NEXT: [[TMP0:%.*]] = zext i8 [[VAL]] to i32
; CHECK-NEXT: [[TMP1:%.*]] = shl i32 [[TMP0]], 8
; CHECK-NEXT: [[TMP2:%.*]] = or i32 [[TMP0]], [[TMP1]]
; CHECK-NEXT: [[TMP3:%.*]] = shl i32 [[TMP2]], 16
; CHECK-NEXT: [[TMP4:%.*]] = or i32 [[TMP2]], [[TMP3]]
; CHECK-NEXT: [[TMP5:%.*]] = bitcast i32 [[TMP4]] to float
; CHECK-NEXT: ret float [[TMP5]]
;
entry:
%conv = bitcast float* %A to i8* ; <i8*> [#uses=1]
tail call void @llvm.memset.p0i8.i64(i8* %conv, i8 %Val, i64 400, i1 false)
%arrayidx = getelementptr inbounds float, float* %A, i64 42 ; <float*> [#uses=1]
%ttmp2 = load float, float* %arrayidx ; <float> [#uses=1]
ret float %ttmp2
}
;; non-local memset -> i16 load forwarding.
define i16 @memset_to_i16_nonlocal0(i16* %P, i1 %cond) {
; CHECK-LABEL: @memset_to_i16_nonlocal0(
; CHECK-NEXT: [[P3:%.*]] = bitcast i16* [[P:%.*]] to i8*
; CHECK-NEXT: br i1 [[COND:%.*]], label [[T:%.*]], label [[F:%.*]]
; CHECK: T:
; CHECK-NEXT: tail call void @llvm.memset.p0i8.i64(i8* [[P3]], i8 1, i64 400, i1 false)
; CHECK-NEXT: br label [[CONT:%.*]]
; CHECK: F:
; CHECK-NEXT: tail call void @llvm.memset.p0i8.i64(i8* [[P3]], i8 2, i64 400, i1 false)
; CHECK-NEXT: br label [[CONT]]
; CHECK: Cont:
; CHECK-NEXT: [[A:%.*]] = phi i16 [ 514, [[F]] ], [ 257, [[T]] ]
; CHECK-NEXT: ret i16 [[A]]
;
%P3 = bitcast i16* %P to i8*
br i1 %cond, label %T, label %F
T:
tail call void @llvm.memset.p0i8.i64(i8* %P3, i8 1, i64 400, i1 false)
br label %Cont
F:
tail call void @llvm.memset.p0i8.i64(i8* %P3, i8 2, i64 400, i1 false)
br label %Cont
Cont:
%P2 = getelementptr i16, i16* %P, i32 4
%A = load i16, i16* %P2
ret i16 %A
}
@GCst = constant {i32, float, i32 } { i32 42, float 14., i32 97 }
@GCst_as1 = addrspace(1) constant {i32, float, i32 } { i32 42, float 14., i32 97 }
; memset -> float forwarding.
define float @memcpy_to_float_local(float* %A) nounwind ssp {
; CHECK-LABEL: @memcpy_to_float_local(
; CHECK-NEXT: entry:
; CHECK-NEXT: [[CONV:%.*]] = bitcast float* [[A:%.*]] to i8*
; CHECK-NEXT: tail call void @llvm.memcpy.p0i8.p0i8.i64(i8* [[CONV]], i8* bitcast ({ i32, float, i32 }* @GCst to i8*), i64 12, i1 false)
; CHECK-NEXT: ret float 1.400000e+01
;
entry:
%conv = bitcast float* %A to i8* ; <i8*> [#uses=1]
tail call void @llvm.memcpy.p0i8.p0i8.i64(i8* %conv, i8* bitcast ({i32, float, i32 }* @GCst to i8*), i64 12, i1 false)
%arrayidx = getelementptr inbounds float, float* %A, i64 1 ; <float*> [#uses=1]
%ttmp2 = load float, float* %arrayidx ; <float> [#uses=1]
ret float %ttmp2
}
; memcpy from address space 1
define float @memcpy_to_float_local_as1(float* %A) nounwind ssp {
; CHECK-LABEL: @memcpy_to_float_local_as1(
; CHECK-NEXT: entry:
; CHECK-NEXT: [[CONV:%.*]] = bitcast float* [[A:%.*]] to i8*
; CHECK-NEXT: tail call void @llvm.memcpy.p0i8.p1i8.i64(i8* [[CONV]], i8 addrspace(1)* bitcast ({ i32, float, i32 } addrspace(1)* @GCst_as1 to i8 addrspace(1)*), i64 12, i1 false)
; CHECK-NEXT: ret float 1.400000e+01
;
entry:
%conv = bitcast float* %A to i8* ; <i8*> [#uses=1]
tail call void @llvm.memcpy.p0i8.p1i8.i64(i8* %conv, i8 addrspace(1)* bitcast ({i32, float, i32 } addrspace(1)* @GCst_as1 to i8 addrspace(1)*), i64 12, i1 false)
%arrayidx = getelementptr inbounds float, float* %A, i64 1 ; <float*> [#uses=1]
%ttmp2 = load float, float* %arrayidx ; <float> [#uses=1]
ret float %ttmp2
}
;; non-local i32/float -> i8 load forwarding.
define i8 @coerce_mustalias_nonlocal0(i32* %P, i1 %cond) {
; LE-LABEL: @coerce_mustalias_nonlocal0(
; LE-NEXT: [[P2:%.*]] = bitcast i32* [[P:%.*]] to float*
; LE-NEXT: br i1 [[COND:%.*]], label [[T:%.*]], label [[F:%.*]]
; LE: T:
; LE-NEXT: store i32 42, i32* [[P]], align 4
; LE-NEXT: br label [[CONT:%.*]]
; LE: F:
; LE-NEXT: store float 1.000000e+00, float* [[P2]], align 4
; LE-NEXT: br label [[CONT]]
; LE: Cont:
; LE-NEXT: [[A:%.*]] = phi i8 [ 0, [[F]] ], [ 42, [[T]] ]
; LE-NEXT: ret i8 [[A]]
;
; BE-LABEL: @coerce_mustalias_nonlocal0(
; BE-NEXT: [[P2:%.*]] = bitcast i32* [[P:%.*]] to float*
; BE-NEXT: br i1 [[COND:%.*]], label [[T:%.*]], label [[F:%.*]]
; BE: T:
; BE-NEXT: store i32 42, i32* [[P]], align 4
; BE-NEXT: br label [[CONT:%.*]]
; BE: F:
; BE-NEXT: store float 1.000000e+00, float* [[P2]], align 4
; BE-NEXT: br label [[CONT]]
; BE: Cont:
; BE-NEXT: [[A:%.*]] = phi i8 [ 63, [[F]] ], [ 0, [[T]] ]
; BE-NEXT: ret i8 [[A]]
;
%P2 = bitcast i32* %P to float*
%P3 = bitcast i32* %P to i8*
br i1 %cond, label %T, label %F
T:
store i32 42, i32* %P
br label %Cont
F:
store float 1.0, float* %P2
br label %Cont
Cont:
%A = load i8, i8* %P3
ret i8 %A
}
;; non-local i32/float -> i8 load forwarding. This also tests that the "P3"
;; bitcast equivalence can be properly phi translated.
define i8 @coerce_mustalias_nonlocal1(i32* %P, i1 %cond) {
; LE-LABEL: @coerce_mustalias_nonlocal1(
; LE-NEXT: [[P2:%.*]] = bitcast i32* [[P:%.*]] to float*
; LE-NEXT: br i1 [[COND:%.*]], label [[T:%.*]], label [[F:%.*]]
; LE: T:
; LE-NEXT: store i32 42, i32* [[P]], align 4
; LE-NEXT: br label [[CONT:%.*]]
; LE: F:
; LE-NEXT: store float 1.000000e+00, float* [[P2]], align 4
; LE-NEXT: br label [[CONT]]
; LE: Cont:
; LE-NEXT: [[A:%.*]] = phi i8 [ 0, [[F]] ], [ 42, [[T]] ]
; LE-NEXT: ret i8 [[A]]
;
; BE-LABEL: @coerce_mustalias_nonlocal1(
; BE-NEXT: [[P2:%.*]] = bitcast i32* [[P:%.*]] to float*
; BE-NEXT: br i1 [[COND:%.*]], label [[T:%.*]], label [[F:%.*]]
; BE: T:
; BE-NEXT: store i32 42, i32* [[P]], align 4
; BE-NEXT: br label [[CONT:%.*]]
; BE: F:
; BE-NEXT: store float 1.000000e+00, float* [[P2]], align 4
; BE-NEXT: br label [[CONT]]
; BE: Cont:
; BE-NEXT: [[A:%.*]] = phi i8 [ 63, [[F]] ], [ 0, [[T]] ]
; BE-NEXT: ret i8 [[A]]
;
%P2 = bitcast i32* %P to float*
br i1 %cond, label %T, label %F
T:
store i32 42, i32* %P
br label %Cont
F:
store float 1.0, float* %P2
br label %Cont
Cont:
%P3 = bitcast i32* %P to i8*
%A = load i8, i8* %P3
ret i8 %A
}
;; non-local i32 -> i8 partial redundancy load forwarding.
define i8 @coerce_mustalias_pre0(i32* %P, i1 %cond) {
; LE-LABEL: @coerce_mustalias_pre0(
; LE-NEXT: [[P3:%.*]] = bitcast i32* [[P:%.*]] to i8*
; LE-NEXT: br i1 [[COND:%.*]], label [[T:%.*]], label [[F:%.*]]
; LE: T:
; LE-NEXT: store i32 42, i32* [[P]], align 4
; LE-NEXT: br label [[CONT:%.*]]
; LE: F:
; LE-NEXT: [[A_PRE:%.*]] = load i8, i8* [[P3]], align 1
; LE-NEXT: br label [[CONT]]
; LE: Cont:
; LE-NEXT: [[A:%.*]] = phi i8 [ [[A_PRE]], [[F]] ], [ 42, [[T]] ]
; LE-NEXT: ret i8 [[A]]
;
; BE-LABEL: @coerce_mustalias_pre0(
; BE-NEXT: [[P3:%.*]] = bitcast i32* [[P:%.*]] to i8*
; BE-NEXT: br i1 [[COND:%.*]], label [[T:%.*]], label [[F:%.*]]
; BE: T:
; BE-NEXT: store i32 42, i32* [[P]], align 4
; BE-NEXT: br label [[CONT:%.*]]
; BE: F:
; BE-NEXT: [[A_PRE:%.*]] = load i8, i8* [[P3]], align 1
; BE-NEXT: br label [[CONT]]
; BE: Cont:
; BE-NEXT: [[A:%.*]] = phi i8 [ [[A_PRE]], [[F]] ], [ 0, [[T]] ]
; BE-NEXT: ret i8 [[A]]
;
%P3 = bitcast i32* %P to i8*
br i1 %cond, label %T, label %F
T:
store i32 42, i32* %P
br label %Cont
F:
br label %Cont
Cont:
%A = load i8, i8* %P3
ret i8 %A
}
;;===----------------------------------------------------------------------===;;
;; Store -> Load and Load -> Load forwarding where src and dst are different
;; types, and the reload is an offset from the store pointer.
;;===----------------------------------------------------------------------===;;
;; i32 -> i8 forwarding.
;; PR4216
define i8 @coerce_offset0(i32 %V, i32* %P) {
; LE-LABEL: @coerce_offset0(
; LE-NEXT: store i32 [[V:%.*]], i32* [[P:%.*]], align 4
; LE-NEXT: [[TMP1:%.*]] = lshr i32 [[V]], 16
; LE-NEXT: [[TMP2:%.*]] = trunc i32 [[TMP1]] to i8
; LE-NEXT: ret i8 [[TMP2]]
;
; BE-LABEL: @coerce_offset0(
; BE-NEXT: store i32 [[V:%.*]], i32* [[P:%.*]], align 4
; BE-NEXT: [[TMP1:%.*]] = lshr i32 [[V]], 8
; BE-NEXT: [[TMP2:%.*]] = trunc i32 [[TMP1]] to i8
; BE-NEXT: ret i8 [[TMP2]]
;
store i32 %V, i32* %P
%P2 = bitcast i32* %P to i8*
%P3 = getelementptr i8, i8* %P2, i32 2
%A = load i8, i8* %P3
ret i8 %A
}
;; non-local i32/float -> i8 load forwarding.
define i8 @coerce_offset_nonlocal0(i32* %P, i1 %cond) {
; LE-LABEL: @coerce_offset_nonlocal0(
; LE-NEXT: [[P2:%.*]] = bitcast i32* [[P:%.*]] to float*
; LE-NEXT: br i1 [[COND:%.*]], label [[T:%.*]], label [[F:%.*]]
; LE: T:
; LE-NEXT: store i32 57005, i32* [[P]], align 4
; LE-NEXT: br label [[CONT:%.*]]
; LE: F:
; LE-NEXT: store float 1.000000e+00, float* [[P2]], align 4
; LE-NEXT: br label [[CONT]]
; LE: Cont:
; LE-NEXT: [[A:%.*]] = phi i8 [ -128, [[F]] ], [ 0, [[T]] ]
; LE-NEXT: ret i8 [[A]]
;
; BE-LABEL: @coerce_offset_nonlocal0(
; BE-NEXT: [[P2:%.*]] = bitcast i32* [[P:%.*]] to float*
; BE-NEXT: br i1 [[COND:%.*]], label [[T:%.*]], label [[F:%.*]]
; BE: T:
; BE-NEXT: store i32 57005, i32* [[P]], align 4
; BE-NEXT: br label [[CONT:%.*]]
; BE: F:
; BE-NEXT: store float 1.000000e+00, float* [[P2]], align 4
; BE-NEXT: br label [[CONT]]
; BE: Cont:
; BE-NEXT: [[A:%.*]] = phi i8 [ 0, [[F]] ], [ -34, [[T]] ]
; BE-NEXT: ret i8 [[A]]
;
%P2 = bitcast i32* %P to float*
%P3 = bitcast i32* %P to i8*
%P4 = getelementptr i8, i8* %P3, i32 2
br i1 %cond, label %T, label %F
T:
store i32 57005, i32* %P
br label %Cont
F:
store float 1.0, float* %P2
br label %Cont
Cont:
%A = load i8, i8* %P4
ret i8 %A
}
;; non-local i32 -> i8 partial redundancy load forwarding.
define i8 @coerce_offset_pre0(i32* %P, i1 %cond) {
; CHECK-LABEL: @coerce_offset_pre0(
; CHECK-NEXT: [[P3:%.*]] = bitcast i32* [[P:%.*]] to i8*
; CHECK-NEXT: [[P4:%.*]] = getelementptr i8, i8* [[P3]], i32 2
; CHECK-NEXT: br i1 [[COND:%.*]], label [[T:%.*]], label [[F:%.*]]
; CHECK: T:
; CHECK-NEXT: store i32 42, i32* [[P]], align 4
; CHECK-NEXT: br label [[CONT:%.*]]
; CHECK: F:
; CHECK-NEXT: [[A_PRE:%.*]] = load i8, i8* [[P4]], align 1
; CHECK-NEXT: br label [[CONT]]
; CHECK: Cont:
; CHECK-NEXT: [[A:%.*]] = phi i8 [ [[A_PRE]], [[F]] ], [ 0, [[T]] ]
; CHECK-NEXT: ret i8 [[A]]
;
%P3 = bitcast i32* %P to i8*
%P4 = getelementptr i8, i8* %P3, i32 2
br i1 %cond, label %T, label %F
T:
store i32 42, i32* %P
br label %Cont
F:
br label %Cont
Cont:
%A = load i8, i8* %P4
ret i8 %A
}
define i32 @chained_load(i32** %p, i32 %x, i32 %y) {
; CHECK-LABEL: @chained_load(
; CHECK-NEXT: block1:
; CHECK-NEXT: [[A:%.*]] = alloca i32*, align 4
; CHECK-NEXT: [[Z:%.*]] = load i32*, i32** [[P:%.*]], align 4
; CHECK-NEXT: store i32* [[Z]], i32** [[A]], align 4
; CHECK-NEXT: [[CMP:%.*]] = icmp eq i32 [[X:%.*]], [[Y:%.*]]
; CHECK-NEXT: br i1 [[CMP]], label [[BLOCK2:%.*]], label [[BLOCK3:%.*]]
; CHECK: block2:
; CHECK-NEXT: br label [[BLOCK4:%.*]]
; CHECK: block3:
; CHECK-NEXT: br label [[BLOCK4]]
; CHECK: block4:
; CHECK-NEXT: [[D:%.*]] = load i32, i32* [[Z]], align 4
; CHECK-NEXT: ret i32 [[D]]
;
block1:
%A = alloca i32*
%z = load i32*, i32** %p
store i32* %z, i32** %A
%cmp = icmp eq i32 %x, %y
br i1 %cmp, label %block2, label %block3
block2:
%a = load i32*, i32** %p
br label %block4
block3:
%b = load i32*, i32** %p
br label %block4
block4:
%c = load i32*, i32** %p
%d = load i32, i32* %c
ret i32 %d
}
declare i1 @cond() readonly
declare i1 @cond2() readonly
define i32 @phi_trans2() {
; CHECK-LABEL: @phi_trans2(
; CHECK-NEXT: entry:
; CHECK-NEXT: [[P:%.*]] = alloca i32, i32 400, align 4
; CHECK-NEXT: br label [[F1:%.*]]
; CHECK: F1:
; CHECK-NEXT: [[A:%.*]] = phi i32 [ 1, [[ENTRY:%.*]] ], [ 2, [[F:%.*]] ]
; CHECK-NEXT: [[COND2:%.*]] = call i1 @cond()
; CHECK-NEXT: br i1 [[COND2]], label [[T1:%.*]], label [[TY:%.*]]
; CHECK: T1:
; CHECK-NEXT: [[P2:%.*]] = getelementptr i32, i32* [[P]], i32 [[A]]
; CHECK-NEXT: [[X:%.*]] = load i32, i32* [[P2]], align 4
; CHECK-NEXT: [[COND:%.*]] = call i1 @cond2()
; CHECK-NEXT: br i1 [[COND]], label [[TX:%.*]], label [[F]]
; CHECK: F:
; CHECK-NEXT: [[P3:%.*]] = getelementptr i32, i32* [[P]], i32 2
; CHECK-NEXT: store i32 17, i32* [[P3]], align 4
; CHECK-NEXT: store i32 42, i32* [[P2]], align 4
; CHECK-NEXT: br label [[F1]]
; CHECK: TX:
; CHECK-NEXT: ret i32 [[X]]
; CHECK: TY:
; CHECK-NEXT: ret i32 0
;
entry:
%P = alloca i32, i32 400
br label %F1
F1:
%A = phi i32 [1, %entry], [2, %F]
%cond2 = call i1 @cond()
br i1 %cond2, label %T1, label %TY
T1:
%P2 = getelementptr i32, i32* %P, i32 %A
%x = load i32, i32* %P2
%cond = call i1 @cond2()
br i1 %cond, label %TX, label %F
F:
%P3 = getelementptr i32, i32* %P, i32 2
store i32 17, i32* %P3
store i32 42, i32* %P2 ; Provides "P[A]".
br label %F1
TX:
; This load should not be compiled to 'ret i32 42'. An overly clever
; implementation of GVN would see that we're returning 17 if the loop
; executes once or 42 if it executes more than that, but we'd have to do
; loop restructuring to expose this, and GVN shouldn't do this sort of CFG
; transformation.
ret i32 %x
TY:
ret i32 0
}
define i32 @phi_trans3(i32* %p, i32 %x, i32 %y, i32 %z) {
; CHECK-LABEL: @phi_trans3(
; CHECK-NEXT: block1:
; CHECK-NEXT: [[CMPXY:%.*]] = icmp eq i32 [[X:%.*]], [[Y:%.*]]
; CHECK-NEXT: br i1 [[CMPXY]], label [[BLOCK2:%.*]], label [[BLOCK3:%.*]]
; CHECK: block2:
; CHECK-NEXT: store i32 87, i32* [[P:%.*]], align 4
; CHECK-NEXT: br label [[BLOCK4:%.*]]
; CHECK: block3:
; CHECK-NEXT: [[P2:%.*]] = getelementptr i32, i32* [[P]], i32 43
; CHECK-NEXT: store i32 97, i32* [[P2]], align 4
; CHECK-NEXT: br label [[BLOCK4]]
; CHECK: block4:
; CHECK-NEXT: [[D:%.*]] = phi i32 [ 87, [[BLOCK2]] ], [ 97, [[BLOCK3]] ]
; CHECK-NEXT: br i1 [[CMPXY]], label [[BLOCK5:%.*]], label [[EXIT:%.*]]
; CHECK: block5:
; CHECK-NEXT: br i1 true, label [[BLOCK6:%.*]], label [[BLOCK5_EXIT_CRIT_EDGE:%.*]]
; CHECK: block5.exit_crit_edge:
; CHECK-NEXT: br label [[EXIT]]
; CHECK: block6:
; CHECK-NEXT: br i1 true, label [[BLOCK7:%.*]], label [[BLOCK6_EXIT_CRIT_EDGE:%.*]]
; CHECK: block6.exit_crit_edge:
; CHECK-NEXT: br label [[EXIT]]
; CHECK: block7:
; CHECK-NEXT: ret i32 [[D]]
; CHECK: exit:
; CHECK-NEXT: ret i32 -1
;
block1:
%cmpxy = icmp eq i32 %x, %y
br i1 %cmpxy, label %block2, label %block3
block2:
store i32 87, i32* %p
br label %block4
block3:
%p2 = getelementptr i32, i32* %p, i32 43
store i32 97, i32* %p2
br label %block4
block4:
%A = phi i32 [-1, %block2], [42, %block3]
br i1 %cmpxy, label %block5, label %exit
block5:
%B = add i32 %A, 1
br i1 %cmpxy, label %block6, label %exit
block6:
%C = getelementptr i32, i32* %p, i32 %B
br i1 %cmpxy, label %block7, label %exit
block7:
%D = load i32, i32* %C
ret i32 %D
exit:
ret i32 -1
}
define i8 @phi_trans4(i8* %p) {
; CHECK-LABEL: @phi_trans4(
; CHECK-NEXT: entry:
; CHECK-NEXT: [[X3:%.*]] = getelementptr i8, i8* [[P:%.*]], i32 192
; CHECK-NEXT: store i8 -64, i8* [[X3]], align 1
; CHECK-NEXT: [[X:%.*]] = getelementptr i8, i8* [[P]], i32 4
; CHECK-NEXT: [[Y:%.*]] = load i8, i8* [[X]], align 1
; CHECK-NEXT: br label [[LOOP:%.*]]
; CHECK: loop:
; CHECK-NEXT: [[Y2:%.*]] = phi i8 [ [[Y]], [[ENTRY:%.*]] ], [ 0, [[LOOP]] ]
; CHECK-NEXT: [[COND:%.*]] = call i1 @cond2()
; CHECK-NEXT: [[Z:%.*]] = bitcast i8* [[X3]] to i32*
; CHECK-NEXT: store i32 0, i32* [[Z]], align 4
; CHECK-NEXT: br i1 [[COND]], label [[LOOP]], label [[OUT:%.*]]
; CHECK: out:
; CHECK-NEXT: [[R:%.*]] = add i8 [[Y]], [[Y2]]
; CHECK-NEXT: ret i8 [[R]]
;
entry:
%X3 = getelementptr i8, i8* %p, i32 192
store i8 192, i8* %X3
%X = getelementptr i8, i8* %p, i32 4
%Y = load i8, i8* %X
br label %loop
loop:
%i = phi i32 [4, %entry], [192, %loop]
%X2 = getelementptr i8, i8* %p, i32 %i
%Y2 = load i8, i8* %X2
%cond = call i1 @cond2()
%Z = bitcast i8 *%X3 to i32*
store i32 0, i32* %Z
br i1 %cond, label %loop, label %out
out:
%R = add i8 %Y, %Y2
ret i8 %R
}
define i8 @phi_trans5(i8* %p) {
; CHECK-LABEL: @phi_trans5(
; CHECK-NEXT: entry:
; CHECK-NEXT: [[X4:%.*]] = getelementptr i8, i8* [[P:%.*]], i32 2
; CHECK-NEXT: store i8 19, i8* [[X4]], align 1
; CHECK-NEXT: [[X:%.*]] = getelementptr i8, i8* [[P]], i32 4
; CHECK-NEXT: [[Y:%.*]] = load i8, i8* [[X]], align 1
; CHECK-NEXT: br label [[LOOP:%.*]]
; CHECK: loop:
; CHECK-NEXT: [[Y2:%.*]] = phi i8 [ [[Y]], [[ENTRY:%.*]] ], [ [[Y2_PRE:%.*]], [[CONT:%.*]] ]
; CHECK-NEXT: [[I:%.*]] = phi i32 [ 4, [[ENTRY]] ], [ 3, [[CONT]] ]
; CHECK-NEXT: [[X2:%.*]] = getelementptr i8, i8* [[P]], i32 [[I]]
; CHECK-NEXT: [[COND:%.*]] = call i1 @cond2()
; CHECK-NEXT: br i1 [[COND]], label [[CONT]], label [[OUT:%.*]]
; CHECK: cont:
; CHECK-NEXT: [[Z:%.*]] = getelementptr i8, i8* [[X2]], i32 -1
; CHECK-NEXT: [[Z2:%.*]] = bitcast i8* [[Z]] to i32*
; CHECK-NEXT: store i32 50462976, i32* [[Z2]], align 4
; CHECK-NEXT: [[X2_PHI_TRANS_INSERT:%.*]] = getelementptr i8, i8* [[P]], i32 3
; CHECK-NEXT: [[Y2_PRE]] = load i8, i8* [[X2_PHI_TRANS_INSERT]], align 1
; CHECK-NEXT: br label [[LOOP]]
; CHECK: out:
; CHECK-NEXT: [[R:%.*]] = add i8 [[Y]], [[Y2]]
; CHECK-NEXT: ret i8 [[R]]
;
entry:
%X4 = getelementptr i8, i8* %p, i32 2
store i8 19, i8* %X4
%X = getelementptr i8, i8* %p, i32 4
%Y = load i8, i8* %X
br label %loop
loop:
%i = phi i32 [4, %entry], [3, %cont]
%X2 = getelementptr i8, i8* %p, i32 %i
%Y2 = load i8, i8* %X2 ; Ensure this load is not being incorrectly replaced.
%cond = call i1 @cond2()
br i1 %cond, label %cont, label %out
cont:
%Z = getelementptr i8, i8* %X2, i32 -1
%Z2 = bitcast i8 *%Z to i32*
store i32 50462976, i32* %Z2 ;; (1 << 8) | (2 << 16) | (3 << 24)
br label %loop
out:
%R = add i8 %Y, %Y2
ret i8 %R
}
declare void @use_i32(i32) readonly
; indirectbr currently prevents MergeBlockIntoPredecessor from merging latch
; into header. Make sure we translate the address for %l1 correctly where
; parts of the address computations are in different basic blocks.
define i32 @phi_trans6(i32* noalias nocapture readonly %x, i1 %cond) {
; CHECK-LABEL: @phi_trans6(
; CHECK-NEXT: entry:
; CHECK-NEXT: [[L0:%.*]] = load i32, i32* [[X:%.*]], align 4
; CHECK-NEXT: call void @use_i32(i32 [[L0]])
; CHECK-NEXT: br label [[HEADER:%.*]]
; CHECK: header:
; CHECK-NEXT: [[L1:%.*]] = phi i32 [ [[L0]], [[ENTRY:%.*]] ], [ [[L1_PRE:%.*]], [[LATCH_HEADER_CRIT_EDGE:%.*]] ]
; CHECK-NEXT: [[IV:%.*]] = phi i32 [ 0, [[ENTRY]] ], [ [[IV_NEXT:%.*]], [[LATCH_HEADER_CRIT_EDGE]] ]
; CHECK-NEXT: indirectbr i8* blockaddress(@phi_trans6, [[LATCH:%.*]]), [label %latch]
; CHECK: latch:
; CHECK-NEXT: [[IV_NEXT]] = add i32 [[IV]], 1
; CHECK-NEXT: br i1 [[COND:%.*]], label [[EXIT:%.*]], label [[LATCH_HEADER_CRIT_EDGE]]
; CHECK: latch.header_crit_edge:
; CHECK-NEXT: [[GEP_1_PHI_TRANS_INSERT_PHI_TRANS_INSERT:%.*]] = getelementptr i32, i32* [[X]], i32 [[IV_NEXT]]
; CHECK-NEXT: [[L1_PRE]] = load i32, i32* [[GEP_1_PHI_TRANS_INSERT_PHI_TRANS_INSERT]], align 4
; CHECK-NEXT: br label [[HEADER]]
; CHECK: exit:
; CHECK-NEXT: ret i32 [[L1]]
;
entry:
%l0 = load i32, i32* %x
call void @use_i32(i32 %l0)
br label %header
header:
%iv = phi i32 [0, %entry], [ %iv.next, %latch]
indirectbr i8* blockaddress(@phi_trans6, %latch), [label %latch]
latch:
%gep.1 = getelementptr i32, i32* %x, i32 %iv
%l1 = load i32, i32* %gep.1
%iv.next = add i32 %iv, 1
br i1 %cond, label %exit, label %header
exit:
ret i32 %l1
}
; FIXME: Currently we fail to translate the PHI in this case.
define i32 @phi_trans7(i32* noalias nocapture readonly %x, i1 %cond) {
; CHECK-LABEL: @phi_trans7(
; CHECK-NEXT: entry:
; CHECK-NEXT: [[L0:%.*]] = load i32, i32* [[X:%.*]], align 4
; CHECK-NEXT: call void @use_i32(i32 [[L0]])
; CHECK-NEXT: br label [[HEADER:%.*]]
; CHECK: header:
; CHECK-NEXT: [[IV:%.*]] = phi i32 [ 2, [[ENTRY:%.*]] ], [ [[IV_NEXT:%.*]], [[LATCH_HEADER_CRIT_EDGE:%.*]] ]
; CHECK-NEXT: [[OFFSET:%.*]] = add i32 [[IV]], -2
; CHECK-NEXT: indirectbr i8* blockaddress(@phi_trans7, [[LATCH:%.*]]), [label %latch]
; CHECK: latch:
; CHECK-NEXT: [[GEP_1:%.*]] = getelementptr i32, i32* [[X]], i32 [[OFFSET]]
; CHECK-NEXT: [[L1:%.*]] = load i32, i32* [[GEP_1]], align 4
; CHECK-NEXT: [[IV_NEXT]] = add i32 [[IV]], 1
; CHECK-NEXT: br i1 [[COND:%.*]], label [[EXIT:%.*]], label [[LATCH_HEADER_CRIT_EDGE]]
; CHECK: latch.header_crit_edge:
; CHECK-NEXT: br label [[HEADER]]
; CHECK: exit:
; CHECK-NEXT: ret i32 [[L1]]
;
entry:
%l0 = load i32, i32* %x
call void @use_i32(i32 %l0)
br label %header
header:
%iv = phi i32 [2, %entry], [ %iv.next, %latch]
%offset = add i32 %iv, -2
indirectbr i8* blockaddress(@phi_trans7, %latch), [label %latch]
latch:
%gep.1 = getelementptr i32, i32* %x, i32 %offset
%l1 = load i32, i32* %gep.1
%iv.next = add i32 %iv, 1
br i1 %cond, label %exit, label %header
exit:
ret i32 %l1
}
; FIXME: Currently we fail to translate the PHI in this case.
define i32 @phi_trans8(i32* noalias nocapture readonly %x, i1 %cond) {
; CHECK-LABEL: @phi_trans8(
; CHECK-NEXT: entry:
; CHECK-NEXT: [[L0:%.*]] = load i32, i32* [[X:%.*]], align 4
; CHECK-NEXT: call void @use_i32(i32 [[L0]])
; CHECK-NEXT: br label [[HEADER:%.*]]
; CHECK: header:
; CHECK-NEXT: [[IV:%.*]] = phi i32 [ 2, [[ENTRY:%.*]] ], [ [[IV_NEXT:%.*]], [[LATCH_HEADER_CRIT_EDGE:%.*]] ]
; CHECK-NEXT: indirectbr i8* blockaddress(@phi_trans8, [[LATCH:%.*]]), [label %latch]
; CHECK: latch:
; CHECK-NEXT: [[OFFSET:%.*]] = add i32 [[IV]], -2
; CHECK-NEXT: [[GEP_1:%.*]] = getelementptr i32, i32* [[X]], i32 [[OFFSET]]
; CHECK-NEXT: [[L1:%.*]] = load i32, i32* [[GEP_1]], align 4
; CHECK-NEXT: [[IV_NEXT]] = add i32 [[IV]], 1
; CHECK-NEXT: br i1 [[COND:%.*]], label [[EXIT:%.*]], label [[LATCH_HEADER_CRIT_EDGE]]
; CHECK: latch.header_crit_edge:
; CHECK-NEXT: br label [[HEADER]]
; CHECK: exit:
; CHECK-NEXT: ret i32 [[L1]]
;
entry:
%l0 = load i32, i32* %x
call void @use_i32(i32 %l0)
br label %header
header:
%iv = phi i32 [2, %entry], [ %iv.next, %latch]
indirectbr i8* blockaddress(@phi_trans8, %latch), [label %latch]
latch:
%offset = add i32 %iv, -2
%gep.1 = getelementptr i32, i32* %x, i32 %offset
%l1 = load i32, i32* %gep.1
%iv.next = add i32 %iv, 1
br i1 %cond, label %exit, label %header
exit:
ret i32 %l1
}
; PR6642
define i32 @memset_to_load() nounwind readnone {
; CHECK-LABEL: @memset_to_load(
; CHECK-NEXT: entry:
; CHECK-NEXT: [[X:%.*]] = alloca [256 x i32], align 4
; CHECK-NEXT: [[TTMP:%.*]] = bitcast [256 x i32]* [[X]] to i8*
; CHECK-NEXT: call void @llvm.memset.p0i8.i64(i8* align 4 [[TTMP]], i8 0, i64 1024, i1 false)
; CHECK-NEXT: ret i32 0
;
entry:
%x = alloca [256 x i32], align 4 ; <[256 x i32]*> [#uses=2]
%ttmp = bitcast [256 x i32]* %x to i8* ; <i8*> [#uses=1]
call void @llvm.memset.p0i8.i64(i8* align 4 %ttmp, i8 0, i64 1024, i1 false)
%arraydecay = getelementptr inbounds [256 x i32], [256 x i32]* %x, i32 0, i32 0 ; <i32*>
%ttmp1 = load i32, i32* %arraydecay ; <i32> [#uses=1]
ret i32 %ttmp1
}
;;===----------------------------------------------------------------------===;;
;; Load -> Load forwarding in partial alias case.
;;===----------------------------------------------------------------------===;;
define i32 @load_load_partial_alias(i8* %P) nounwind ssp {
; CHECK-LABEL: @load_load_partial_alias(
; CHECK-NEXT: entry:
; CHECK-NEXT: [[TMP0:%.*]] = bitcast i8* [[P:%.*]] to i32*
; CHECK-NEXT: [[TTMP2:%.*]] = load i32, i32* [[TMP0]], align 4
; LE-NEXT: [[TMP1:%.*]] = lshr i32 [[TTMP2]], 8
; BE-NEXT: [[TMP1:%.*]] = lshr i32 [[TTMP2]], 16
; CHECK-NEXT: [[TMP2:%.*]] = trunc i32 [[TMP1]] to i8
; CHECK-NEXT: [[CONV:%.*]] = zext i8 [[TMP2]] to i32
; CHECK-NEXT: [[ADD:%.*]] = add nsw i32 [[TTMP2]], [[CONV]]
; CHECK-NEXT: ret i32 [[ADD]]
;
entry:
%0 = bitcast i8* %P to i32*
%ttmp2 = load i32, i32* %0
%add.ptr = getelementptr inbounds i8, i8* %P, i64 1
%ttmp5 = load i8, i8* %add.ptr
%conv = zext i8 %ttmp5 to i32
%add = add nsw i32 %ttmp2, %conv
ret i32 %add
}
; Cross block partial alias case.
define i32 @load_load_partial_alias_cross_block(i8* %P) nounwind ssp {
; CHECK-LABEL: @load_load_partial_alias_cross_block(
; CHECK-NEXT: entry:
; CHECK-NEXT: [[XX:%.*]] = bitcast i8* [[P:%.*]] to i32*
; CHECK-NEXT: [[X1:%.*]] = load i32, i32* [[XX]], align 4
; CHECK-NEXT: [[CMP:%.*]] = icmp eq i32 [[X1]], 127
; LE-NEXT: [[TMP0:%.*]] = lshr i32 [[X1]], 8
; BE-NEXT: [[TMP0:%.*]] = lshr i32 [[X1]], 16
; CHECK-NEXT: [[TMP1:%.*]] = trunc i32 [[TMP0]] to i8
; CHECK-NEXT: br i1 [[CMP]], label [[LAND_LHS_TRUE:%.*]], label [[IF_END:%.*]]
; CHECK: land.lhs.true:
; CHECK-NEXT: [[CONV6:%.*]] = zext i8 [[TMP1]] to i32
; CHECK-NEXT: ret i32 [[CONV6]]
; CHECK: if.end:
; CHECK-NEXT: ret i32 52
;
entry:
%xx = bitcast i8* %P to i32*
%x1 = load i32, i32* %xx, align 4
%cmp = icmp eq i32 %x1, 127
br i1 %cmp, label %land.lhs.true, label %if.end