gts-kill-ring-render saves both input & output

[strikerlulu]

In v1 i think go-translate-kill-ring-save only saved the output(target lang)
but now gts-kill-ring-render saves both input & output
I see an option to create my own render but how do i just get the result of translated text from result ?

[lorniu]

Different parser makes different result.

This will cause all (both input & output & more) copied to kill ring:

(setq gts-default-translator
      (gts-translator
       :picker (gts-prompt-picker)
       :engines (gts-google-engine)
       :render (gts-kill-ring-render)))

While this will only copy the brief result:

(setq gts-default-translator
      (gts-translator
       :picker (gts-prompt-picker)
       :engines (gts-google-engine :parser (gts-google-summary-parser))
       :render (gts-kill-ring-render)))

[strikerlulu]

Thx :)

(gts-translate (gts-translator
                  :picker (gts-prompt-picker)
                  :engines (gts-google-rpc-engine)
                  :render (gts-posframe-pop-render))))

is there any way to speak the input in background while its rendering in posframe popup ?
like pressing y to speak on the gts-buffer-render

[lorniu]

Same keybinds as in gts-buffer-render. Focus and click the pop-up frame window, and then use y to play the sound.

[strikerlulu]

i don't wanna use mouse :(
so i think I've to create a new render and use go-tts function to speak

;; A method
(cl-defmethod gts-out ((_ your-render) result)
  (deactivate-mark)
  (insert result))

and in the README instead of result shouldn't it be task ? how do i get the insert-able text from the task ?

[strikerlulu]

Ah got it...
i just override the gts-postframe-pop-render's gts-out method for the ease :P

(cl-defmethod gts-out ((_ gts-posframe-pop-render) task)
  (when-let ((buf (gts-render-buffer gts-posframe-pop-render-buffer task)))
    (posframe-refresh buf)
    (add-hook 'post-command-hook #'gts-posframe-render-auto-close-handler))
  (with-slots (text from engine) task
    (gts-tts engine text from)))

and i think in README it should be

(cl-defmethod gts-out ((_ your-render) task)
  (deactivate-mark)
  (with-slots (result) task
    (insert result)))

[lorniu]

Thanks for correcting.

And, with eieio you can write shorter:

(cl-defmethod gts-out :after ((_ gts-posframe-pop-render) task)
  (with-slots (text from engine) task
    (gts-tts engine text from)))

Also you can write another render instead:

(defclass your-posframe-pop-with-tts-render (gts-posframe-pop-render) ())

(cl-defmethod gts-out ((_ your-posframe-pop-with-tts-render) task)
  (cl-call-next-method)
  (with-slots (text from engine) task
    (gts-tts engine text from)))

;; then use `your-posframe-pop-with-tts-render' in your command.
  :render (your-posframe-pop-with-tts-render)