forked from timfel/JSON-st
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Json.st
317 lines (271 loc) · 6.9 KB
/
Json.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
Object subclass: Json [
| stream ctorMap |
<category: 'JSON'>
<comment: 'This class reads and writes JSON format data - strings, numbers, boolean, nil, arrays and dictionaries. See http://www.crockford.com/JSON/index.html. It has been extended with syntax for invoking a prearranged list of constructors on read objects.'>
Json class [
| escapeArray |
]
Json class >> escapeForCharacter: c [
| index |
^(index := c asciiValue + 1) <= escapeArray size
ifTrue: [escapeArray at: index]
ifFalse: [c]
]
Json class >> initialize [
"Json initialize."
| tmpStr |
escapeArray := (1 to: 128) collect: [:i | Character value: i - 1].
(0 to: 31) , #(127) do:
[:each |
tmpStr := String streamContents: [:str | each printOn: str base: 16].
escapeArray at: each + 1
put: '\u' , (String new: (4 - tmpStr size max: 0) withAll: $0) , tmpStr].
{$" -> '\"'.
$\ -> '\\'.
Character backspace -> '\b'.
Character lf -> '\n'.
Character newPage -> '\f'.
Character cr -> '\r'.
Character tab -> '\t'}
do: [:each | escapeArray at: each key asciiValue + 1 put: each value]
]
Json class >> mimeType [
^'application/x-json'
]
Json class >> newWithConstructors: aCollection [
| m |
m := Dictionary new.
aCollection do:
[:each |
(each isKindOf: Association)
ifTrue: [m add: each]
ifFalse: [m at: each name asString put: each]].
^(self new)
ctorMap: m;
yourself
]
Json class >> numbersMayContain: aChar [
^aChar isDigit or: [#($- $+ $. $e $E) includes: aChar]
]
Json class >> readFrom: aStream [
^self new readFrom: aStream
]
Json class >> render: anObject [
| s |
s := WriteStream on: String new.
anObject jsonWriteOn: s.
^s contents
]
Json class >> render: anObject withConstructor: aConstructorName on: aStream [
aStream nextPutAll: '@' , aConstructorName.
anObject jsonWriteOn: aStream
]
Json class >> renderInstanceVariables: aCollection of: anObject on: aStream [
| map |
map := Dictionary new.
aCollection
do: [:ivarName | map at: ivarName put: (anObject instVarNamed: ivarName)].
self
render: map
withConstructor: anObject class name asString
on: aStream
]
consume: aString returning: anObject [
<category: 'private'>
aString do:
[:c |
stream next == c
ifFalse: [JsonSyntaxError signal: 'Expected ''' , aString , '''']].
^anObject
]
interpretStringEscape [
<category: 'private'>
| c |
c := stream next.
c == $b ifTrue: [^Character backspace].
c == $n ifTrue: [^Character lf].
c == $f ifTrue: [^Character newPage].
c == $r ifTrue: [^Character cr].
c == $t ifTrue: [^Character tab].
c == $u ifTrue: [^self unescapeUnicode].
^c
]
readArray [
<category: 'private'>
| a |
a := OrderedCollection new.
self skipWhitespace.
(stream peekFor: $]) ifTrue: [^#()].
[a add: self readAny.
self skipWhitespace.
(stream peekFor: $]) ifTrue: [^a asArray].
(stream peekFor: $,) ifFalse: [JsonSyntaxError signal: 'Missing comma']]
repeat
]
readConstructor [
<category: 'private'>
| s c v ctor |
s := WriteStream on: ''.
[c := stream peek.
c
ifNil: [JsonSyntaxError signal: 'Premature EOF reading constructor name'].
(c == $. or: [c isLetter])
ifTrue:
[s nextPut: c.
stream next]
ifFalse:
[v := self readAny.
s := s contents.
ctor := ctorMap ifNotNil: [:foo | ctor := ctorMap at: s ifAbsent: [nil]].
ctor ifNil: [JsonSyntaxError signal: 'Unknown ctor ' , s].
^ctor constructFromJson: v]]
repeat
]
readDictionary [
<category: 'private'>
| m k v needComma |
m := JsonObject new.
needComma := false.
[self skipWhitespace.
(stream peekFor: $}) ifTrue: [^m].
needComma
ifTrue:
[(stream peekFor: $,) ifFalse: [JsonSyntaxError signal: 'Missing comma'].
self skipWhitespace]
ifFalse: [needComma := true].
"k := self readAny."
(stream peekFor: $")
ifFalse: [JsonSyntaxError signal: 'Key in dictionary must be string'].
k := self readString.
self skipWhitespace.
(stream peekFor: $:) ifFalse: [JsonSyntaxError signal: 'Missing colon'].
v := self readAny.
m at: k put: v]
repeat
]
readNumber [
<category: 'private'>
| acc c |
acc := WriteStream on: ''.
[c := stream peek.
(c isNil not and: [Json numbersMayContain: c])
ifFalse:
[[^acc contents asNumber] on: Error
do: [JsonSyntaxError signal: 'Invalid number']].
acc nextPut: c.
stream next]
repeat
]
readString [
<category: 'private'>
| s c |
s := WriteStream on: ''.
[c := stream next.
c == $\
ifTrue: [s nextPut: self interpretStringEscape]
ifFalse:
[c == $" ifTrue: [^s contents].
s nextPut: c]]
repeat
]
skipComment [
<category: 'private'>
stream peek == $/
ifTrue:
[stream next.
stream peek == $/
ifTrue: [self skipToEndOfLine]
ifFalse:
[stream peek == $*
ifTrue:
[stream next.
self skipCommentBody]
ifFalse: [JsonSyntaxError signal: 'Invalid comment syntax']]]
]
skipCommentBody [
<category: 'private'>
[[stream next == $*] whileFalse.
stream peek == $/] whileFalse.
stream next. "skip that last slash"
self skipWhitespace
]
skipToEndOfLine [
<category: 'private'>
| cr lf |
cr := Character cr.
lf := Character lf.
[| c |
(c := stream peek) == cr or: [c == lf]] whileFalse: [stream next].
self skipWhitespace
]
skipWhitespace [
<category: 'private'>
[stream peek isSeparator] whileTrue: [stream next].
self skipComment
]
unescapeUnicode [
<category: 'private'>
| string |
string := (String
with: stream next
with: stream next
with: stream next
with: stream next) asUppercase.
^Character codePoint: (Integer readFrom: string readStream radix: 16)
]
ctorMap [
<category: 'accessing'>
^ctorMap
]
ctorMap: m [
<category: 'accessing'>
ctorMap := m
]
stream [
"Answer the value of stream"
<category: 'accessing'>
^stream
]
stream: anObject [
"Set the value of stream"
<category: 'accessing'>
stream := anObject.
(stream respondsTo: #reset) ifTrue: [stream reset]
]
readAny [
"This is the main entry point for the JSON parser. See also readFrom: on the class side."
<category: 'parsing'>
| c |
self skipWhitespace.
c := stream peek asLowercase.
c == ${
ifTrue:
[stream next.
^self readDictionary].
c == $[
ifTrue:
[stream next.
^self readArray].
c == $"
ifTrue:
[stream next.
^self readString].
c == $t ifTrue: [^self consume: 'true' returning: true].
c == $f ifTrue: [^self consume: 'false' returning: false].
c == $n ifTrue: [^self consume: 'null' returning: nil].
c == $@
ifTrue:
[stream next.
^self readConstructor].
(Json numbersMayContain: c) ifTrue: [^self readNumber].
JsonSyntaxError signal: 'Unknown Json input'
]
readFrom: aStream [
<category: 'parsing'>
self stream: aStream.
^self readAny
]
]
Eval [
Json initialize
]