Add belongs_to and has_many

Close #53
Close #54

db/migrations/20171006163153_create_posts_and_comments.cr

@@ -0,0 +1,17 @@
+class CreatePostsAndComments::V20171006163153 < LuckyMigrator::Migration::V1
+  def migrate
+    create :posts do
+      add title : String
+    end
+
+    create :comments do
+      add body : String
+      add post_id : Int32
+    end
+  end
+
+  def rollback
+    drop :posts
+    drop :comments
+  end
+end

spec/associations_spec.cr

@@ -0,0 +1,13 @@
+require "./spec_helper"
+
+describe LuckyRecord::Model do
+  it "gets the related records" do
+    post = PostBox.save
+    comment = CommentBox.new.post_id(post.id).save
+
+    post = Post::BaseQuery.new.find(post.id)
+
+    post.comments.to_a.should eq [comment]
+    comment.post.should eq post
+  end
+end

spec/support/comment.cr

@@ -0,0 +1,8 @@
+require "./post"
+
+class Comment < LuckyRecord::Model
+  table :comments do
+    field body : String
+    belongs_to post, Post
+  end
+end

spec/support/comment_box.cr

@@ -0,0 +1,26 @@
+class CommentBox
+  getter form
+
+  @form = Comment::BaseForm.new
+
+  def initialize
+    body "Best comment ever"
+  end
+
+  def self.save
+    new.save
+  end
+
+  def save
+    if form.save
+      form.record.not_nil!
+    else
+      raise "Did not save. Make sure fields are valid"
+    end
+  end
+
+  macro method_missing(call)
+    form.{{ call.name.id }}.value = {{ call.args.first }}
+    self
+  end
+end

spec/support/post.cr

@@ -0,0 +1,8 @@
+require "./comment"
+
+class Post < LuckyRecord::Model
+  table :posts do
+    field title : String
+    has_many comments, Comment
+  end
+end

spec/support/post_box.cr

@@ -0,0 +1,26 @@
+class PostBox
+  getter form
+
+  @form = Post::BaseForm.new
+
+  def initialize
+    title "My Cool Title"
+  end
+
+  def self.save
+    new.save
+  end
+
+  def save
+    if form.save
+      form.record.not_nil!
+    else
+      raise "Did not save. Make sure fields are valid"
+    end
+  end
+
+  macro method_missing(call)
+    form.{{ call.name.id }}.value = {{ call.args.first }}
+    self
+  end
+end

src/lucky_record/associations.cr

@@ -0,0 +1,15 @@
+module LuckyRecord::Associations
+  macro has_many(assoc_name, model)
+    def {{ assoc_name.id }}
+      {{ model }}::BaseQuery.new.{{ @type.name.underscore }}_id(id)
+    end
+  end
+
+  macro belongs_to(assoc_name, model)
+    field {{ assoc_name.id }}_id : Int32
+
+    def {{ assoc_name.id }}
+      {{ model }}::BaseQuery.new.find({{ assoc_name.id }}_id)
+    end
+  end
+end

src/lucky_record/model.cr

@@ -1,4 +1,6 @@
 class LuckyRecord::Model
+  include LuckyRecord::Associations
+
   macro inherited
     FIELDS = [] of {name: Symbol, type: Object, nilable: Bool, autogenerated: Bool}