-
Notifications
You must be signed in to change notification settings - Fork 1
/
ColorOrganCalculator.pde
286 lines (237 loc) · 9.37 KB
/
ColorOrganCalculator.pde
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
/*
Color Organ Calculator
Produces amplitude information from configurable frequency bands
from a live sound stream via the minim library (applying some
shaping with the goal of producing an interesting light display).
Copyright (C) 2013 Douglas A. Telfer
This source code is released simultaneously under the GNU GPL v2
and the Mozilla Public License, v. 2.0; derived works may use
either license, a compatible license, or both licenses as suits
the needs of the derived work.
Additional licensing terms may be available; contact the author
with your proposal.
*** GNU General Public License, version 2 notice:
This program is free software; you can redistribute it and/or
modify it under the terms of the GNU General Public License
as published by the Free Software Foundation; either version 2
of the License, or (at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU General Public License
along with this program; if not, write to the Free Software
Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
*** Mozilla Public License, v. 2.0 notice:
This Source Code Form is subject to the terms of the Mozilla Public
License, v. 2.0. If a copy of the MPL was not distributed with this
file, You can obtain one at http://mozilla.org/MPL/2.0/
*/
import ddf.minim.analysis.*;
import ddf.minim.*;
class ColorOrganCalculator {
protected Minim minim;
protected AudioInput myInput;
protected AudioOutput myOutput;
protected BeatDetect beat;
protected FFT fftL;
protected FFT fftR;
public int bufferSize;
public int minBeatPeriod;
// Frequency analysis
public float decay;
public float decayPeriod;
public float thresBot;
public float thresTop;
protected float[] peaks;
protected float[] peakSinceUpdate;
protected float[] noiseLvl;
public float minPeak; // Used to stop lights flickering at start due to inaudible noise
public boolean trackNoiseLvl = false;
protected float maxPeak;
protected int maxPeakIdx;
protected int bandNumber;
protected int beatRadix;
public int beatNumber;
protected int lastUpdate;
public long[] colorIndex; // Standard HTML 24-bit RGB hex color notation.
public int bandLimit = 12;
public int startingQ = 55;
public int octaveDivisions = 2;
public ColorOrganCalculator() {
this(new long[] {0xff0000, 0xff0000, 0xff0000, 0xffff00, 0x00ff00, 0x00ff00,
0x00ff00, 0x0000ff, 0x0000ff, 0x8000ff, 0xff00ff, 0xff00ff},
12, 55, 2, 0);
}
public ColorOrganCalculator(long[] colorIndex,
int bandLimit,
int startingQ,
int octaveDivisions,
int beatRadix) {
this.colorIndex = colorIndex;
this.bandLimit = bandLimit;
this.startingQ = startingQ;
this.octaveDivisions = octaveDivisions;
this.beatRadix = beatRadix;
bufferSize = 2048;
minBeatPeriod = 300; // if new "beat" is < 300 ms after last beat, ignore it.
decay = 0.99f;
decayPeriod = 60.0/1000.0; // 60 updates per 1000ms
thresBot = 0.3;
thresTop = 0.9;
minPeak = 0.1; // Used to stop lights flickering at start due to inaudible noise
trackNoiseLvl = false;
maxPeak = 0;
maxPeakIdx = 0;
beatNumber = 0;
}
public void init() {
// Init all the sound objects
minim = new Minim(this);
myInput = minim.getLineIn(Minim.STEREO, bufferSize);
fftL = new FFT(myInput.bufferSize(), myInput.sampleRate());
fftL.logAverages(startingQ, octaveDivisions);
fftL.window(FFT.HAMMING);
fftR = new FFT(myInput.bufferSize(), myInput.sampleRate());
fftR.logAverages(startingQ, octaveDivisions);
fftR.window(FFT.HAMMING);
beat = new BeatDetect(myInput.bufferSize(), myInput.sampleRate());
beat.setSensitivity(minBeatPeriod);
bandNumber = min(bandLimit, fftL.avgSize());
peaks = new float[bandNumber];
peakSinceUpdate = new float[bandNumber];
noiseLvl = new float[bandNumber];
for (int i = 0; i < bandNumber; ++i) peaks[i] = minPeak;
lastUpdate = millis();
}
public void analyzeInput() {
beat.detect(myInput.mix);
fftL.forward(myInput.left);
fftR.forward(myInput.right);
}
public float[] getCurrentLevels() {
checkPeaks();
return getAmplitudes();
}
public int[] getCurrentColors() {
return getColors(getCurrentLevels());
}
void checkPeaks() {
boolean newPeak = false;
boolean newMaxPeak = false;
// Grab the new level data. Check to see if it represents a new peak.
// Also check to see if there is a new max peak.
// If there are no new peaks, decay the levels of the current peaks.
// (this acts as a primitive auto-level control, and helps emphasize
// changes in volume)
for (int i=0; i < bandNumber; i++) {
if (fftL.getAvg(i) + fftR.getAvg(i) > peaks[i]) {
peaks[i] = fftL.getAvg(i) + fftR.getAvg(i);
// Shape peaks to pink noise curve
peaks[i] *= pow(10.0, (3.0/20) * (i/octaveDivisions));
if (peaks[i] > maxPeak) {
newMaxPeak = true;
maxPeak = peaks[i];
maxPeakIdx = i;
}
}
if (!newPeak) {
peaks[i] *= pow(decay, (millis() - lastUpdate) * decayPeriod);
if (peaks[i] < minPeak) peaks[i] = minPeak;
}
}
if (!newMaxPeak) {
maxPeak *= pow(decay, (millis() - lastUpdate) * decayPeriod);
if (maxPeak < minPeak) maxPeak = minPeak;
}
// Raise the other peaks based on the max peak. This allows a few
// fequency bands to dominate the display when those frequencies also
// dominate the sound spectrum. The power function makes more distant
// frequency bands less affected by this shaping. The value of 0.9
// (and heck, the function) was the result of crude experimentation.
// There are probably better methods for this, but it seems to do
// about what I want.
for (int i = 0; i < bandNumber; i++) {
float peakTop = maxPeak*(pow(0.9, abs(i-maxPeakIdx)));
if (peaks[i] < peakTop) peaks[i] = peakTop;
}
if (trackNoiseLvl) setNoiseFloor();
// I'm not sure I'm totally sold on this. It seems a little busy.
if (beat.isKick()) beatNumber++;
if (beatNumber >= beatRadix) beatNumber = 0;
lastUpdate = millis();
}
public float[] getAmplitudes() {
float[] amplitudes = new float[bandNumber];
for (int i=0; i < bandNumber; i++) {
float amp = fftL.getAvg(i) + fftR.getAvg(i);
// Check noise threshold. If above, normalize amp to [0-1].
if (amp > noiseLvl[i]) amp = (amp)/peaks[i] * pow(10.0, (3.0/20) * (i/octaveDivisions));
else amp = 0;
// Shape the band levels. Peg values above or below the upper and lower
// bounds. Remap the middle so that it covers the full range. Less space
// between the bounds makes things blinkier.
if (amp < thresBot) amp = 0;
else if (amp > thresTop) amp = 1;
else amp = amp/(thresTop - thresBot) - thresBot;
if (amp < 0) amp = 0;
else if (amp > 1) amp = 1;
// Hold on the biggest amplitudes we've seen since the last update. This
// is so that we don't lose transients if it takes too long to communicate
// with the lights. I'm not sure how much of a difference this makes
// though.
if (amp > peakSinceUpdate[i]) peakSinceUpdate[i]=amp;
else amp=peakSinceUpdate[i];
amplitudes[i] = amp;
}
return amplitudes;
}
public int[] getColors(float[] amplitudes) {
int[] colors = new int[amplitudes.length*3];
for (int i=0; i < amplitudes.length; i++) {
long col = colorIndex[i%colorIndex.length];
// Set the colors from the amplitudes
colors[i*3+0] = (byte)( ((col&0xff0000) >> 16)*amplitudes[i] );
colors[i*3+1] = (byte)( ((col&0x00ff00) >> 8 )*amplitudes[i] );
colors[i*3+2] = (byte)( ((col&0x0000ff) )*amplitudes[i] );
}
return colors;
}
public void clearPSU() {
for (int i = 0; i<bandNumber; ++i) {
peakSinceUpdate[i] = 0;
}
}
// This is used primarily when taking audio from an external input. Since
// I automatically reset levels based on recent input volume, even a
// small amount of noise from the external source will eventually light
// up some of the lights, which can ruin the effect of quiet passages
// in the music. The somewhat crude solution is to set a noise threshold
// when no music is playing. Sound must exceed the volume of the noise in
// order to be recognized. This check is done on a per-band basis, so a
// lot of noise in one band (e.g. a 60Hz hum) won't interfere with the
// sensitivity of other bands.
public void startSettingNoiseLevel() {
if (!trackNoiseLvl) {
for (int i=0; i < fftL.avgSize(); i++) {
noiseLvl[i] = 0;
}
trackNoiseLvl = true;
}
}
public void stopSettingNoiseLevel() {
trackNoiseLvl = false;
}
void setNoiseFloor() {
for (int i=0; i < bandNumber; i++) {
if (fftL.getAvg(i)+fftR.getAvg(i) > noiseLvl[i]) {
noiseLvl[i] = fftL.getAvg(i)+fftR.getAvg(i);
}
}
}
public void stop() {
myInput.close();
myOutput.close();
minim.stop();
}
}