/
ch-1.raku
160 lines (120 loc) · 4.5 KB
/
ch-1.raku
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
use v6d;
################################################################################
=begin comment
Perl Weekly Challenge 263
=========================
TASK #1
-------
*Target Index*
Submitted by: Mohammad Sajid Anwar
You are given an array of integers, @ints and a target element $k.
Write a script to return the list of indices in the sorted array where the
element is same as the given target element.
Example 1
Input: @ints = (1, 5, 3, 2, 4, 2), $k = 2
Output: (1, 2)
Sorted array: (1, 2, 2, 3, 4, 5)
Target indices: (1, 2) as $ints[1] = 2 and $k[2] = 2
Example 2
Input: @ints = (1, 2, 4, 3, 5), $k = 6
Output: ()
No element in the given array matching the given target.
Example 3
Input: @ints = (5, 3, 2, 4, 2, 1), $k = 4
Output: (4)
Sorted array: (1, 2, 2, 3, 4, 5)
Target index: (4) as $ints[4] = 4
=end comment
################################################################################
#--------------------------------------#
# Copyright © 2024 PerlMonk Athanasius #
#--------------------------------------#
#===============================================================================
=begin comment
Interface
---------
1. If no command-line arguments are given, the test suite is run. Otherwise:
2. The divisor $k is given on the command-line as a named argument, followed by
a (possibly empty) unnamed list of integers.
3. If the first integer in the list (i.e., following $k) on the command-line is
negative, it must be preceded by "--" to indicate that it is not a command-
line flag.
=end comment
#===============================================================================
use Test;
#-------------------------------------------------------------------------------
BEGIN
#-------------------------------------------------------------------------------
{
"\nChallenge 263, Task #1: Target Index (Raku)\n".put;
}
#===============================================================================
multi sub MAIN
(
Int:D :$k, #= The target element
*@ints where { .all ~~ Int:D } #= A list of integers
)
#===============================================================================
{
"Input: \@ints = (%s), \$k = %d\n".printf: @ints.join( ', ' ), $k;
my UInt @indices = find-target-indices( @ints, $k );
"Output: (%s)\n".printf: @indices.join: ', ';
}
#===============================================================================
multi sub MAIN() # No input: run the test suite
#===============================================================================
{
run-tests();
}
#-------------------------------------------------------------------------------
sub find-target-indices( List:D[Int:D] $ints, Int:D $k --> List:D[UInt:D] )
#-------------------------------------------------------------------------------
{
my UInt @indices;
my Int @sorted = $ints.sort;
for 0 .. @sorted.end -> UInt $i
{
@indices.push: $i if @sorted[ $i ] == $k;
}
return @indices;
}
#-------------------------------------------------------------------------------
sub run-tests()
#-------------------------------------------------------------------------------
{
'Running the test suite'.put;
for test-data.lines -> Str $line
{
my Str ($test-name, $ints-str, $k-str, $expd-str) = $line.split: / \| /;
for $test-name, $ints-str, $k-str, $expd-str
{
s/ ^ \s+ //;
s/ \s+ $ //;
}
my Int @ints = $ints-str.split( / \s+ /, :skip-empty ).map: { .Int };
my UInt @expd = $expd-str.split( / \s+ /, :skip-empty ).map: { .Int };
my UInt @inds = find-target-indices( @ints, $k-str.Int );
is-deeply @inds, @expd, $test-name;
}
done-testing;
}
#-------------------------------------------------------------------------------
sub USAGE()
#-------------------------------------------------------------------------------
{
my Str $usage = $*USAGE;
$usage ~~ s:g/ ($*PROGRAM-NAME) /raku $0/;
$usage.put;
}
#-------------------------------------------------------------------------------
sub test-data( --> Str:D )
#-------------------------------------------------------------------------------
{
return q:to/END/;
Example 1| 1 5 3 2 4 2| 2|1 2
Example 2| 1 2 4 3 5 | 6|
Example 3| 5 3 2 4 2 1| 4|4
Negatives|-1 -2 -3 0 4 -3|-3|0 1
END
}
################################################################################