added JSON support (#53) (#55)

example-data/roles.json

@@ -0,0 +1,10 @@
+[
+  {
+    "Name": "Users",
+    "Description": "The users of the system"
+  },
+  {
+    "Name": "Moderators",
+    "Description": "The mods of the system"
+  }
+]

modules/global/src/de/diedavids/cuba/dataimport/converter/DataConverterFactory.groovy

@@ -10,6 +10,7 @@ class DataConverterFactory {
         switch (fileDescriptor.extension) {
             case 'xlsx': return new ExcelImportDataConverter()
             case 'csv': return new CsvImportDataConverter()
+            case 'json': return new JsonImportDataConverter()
             case 'xml': return new XmlImportDataConverter()
             default: throw new FileNotSupportedException()
         }

modules/global/src/de/diedavids/cuba/dataimport/converter/JsonImportDataConverter.groovy

@@ -0,0 +1,43 @@
+package de.diedavids.cuba.dataimport.converter
+
+import de.diedavids.cuba.dataimport.dto.DataRow
+import de.diedavids.cuba.dataimport.dto.DataRowImpl
+import de.diedavids.cuba.dataimport.dto.ImportData
+import de.diedavids.cuba.dataimport.dto.ImportDataImpl
+import groovy.json.JsonSlurper
+
+class JsonImportDataConverter implements ImportDataConverter {
+    @Override
+    ImportData convert(String content) {
+        def result = new ImportDataImpl()
+
+        def json = parseJson(content)
+
+        json.each {
+            result.columns = getColumns(it)
+            addToTableData(result, it)
+        }
+
+        result
+    }
+
+    private Object parseJson(String content) {
+        new JsonSlurper().parseText(content)
+    }
+
+    private List<String> getColumns(it) {
+        new ArrayList(it.keySet())
+    }
+
+    private DataRow addToTableData(ImportDataImpl importData, Map row) {
+        def dataRow = DataRowImpl.ofMap(row)
+        importData.rows << dataRow
+        dataRow
+    }
+
+    @Override
+    ImportData convert(File file) {
+        convert(file.text)
+    }
+
+}

modules/global/test/de/diedavids/cuba/dataimport/converter/JsonImportDataConverterSpec.groovy

@@ -0,0 +1,46 @@
+package de.diedavids.cuba.dataimport.converter
+
+import de.diedavids.cuba.dataimport.dto.ImportData
+import spock.lang.Specification
+
+class JsonImportDataConverterSpec extends Specification {
+    private sut
+    private String JSON_STRING = '''[
+  {
+    "Name": "Mark",
+    "Lastname": "Andersson"
+  },
+  {
+    "Name": "Pete",
+    "Lastname": "Hansen"
+  }
+]'''
+
+
+    void setup() {
+        sut = new JsonImportDataConverter()
+    }
+
+    def "convert contains the correct amount of columns"() {
+
+        when:
+        ImportData result = sut.convert(JSON_STRING)
+        then:
+        result.columns.size() == 2
+    }
+
+    def "convert contains two DataRows"() {
+        when:
+        ImportData result = sut.convert(JSON_STRING)
+        then:
+        result.rows.size() == 2
+    }
+
+    def "convert contains the correct values for the DataRows"() {
+        when:
+        ImportData result = sut.convert(JSON_STRING)
+        then:
+        result.rows[0].Name == 'Mark'
+        result.rows[0].Lastname == 'Andersson'
+    }
+}