i8 bool accumulator not converted to i1

[nikic]

define zeroext i1 @test(ptr %ptr.base, i64 %len) {
start:
  %end = getelementptr inbounds i64, ptr %ptr.base, i64 %len
  %len.zero = icmp eq i64 %len, 0
  br i1 %len.zero, label %exit, label %loop

loop:
  %accum = phi i8 [ %accum.next, %loop ], [ 1, %start ]
  %ptr = phi ptr [ %ptr.next, %loop ], [ %ptr.base, %start ]
  %ptr.next = getelementptr inbounds i64, ptr %ptr, i64 1
  %accum.bool = icmp ne i8 %accum, 0
  %val = load i64, ptr %ptr, align 8
  %val.zero = icmp eq i64 %val, 0
  %and = and i1 %accum.bool, %val.zero
  %accum.next = zext i1 %and to i8
  %exit.cond = icmp eq ptr %ptr.next, %end
  br i1 %exit.cond, label %exit, label %loop

exit:
  %res = phi i1 [ true, %start ], [ %and, %loop ]
  ret i1 %res
}

This stays invariant under -O2. It should be possible to narrow %accum to i1, resulting in the following IR:

define zeroext i1 @test(ptr %ptr.base, i64 %len) {
start:
  %end = getelementptr inbounds i64, ptr %ptr.base, i64 %len
  %len.zero = icmp eq i64 %len, 0
  br i1 %len.zero, label %exit, label %loop

loop:
  %accum.bool = phi i1 [ %accum.next, %loop ], [ true, %start ]
  %ptr = phi ptr [ %ptr.next, %loop ], [ %ptr.base, %start ]
  %ptr.next = getelementptr inbounds i64, ptr %ptr, i64 1
  %val = load i64, ptr %ptr, align 8
  %val.zero = icmp eq i64 %val, 0
  %accum.next = and i1 %accum.bool, %val.zero
  %exit.cond = icmp eq ptr %ptr.next, %end
  br i1 %exit.cond, label %exit, label %loop

exit:
  %res = phi i1 [ true, %start ], [ %accum.next, %loop ]
  ret i1 %res
}

[nikic]

We'd want to push the icmp ne i8 %accum, 0 through the phi here, because that allows it to fold with the zext. But general transforms like foldOpIntoPhi() won't cover this, because we usually don't want to push an op over a loop backedge (easy to infinite loop in that case).

Not sure what an elegant way to fix this would be cc @rotateright

[nikic]

Candidate patch: https://reviews.llvm.org/D134954