/
gth.erl
1680 lines (1429 loc) · 54.9 KB
/
gth.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%%%-------------------------------------------------------------------
%%% File : gth.erl
%%% Author : matthias <matthias@corelatus.se>
%%% Description : An Erlang wrapper for the XML API on a Corelatus GTH.
%%%
%%% A corelatus GTH is a T1/E1 device which can do pretty
%%% much anything with a T1/E1 line: detect tones, switch
%%% timeslots, decode signalling, play recorded messages, etc.
%%%
%%% This interface lets you interface to a GTH without
%%% having to deal with the API socket and its XML
%%% commands directly.
%%%
%%% See also: www.corelatus.com/gth/api/
%%%
%%% This code follows the GTH API documentation closely, e.g.
%%% the API command
%%%
%%% <new><mtp2_monitor ....>
%%% <pcm_source span='1A' timeslot='9'/>
%%% </mtp2_monitor></new>
%%%
%%% is implemented by the function new_mtp2_monitor/3. The
%%% options all have the same names and values as in the
%%% XML API, but they're coded as lists of tuples. So for
%%% instance the option attributes in
%%%
%%% <mtp2_monitor msu='yes' tag='13'>
%%%
%%% are passed to this code as
%%%
%%% [{"msu", "yes"}, {"tag", 13}]
%%%
%%% Example: starting MTP-2 monitoring
%%%
%%% 41> {ok, A} = gth:start_link("172.16.2.7").
%%% {ok,<0.188.0>}
%%% 42> {ok, ID, Socket} = gth:new_mtp2_monitor(A, "1A", 16).
%%% {ok,"m2mo21",#Port<0.2261>}
%%%
%%% You can now read MTP-2 packets from 'Socket' by calling
%%% gen_tcp:recv()
%%%
%%% Example: defining a clip and playing it
%%%
%%% 43> {ok, _} = gth:new_clip(A, "my clip", [1,2,3]).
%%% {ok, "clip my clip"}
%%% 44> {ok, _} = gth:new_player(A, ["clip my clip"], "1A", 3)
%%% {ok, "play13"}
%%%
%%% This code is shipped to customers.
%%%
%%% Copyright (c) 2009, Corelatus AB Stockholm
%%%
%%% Licence: BSD
%%%
%%% All rights reserved.
%%%
%%% Redistribution and use in source and binary forms, with or without
%%% modification, are permitted provided that the following conditions are met:
%%% * Redistributions of source code must retain the above copyright
%%% notice, this list of conditions and the following disclaimer.
%%% * Redistributions in binary form must reproduce the above copyright
%%% notice, this list of conditions and the following disclaimer in the
%%% documentation and/or other materials provided with the distribution.
%%% * Neither the name of Corelatus nor the
%%% names of its contributors may be used to endorse or promote products
%%% derived from this software without specific prior written permission.
%%%
%%% THIS SOFTWARE IS PROVIDED BY Corelatus ''AS IS'' AND ANY EXPRESS
%%% OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
%%% WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
%%% ARE DISCLAIMED. IN NO EVENT SHALL Corelatus BE LIABLE FOR ANY
%%% DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
%%% DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE
%%% GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
%%% INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
%%% WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
%%% NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
%%% SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
%%%
%%%
%%% To do: edoc-ify this module
%%%
%%%-------------------------------------------------------------------
-module(gth).
-behaviour(gen_server).
-include("gth_xml.hrl").
%% API
-export([start_link/1, start_link/2,
atomise_error_reason/1,
bye/1,
custom/3,
delete/2,
disable/2,
enable/2, enable/3,
get_ip/1, get_gth_ip/1, get_my_ip/1,
install/3,
map/3, map/5,
new_clip/3,
new_atm_aal0_layer/3, new_atm_aal0_layer/4,
new_atm_aal0_monitor/3, new_atm_aal0_monitor/4,
new_atm_aal2_monitor/4, new_atm_aal2_monitor/5,
new_atm_aal5_monitor/4, new_atm_aal5_monitor/5,
new_cas_r2_mfc_detector/4, new_cas_r2_mfc_detector/5,
new_cas_r2_linesig_monitor/3, new_cas_r2_linesig_monitor/4,
new_connection/5, new_connection/6,
new_fr_monitor/3, new_fr_monitor/4,
new_fr_layer/3,
new_lapd_layer/6, new_lapd_layer/7,
new_lapd_monitor/3, new_lapd_monitor/4,
new_level_detector/4, new_level_detector/6,
new_mtp2_monitor/3, new_mtp2_monitor/4,
new_player/4, new_player/5,
new_raw_monitor/3, new_raw_monitor/4,
new_recorder/3, new_recorder/4,
new_ss5_linesig_monitor/3, new_ss5_linesig_monitor/4,
new_ss5_registersig_monitor/3, new_ss5_registersig_monitor/4,
new_tcp_player/3, new_tcp_player/4,
new_wide_recorder/3,
new_tone_detector/3, new_tone_detector/4,
new_tone_detector/5, new_tone_detector/6,
nop/1,
query_jobs/3, query_jobs/2, query_job/2, query_job/3,
query_resource/2, query_resource/3,
raw_xml/2,
reset/1,
set/3,
takeover/2,
unmap/2,
update/3,
zero_job/2,
zero_resource/2
]).
%% gen_server callbacks
-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
terminate/2, code_change/3]).
-record(state,
{socket :: port() | none,
debug_remote_ip :: hostname_or_address(),
xml_cmd_checker :: fun((binary()) -> any()) | 'none',
xml_resp_checker :: fun((binary()) -> any()) | 'none',
%% pre-opened listen socket for players
player_ls :: {integer(), port()},
command_timeout = 5000 :: integer(),
event_dict :: dict:dictionary(),
resource_event_target :: pid(),
job_event_target :: pid(),
my_ip :: string()}). %% my IP address, according to the GTH
%% Macro used in guards to decide if something is a valid event handler.
-define(IS_VALID_EVENT_HANDLER(Arg), (Arg == default orelse is_pid(Arg)) ).
%% This code supervises the GTH, and requests the GTH to supervise it.
-define(KICK_INTERVAL, 5000).
-type ok_or_error()::'ok' | {error, Reason::any()}.
-type id_or_error()::{'ok', string()} | {error, Reason::any()}.
-type resource_or_error()::{'ok', string()} | {error, Reason::any()}.
-type keyval()::{Key::atom() | string(), Value::any()}.
-type keyval_list()::[keyval()].
-type option_list()::[Option::atom() | keyval()].
-type event_handler()::'default' | pid().
-type timeslot_or_timeslot_list()::1..31 | [1..31].
-type subrate()::{'subrate', Timeslot::1..31, First_bit::0..7,
Bandwidth::integer()}.
%% The reuse_socket option sends the signalling to an existing socket
%% instead of opening a new one.
-type monitoring_options()::[{string(), integer() | string()}
|{reuse_socket, port()}].
-type hostname_or_address()::inet:hostname() | inet:ip_address().
-type job()::{'job', Id::string(), Owner::string(), Counters::keyval_list()}
|{'job', Id::string(), Owner::string(), Tree::#resp_tuple{},
Counters::keyval_list()}.
%% API for users
-spec start_link( hostname_or_address() ) -> {'ok',pid()} | {'error', _}.
start_link(Host) ->
start_link(Host, []).
-type startup_options() ::
[{connect_timeout, integer()} %% milliseconds
|{job_event_target, pid()} %% callback for job-related events
|{resource_event_target, pid()} %% callback for resource-related events
|{api_port_number, integer()} %% defaults to 2089, as per API doc
%% hooks for seeing all XML going to and from the GTH. Useful for
%% automated testing.
|{xml_cmd_checker, fun((binary()) -> any())}
|{xml_resp_checker, fun((binary()) -> any())}
].
%% Event handlers process GTH events. Whenever an event comes, a message
%% is sent to the given PID. The event is always a tuple:
%% -type event() :: {Type::atom(), API::pid(), Details::any()}.
%% Start_link connects to the API socket but then cedes control to
%% the newly started process. This is a bit complicated, but it allows
%% us to fail without a crash when the remote socket can't be opened.
-spec start_link( hostname_or_address(), startup_options()) ->
{'ok', pid()} | {'error', _}.
start_link(Host, Options)
when is_list(Options) ->
Default = [{gth_ip, Host},
{connect_timeout, 5000},
{job_event_target, self()},
{resource_event_target, self()},
{api_port_number, 2089},
{xml_cmd_checker, 'none'},
{xml_resp_checker, 'none'}
],
Timeout = proplists:get_value(connect_timeout, Options ++ Default),
Port_number = proplists:get_value(api_port_number, Options ++ Default),
case gen_tcp:connect(Host, Port_number,
[{active, false}, binary, {packet, line}], Timeout) of
{ok, S} ->
case gen_server:start_link(?MODULE,
[{socket, S}|Options]++ Default, []) of
{ok, Pid} ->
ok = gen_tcp:controlling_process(S, Pid),
gen_server:call(Pid, socket_ready),
{ok, Pid};
Error ->
Error
end;
Error ->
Error
end.
-spec bye(pid()) -> 'ok'.
%% Terminate gracefully. This is the only graceful way to shut down;
%% if you just kill the process, we don't attempt to send <bye/>.
bye(Pid)
when is_pid(Pid) ->
Result = gen_server:call(Pid, bye),
flush(Pid),
Result.
-spec custom(pid(), string(), keyval_list()) -> ok_or_error().
custom(Pid, Name, Attributes)
when is_pid(Pid), is_list(Name), is_list(Attributes) ->
gen_server:call(Pid, {custom, Name, Attributes}).
-spec delete(pid(), string()) -> ok_or_error().
delete(Pid, Id)
when is_pid(Pid), is_list(Id) ->
gen_server:call(Pid, {delete, Id}).
-spec disable(pid(), string()) -> ok_or_error().
disable(Pid, Name)
when is_pid(Pid), is_list(Name) ->
gen_server:call(Pid, {disable, Name}).
-spec enable(pid(), Name::string(), Attributes::keyval_list()) -> ok_or_error().
enable(Pid, Name) ->
enable(Pid, Name, []).
enable(Pid, Name, Attributes)
when is_pid(Pid), is_list(Attributes) ->
gen_server:call(Pid, {enable, Name, Attributes}).
-spec get_gth_ip(pid()) -> {ok, inet:ip_address()}.
get_gth_ip(Pid)
when is_pid(Pid) ->
gen_server:call(Pid, get_gth_ip).
%% Returns the address of the local end of the API socket. Mainly
%% useful on multi-homed machines.
-spec get_my_ip(pid()) -> {ok, inet:ip_address()}.
get_my_ip(Pid)
when is_pid(Pid) ->
gen_server:call(Pid, get_my_ip).
%% Deprecated; included for backwards compatibility.
get_ip(Pid) ->
get_gth_ip(Pid).
-type install_fun() :: fun(() -> {binary(), fun() | eof}).
%% If called with a fun() as the third argument, the install process
%% will call fun() to obtain some data and a new fun, and then call the
%% new fun. That continues until eof is returned instead of a new fun.
-spec install(pid(), string(), binary() | {integer(), install_fun()}) ->
ok_or_error().
install(Pid, Name, Bin_or_fun)
when is_pid(Pid), is_list(Name) ->
%% Use a long timeout, install takes time
gen_server:call(Pid, {install, Name, Bin_or_fun}, 60000).
-spec new_cas_r2_mfc_detector(pid(), string(), 1..31,
Direction::'forward' | 'backward',
monitoring_options()) ->
{ok, string(), port()} | {'error', any()}.
-spec map(pid(), 'pcm_source', Name::iolist()) -> resource_or_error().
map(Pid, pcm_source, Name)
when is_pid(Pid), is_list(Name) ->
gen_server:call(Pid, {map, pcm_source, Name}).
%% Variant of map which allows HOP and LOP to be passed in as lists, e.g.
%% map(Pid, pcm_source, "sdh1", [1,2], [3,4]).
-spec map(pid(), 'pcm_source',
Name::string(),
HOP::[integer()], LOP::[integer()]) -> resource_or_error().
map(Pid, pcm_source, Name, HOP, LOP) ->
Full_name = [Name, ":hop", path_to_string(HOP), ":lop",path_to_string(LOP)],
map(Pid, pcm_source, Full_name).
new_cas_r2_mfc_detector(Pid, Span, Timeslot, Direction, Options)
when is_pid(Pid),
is_integer(Timeslot),
is_atom(Direction),
is_list(Options) ->
gen_server:call(Pid, {new_cas_r2_mfc_detector, Span, Timeslot,
Direction, Options}).
new_cas_r2_mfc_detector(Pid, Span, Timeslot, Direction) ->
new_cas_r2_mfc_detector(Pid, Span, Timeslot, Direction, []).
-spec new_cas_r2_linesig_monitor(pid(), string(), 1..31,
monitoring_options()) ->
{ok, string(), port()}
| {'error', any()}.
new_cas_r2_linesig_monitor(Pid, Span, Timeslot) ->
new_cas_r2_linesig_monitor(Pid, Span, Timeslot, []).
new_cas_r2_linesig_monitor(Pid, Span, Timeslot, Options)
when is_pid(Pid), is_integer(Timeslot), is_list(Options) ->
gen_server:call(Pid, {new_cas_r2_linesig_monitor, Span, Timeslot, Options}).
-spec new_clip(pid(), string(), binary() | iolist()) -> id_or_error().
new_clip(Pid, Name, Bin)
when is_pid(Pid), is_binary(Bin) ->
gen_server:call(Pid, {new_clip, Name, Bin});
new_clip(Pid, Name, List)
when is_list(List) ->
new_clip(Pid, Name, list_to_binary(List)).
-spec new_connection(pid(), string(), 1..31, string(), 1..31) ->
id_or_error().
new_connection(Pid, S_span, S_ts, D_span, D_ts)
when is_pid(Pid), is_integer(S_ts), is_integer(D_ts) ->
gen_server:call(Pid, {new_connection, S_span, S_ts, D_span, D_ts}).
new_connection(Pid, S_span, S_ts, D_IP, D_span, D_ts)
when is_pid(Pid), is_integer(S_ts), is_integer(D_ts) ->
gen_server:call(Pid, {new_connection, S_span, S_ts, D_IP, D_span, D_ts}).
-spec new_lapd_layer(pid(),
Span::string(),
Timeslot::1..31,
Side::user|network,
SAPI_TEI::{byte(), byte()},
Tag::integer(),
Options::keyval_list()) ->
{ok, string(), port()} | {error, any()}.
new_lapd_layer(Pid, Span, Ts, Side, SAPI_TEI, Tag) ->
new_lapd_layer(Pid, Span, Ts, Side, SAPI_TEI, Tag, []).
new_lapd_layer(Pid, Span, Ts, Side, {SAPI, TEI}, Tag, Options)
when is_pid(Pid), is_integer(Ts), is_atom(Side), is_integer(SAPI),
is_integer(TEI), is_integer(Tag), is_list(Options) ->
gen_server:call(Pid, {new_lapd_layer, Span, Ts, Side, {SAPI, TEI},
Tag, Options}).
%% Signalling_socket: a socket in {packet, 2} mode
%%
new_mtp2_monitor(Pid, Span, Ts) ->
new_mtp2_monitor(Pid, Span, Ts, []).
-spec new_mtp2_monitor(pid(), string(),
timeslot_or_timeslot_list() | subrate(),
monitoring_options()) ->
{'ok', Id::string(), Signalling_socket::port()}
| {'error', any()}.
new_mtp2_monitor(Pid, Span, Ts, Options)
when is_pid(Pid), is_list(Options) ->
gen_server:call(Pid, {new_mtp2_monitor, Span, Ts, Options}).
new_lapd_monitor(Pid, Span, Ts) ->
new_lapd_monitor(Pid, Span, Ts, []).
-spec new_lapd_monitor(pid(), string(),
1..31 | subrate(),
monitoring_options()) ->
{'ok', string(), port()} | {'error', any()}.
new_lapd_monitor(Pid, Span, Ts, Options)
when is_pid(Pid), is_list(Options) ->
gen_server:call(Pid, {new_lapd_monitor, Span, Ts, Options}).
%% The threshold is given in db
new_level_detector(Pid, Span, Ts, Threshold) ->
new_level_detector(Pid, Span, Ts, Threshold, [], default).
-spec new_level_detector(pid(), string(), 1..31, -100..6, keyval_list(),
event_handler()) ->
{'ok', string()} | {'error', any()}.
new_level_detector(Pid, Span, Ts, Threshold, Options, EH)
when is_pid(Pid), is_integer(Ts), is_integer(Threshold), is_list(Options),
?IS_VALID_EVENT_HANDLER(EH) ->
gen_server:call(Pid, {new_level_detector, Span, Ts, Threshold,
Options, EH}).
-spec new_atm_aal0_monitor(pid(), string(), [1..31], monitoring_options()) ->
{ok, string(), Signalling_socket::port()}
| {error, any()}.
new_atm_aal0_monitor(Pid, Span, Timeslots) ->
new_atm_aal0_monitor(Pid, Span, Timeslots, []).
new_atm_aal0_monitor(Pid, Span, Timeslots, Options)
when is_pid(Pid), is_list(Timeslots), is_list(Options) ->
gen_server:call(Pid, {new_atm_aal0_monitor, Span, Timeslots, Options}).
-spec new_atm_aal2_monitor(pid(), string(), [1..31],
{VPI::integer(), VCI::integer()},
monitoring_options()) ->
{ok, string(), Signalling_socket::port()}
| {error, any()}.
new_atm_aal2_monitor(Host, Span, Timeslots, {VPI, VCI}) ->
new_atm_aal2_monitor(Host, Span, Timeslots, {VPI, VCI}, []).
new_atm_aal2_monitor(Pid, Span, Timeslots, {VPI, VCI}, Options)
when is_pid(Pid), is_list(Timeslots), is_integer(VPI), is_integer(VCI) ->
gen_server:call(Pid,
{new_atm_aal2_monitor,
Span, Timeslots, {VPI, VCI}, Options}).
-spec new_atm_aal5_monitor(pid(), string(), [1..31],
{VPI::integer(), VCI::integer()},
monitoring_options()) ->
{ok, string(), Signalling_socket::port()}
| {error, any()}.
new_atm_aal5_monitor(Pid, Span, Timeslots, {VPI, VCI}) ->
new_atm_aal5_monitor(Pid, Span, Timeslots, {VPI, VCI}, []).
new_atm_aal5_monitor(Pid, Span, Timeslots, {VPI, VCI}, Options)
when is_pid(Pid),
is_list(Timeslots),
is_integer(VPI),
is_integer(VCI),
is_list(Options) ->
gen_server:call(Pid,
{new_atm_aal5_monitor, Span, Timeslots, {VPI, VCI},
Options}).
-spec new_fr_monitor(pid(), string(), [1..31], monitoring_options()) ->
{ok, string(), Signalling_socket::port()}
| {error, any()}.
new_fr_monitor(Pid, Span, Timeslots) ->
new_fr_monitor(Pid, Span, Timeslots, []).
new_fr_monitor(Pid, Span, Timeslots, Options)
when is_pid(Pid), is_list(Timeslots), is_list(Options) ->
gen_server:call(Pid, {new_fr_monitor, Span, Timeslots, Options}).
%% Frame relay layers are unsupported (checked 2012-06-10).
new_fr_layer(Pid, Span, Timeslots)
when is_pid(Pid), is_list(Timeslots) ->
gen_server:call(Pid, {new_fr_layer, Span, Timeslots}).
%% ATM layers are unsupported (checked 2012-06-10).
new_atm_aal0_layer(Pid, Span, Timeslots) ->
new_atm_aal0_layer(Pid, Span, Timeslots, []).
new_atm_aal0_layer(Pid, Span, Timeslots, Options)
when is_pid(Pid), is_list(Timeslots), is_list(Options) ->
gen_server:call(Pid, {new_atm_aal0_layer, Span, Timeslots, Options}).
-spec new_player(pid(), Clips::[string()], Span::string(), Ts::1..31) ->
id_or_error().
new_player(Pid, Clips, Span, Ts) ->
new_player(Pid, Clips, Span, Ts, false).
new_player(Pid, Clips, Span, Ts, Loop)
when is_pid(Pid),
is_boolean(Loop),
is_integer(Ts),
is_list(Clips),
Clips =/= [] ->
gen_server:call(Pid, {new_player, Clips, Span, Ts, Loop}).
%% Raw monitors are experimental (unsupported & undocumented, 2011-12-09)
-spec new_raw_monitor(pid(), string(), 0..31, monitoring_options()) ->
{ok, string(), Raw_socket::port()} | {error, any()}.
new_raw_monitor(Pid, Span, Ts) ->
new_raw_monitor(Pid, Span, Ts, []).
new_raw_monitor(Pid, Span, Ts, Options)
when is_pid(Pid), is_integer(Ts), is_list(Options) ->
gen_server:call(Pid, {new_raw_monitor, Span, Ts, Options}).
%% The 'Raw_socket' is a socket in {packet, 0} mode, delivering timeslot data.
-spec new_recorder(pid(), string(), 0..31, option_list()) ->
{ok, string(), Raw_socket::port()} | {error, any()}.
new_recorder(Pid, Span, Ts) ->
new_recorder(Pid, Span, Ts, []).
new_recorder(Pid, Span, Ts, Options)
when is_pid(Pid), is_integer(Ts), is_list(Options) ->
gen_server:call(Pid, {new_recorder, Span, Ts, Options}).
%% Options: {"tag", integer()}
%% | {udp_address, {inet:ip_address(), Port::integer()}}
-spec new_wide_recorder(pid(), string(), keyval_list()) ->
{ok, string(), UDP::port()}
| {ok, string()}
| {error, any()}.
new_wide_recorder(Pid, Span, Options) when is_pid(Pid) ->
gen_server:call(Pid, {new_wide_recorder, Span, Options}).
-spec new_ss5_linesig_monitor(pid(), string(), 1..31, monitoring_options()) ->
{ok, string(), Signalling_socket::port()}
| {error, any()}.
new_ss5_linesig_monitor(Pid, Span, Ts) ->
new_ss5_linesig_monitor(Pid, Span, Ts, []).
new_ss5_linesig_monitor(Pid, Span, Ts, Options)
when is_pid(Pid), is_integer(Ts), is_list(Options) ->
gen_server:call(Pid, {new_ss5_linesig_monitor, Span, Ts, Options}).
-spec new_ss5_registersig_monitor(pid(), string(), 1..31, monitoring_options()) ->
{ok, string(), Signalling_socket::port()}
| {error, any()}.
new_ss5_registersig_monitor(Pid, Span, Ts) ->
new_ss5_registersig_monitor(Pid, Span, Ts, []).
new_ss5_registersig_monitor(Pid, Span, Ts, Options)
when is_pid(Pid), is_integer(Ts), is_list(Options) ->
gen_server:call(Pid, {new_ss5_registersig_monitor, Span, Ts, Options}).
%% Raw_socket: a socket in {packet, 0} mode
-spec new_tcp_player(pid(), string(), 1..31, keyval_list()) ->
{ok, string(), Raw_socket::port()} | {error, any()}.
new_tcp_player(Pid, Span, Ts) ->
new_tcp_player(Pid, Span, Ts, []).
new_tcp_player(Pid, Span, Ts, Options)
when is_pid(Pid), is_integer(Ts), is_list(Options) ->
gen_server:call(Pid, {new_tcp_player, Span, Ts, Options}).
%% Whenever a tone is detected, {tone, self(), {Id, Name, Length}} is
%% sent to the event handler, by default the calling process.
-spec new_tone_detector(pid(), string(), 1..31, event_handler()) ->
id_or_error().
new_tone_detector(Pid, Span, Ts) ->
new_tone_detector(Pid, Span, Ts, default).
new_tone_detector(Pid, Span, Ts, Event_handler)
when is_pid(Pid), is_integer(Ts),
?IS_VALID_EVENT_HANDLER(Event_handler) ->
gen_server:call(Pid, {new_tone_detector, Span, Ts, Event_handler}).
-spec new_tone_detector(pid(),
string(), 1..31,
Freq::integer(), %% Hertz
Length::integer(), %% milliseconds
event_handler()) ->
id_or_error().
new_tone_detector(Pid, Span, Ts, Freq, Length) ->
new_tone_detector(Pid, Span, Ts, Freq, Length, default).
new_tone_detector(Pid, Span, Ts, Freq, Length, Event_handler)
when is_pid(Pid), Freq > 0, Freq < 4000, Length > 40, Length < 10000 ->
gen_server:call(Pid, {new_tone_detector, Span, Ts, Freq, Length,
Event_handler}).
-spec nop(pid()) -> ok_or_error().
nop(Pid) when is_pid(Pid) ->
gen_server:call(Pid, nop).
%% If called with Verbose=false, the return tuple has the ID, Owner
%% and counters/status indicators.
%%
%% If called with Verbose=true, the return tuple also has a
%% representation of the arguments used to start the job. This is
%% useful for debugging and serialisation. In this case,
%% -include("gth_api.hrl") to get the #resp_tuple{} definition.
%%
-spec query_jobs(pid(), [string()], boolean()) ->
{ok, [{error, any()} | job()]}.
query_jobs(Pid, Ids, Verbose) when is_pid(Pid), is_boolean(Verbose) ->
{ok, gen_server:call(Pid, {query_jobs, Ids, Verbose})}.
query_jobs(Pid, Ids) when is_pid(Pid) ->
query_jobs(Pid, Ids, false).
query_job(Pid, Id, Verbose) ->
case query_jobs(Pid, [Id], Verbose) of
{ok, [Error = {error, _}]} -> Error;
{ok, [Reply]} -> {ok, Reply}
end.
query_job(Pid, Id) ->
query_job(Pid, Id, false).
-spec query_resource(pid(), Name::string()) ->
{ok, keyval_list()} % normal
| {ok, [Name::string()]} % "inventory"
| {ok, keyval_list(), binary()} % log queries
| {error, any()}.
%% This uses a timeout of 15s. When fetching logs over a slow link, that
%% won't be enough. Why are you using a slow link?
query_resource(Pid, Name) ->
gen_server:call(Pid, {query_resource, Name}, 15000).
%% A resource query which returns one value, the once specified by third arg
query_resource(Pid, Name, Attribute) when is_pid(Pid), Name =/= "inventory" ->
case gen_server:call(Pid, {query_resource, Name}, 15000) of
{ok, KVs} ->
query_resource_find(Attribute, KVs);
{ok, KVs, _bin} ->
query_resource_find(Attribute, KVs);
Error = {error, _} ->
Error
end.
query_resource_find(Key, KVs) ->
case lists:keyfind(Key, 1, KVs) of
{_, V} -> {ok, V};
_ -> {error, badarg}
end.
%% Undocumented. Used for testing incorrect API commands.
-spec raw_xml(pid(), binary() | iolist()) -> any().
raw_xml(Pid, XML) when is_pid(Pid) ->
gen_server:call(Pid, {raw_xml, XML}, 30000).
-spec set(pid(), Name::string(), Attributes::keyval_list()) -> ok_or_error().
set(Pid, Name, Attributes)
when is_pid(Pid), is_list(Attributes) ->
gen_server:call(Pid, {set, Name, Attributes}).
-spec reset(pid()) -> ok_or_error().
reset(Pid) when is_pid(Pid) ->
gen_server:call(Pid, reset).
-spec takeover(pid(), IDs::[string()]) -> ok_or_error().
takeover(_Pid, []) ->
ok;
takeover(Pid, IDs = [H|_])
when is_pid(Pid), is_list(H) ->
gen_server:call(Pid, {takeover, IDs}).
-spec unmap(pid(), Name::string()) -> ok_or_error().
unmap(Pid, Name)
when is_pid(Pid), is_list(Name) ->
gen_server:call(Pid, {unmap, Name}).
-spec update(pid(), ID::string(), Attributes::keyval_list() | [string()]) ->
ok_or_error().
update(Pid, ID, Attributes)
when is_pid(Pid), is_list(ID), is_list(Attributes) ->
gen_server:call(Pid, {update, ID, Attributes}).
-spec zero_job(pid(), ID::string()) -> ok_or_error().
zero_job(Pid, Id) when is_pid(Pid) ->
gen_server:call(Pid, {zero_job, Id}).
-spec zero_resource(pid(), ID::string()) -> ok_or_error().
zero_resource(Pid, Name) when is_pid(Pid) ->
gen_server:call(Pid, {zero_resource, Name}).
%%====================================================================
%% gen_server callbacks
init(Options) ->
erlang:process_flag(trap_exit, true),
Hostname = proplists:get_value(gth_ip, Options),
JET = proplists:get_value(job_event_target, Options),
RET = proplists:get_value(resource_event_target, Options),
S = proplists:get_value(socket, Options),
?IS_VALID_EVENT_HANDLER(JET) orelse exit(badarg),
?IS_VALID_EVENT_HANDLER(RET) orelse exit(badarg),
{ok, {Addr, _Port}} = inet:sockname(S),
IP = inet_parse:ntoa(Addr),
erlang:send_after(?KICK_INTERVAL, self(), kick),
State = #state{
my_ip = IP,
debug_remote_ip = Hostname,
player_ls = listen(),
socket = S,
event_dict = dict:new(),
job_event_target = JET,
resource_event_target = RET,
xml_cmd_checker = proplists:get_value(xml_cmd_checker, Options),
xml_resp_checker = proplists:get_value(xml_resp_checker, Options)
},
{ok, State}.
handle_call(bye, _From, State = #state{socket = S}) ->
_ = gth_apilib:send(S, "<bye/>"),
%% GTH returns <ok/> in response to bye and then closes the socket.
%% According to T/J, Erlang R11B on MS Windows sometimes drops that OK.
%% So we ignore this error on windows.
case next_non_event(State) of
#resp_tuple{name = ok} ->
fine;
_ ->
case os:type() of
{win32, _} ->
error_logger:error_report(
"ignoring bad <bye/> on MS Windows\n");
_ ->
exit(bad_bye)
end
end,
gen_tcp:close(S),
{stop, normal, ok, State#state{socket = none}};
handle_call({custom, Name, Attributes}, _From, State) ->
send_xml(State, xml:custom( Name, Attributes)),
Reply = expect_ok(State),
{reply, Reply, State};
handle_call({disable, Name}, _From, State) ->
send_xml(State, xml:disable(Name)),
Reply = expect_ok(State),
{reply, Reply, State};
handle_call({enable, Name, KVs}, _From, State) ->
send_xml(State, xml:enable(Name, KVs)),
Reply = expect_ok(State),
{reply, Reply, State};
%% Kill the job on the GTH, but also remove it from the event dictionary.
%% (only tone and level detectors live in the event dictionary, but erasing
%% something which isn't there is OK)
handle_call({delete, Id}, _From, State = #state{event_dict=Dict}) ->
send_xml(State, xml:delete(Id)),
Reply = expect_ok(State),
New_dict = dict:erase(Id, Dict),
{reply, Reply, State#state{event_dict = New_dict}};
handle_call(get_gth_ip, _From, State = #state{socket = S}) ->
I = case inet:peername(S) of
{ok, {IP, _Port}} ->
IP;
X ->
%% One legitimate way to end up here is if we lose contact
%% with the GTH (power fail, ethernet unplugged, etc.).
%%
%% But Erlang R12B-4 SMP sometimes gets here even without
%% anything being wrong. Looks like an Erlang bug. Hasn't
%% been observed in R13B or later.
%%
%% My guess is that peername doesn't work on {active, once}
%% sockets when they've just sent a message, which is why the
%% sleep-and-try again approach usually works.
io:fwrite("Impossible. Peername reported ~p. Retrying.\n", [X]),
receive
Y -> io:fwrite("had ~p in the queue\n", [Y])
after 0 ->
ok
end,
timer:sleep(1000),
{ok, {IP, _Port}} = inet:peername(S),
IP
end,
{reply, {ok, I}, State};
handle_call(get_my_ip, _From, State = #state{socket = S}) ->
{ok, {IP, _Port}} = inet:sockname(S),
{reply, {ok, IP}, State};
handle_call({install, Name, Bin_or_fun}, _From, State = #state{socket = S}) ->
send_xml(State, xml:install(Name)),
Type = case lists:member(Name, ["system_image", "failsafe_image"]) of
true -> "binary/filesystem";
_ -> "binary/file"
end,
case Bin_or_fun of
Bin when is_binary(Bin_or_fun) ->
ok = gth_apilib:send(S, Type, Bin);
{Length, Fun} ->
ok = gen_tcp:send(S, gth_apilib:header(Type, Length)),
stream_install(S, Fun)
end,
Reply = expect_ok(State#state{command_timeout = 60000}),
{reply, Reply, State};
handle_call({map, pcm_source, Name}, _From, State) ->
send_xml(State, xml:map(pcm_source, Name)),
Reply = case next_non_event(State) of
#resp_tuple{name = error, attributes=[{"reason", R}|_],
clippings=C} ->
{error, {atomise_error_reason(R), C}};
#resp_tuple{name = resource,
attributes = [{"name", N}]} -> {ok, N}
end,
{reply, Reply, State};
handle_call({new_atm_aal0_monitor, Span, Timeslots, Options},
{Pid, _tag}, State) ->
Reply = new_signalling_monitor(Pid, State, Span, Timeslots,
"atm_aal0_monitor", Options),
{reply, Reply, State};
handle_call({new_atm_aal2_monitor, Span, Timeslots, {VPI, VCI}, User_options},
{Pid, _tag}, State) ->
Options = [{"vpi", VPI}, {"vci", VCI}|User_options],
Reply = new_signalling_monitor(Pid, State, Span, Timeslots,
"atm_aal2_monitor", Options),
{reply, Reply, State};
handle_call({new_atm_aal5_monitor, Span, Timeslots, {VPI, VCI}, User_options},
{Pid, _tag}, State) ->
Options = [{"vpi", VPI}, {"vci", VCI}|User_options],
Reply = new_signalling_monitor(Pid, State, Span, Timeslots,
"atm_aal5_monitor", Options),
{reply, Reply, State};
handle_call({new_atm_aal0_layer, Span, Timeslots, User_options},
{Pid, _tag},
State = #state{my_ip = Hostname}) ->
Options = User_options ++ [{"scrambling", "yes"}],
Scrambling = proplists:get_value("scrambling", Options),
{Portno, L} = listen([{packet, 2}]),
Sources = [xml:pcm_source(Span, Ts) || Ts <- Timeslots ],
Sinks = [xml:pcm_sink(Span, Ts) || Ts <- Timeslots ],
send_xml(State, xml:new("atm_aal0_layer",
[{"ip_addr", Hostname},
{"ip_port", Portno},
{"scrambling", Scrambling}],
[Sources, Sinks])),
Reply = case receive_job_id(State) of
{ok, Job} ->
{ok, D} = gen_tcp:accept(L, 2000),
ok = gen_tcp:controlling_process(D, Pid),
{ok, Job, D};
X ->
X
end,
ok = gen_tcp:close(L),
{reply, Reply, State};
handle_call({new_cas_r2_mfc_detector, Span, Ts, Direction, User_options},
{Pid, _tag}, State) ->
Options = case Direction of
forward -> [{"direction", "forward"}];
backward -> [{"direction", "backward"}]
end,
Reply = new_signalling_monitor(Pid, State, Span, Ts, "cas_r2_mfc_detector",
Options ++ User_options),
{reply, Reply, State};
handle_call({new_cas_r2_linesig_monitor, Span, Ts, Options}, {Pid, _}, State) ->
Reply = new_signalling_monitor(Pid, State, Span, Ts,
"cas_r2_linesig_monitor", Options),
{reply, Reply, State};
handle_call({new_clip, Name, Bin}, _From, State = #state{socket = S}) ->
XML = xml:new_clip(Name),
ok = gth_apilib:sendv(S, [{"text/xml", XML}, {"binary/audio", Bin}]),
possibly_check_xml(State#state.xml_cmd_checker, XML),
Reply = receive_job_id(State),
{reply, Reply, State};
handle_call({new_connection, S_span, S_ts, D_IP, D_span, D_ts}, _From, State) ->
send_xml(State, xml:new("connection", [],
[xml:pcm_source(S_span, S_ts),
xml:pcm_sink(D_IP, D_span, D_ts)])),
Reply = receive_job_id(State),
{reply, Reply, State};
handle_call({new_connection, S_span, S_ts, D_span, D_ts}, _From, State) ->
send_xml(State, xml:new("connection", [],
[xml:pcm_source(S_span, S_ts),
xml:pcm_sink(D_span, D_ts)])),
Reply = receive_job_id(State),
{reply, Reply, State};
handle_call({new_fr_monitor, Span, Timeslots, Options},
{Pid, _tag}, State) ->
Reply = new_signalling_monitor(Pid, State, Span, Timeslots,
"fr_monitor", Options),
{reply, Reply, State};
handle_call({new_fr_layer, Span, Timeslots},
{Pid, _tag}, State = #state{my_ip = Hostname}) ->
{Portno, L} = listen([{packet, 2}]),
Sources = [xml:pcm_source(Span, Ts) || Ts <- Timeslots ],
Sinks = [xml:pcm_sink(Span, Ts) || Ts <- Timeslots ],
send_xml(State, xml:new("fr_layer",
[{"ip_addr", Hostname},
{"ip_port", Portno}],
[Sources, Sinks])),
Reply = case receive_job_id(State) of
{ok, Job} ->
{ok, D} = gen_tcp:accept(L, 2000),
ok = gen_tcp:controlling_process(D, Pid),
{ok, Job, D};
{error, Reason} ->
{error, Reason}
end,
ok = gen_tcp:close(L),
{reply, Reply, State};
handle_call({new_lapd_layer, Span, Ts, Side, {SAPI, TEI}, Tag, Options},
{Pid, _tag}, State = #state{my_ip = Hostname}) ->
Source_sink = [xml:pcm_source(Span, Ts), xml:pcm_sink(Span, Ts)],
case proplists:get_value(reuse_socket, Options) of
undefined ->
{Portno, L} = listen([{packet, 2}]),
send_xml(State, xml:new(
"lapd_layer",
[{"ip_addr", Hostname},
{"ip_port", Portno},
{"side", atom_to_list(Side)},
{"sapi", SAPI},
{"tag", Tag},
{"tei", TEI}|Options], Source_sink)),
case receive_job_id(State) of
{ok, Job} ->
{ok, D} = gen_tcp:accept(L, 2000),
ok = gen_tcp:close(L),
ok = gen_tcp:controlling_process(D, Pid),
{reply, {ok, Job, D}, State};
{error, Reason} ->
ok = gen_tcp:close(L),
{reply, {error, Reason}, State}
end;
D when is_port(D) ->
{ok, Portno} = inet:port(D),
send_xml(State, xml:new(
"lapd_layer",
[{"ip_addr", Hostname},
{"ip_port", Portno},
{"tag", Tag},
{"side", atom_to_list(Side)},
{"sapi", SAPI}, {"tei", TEI}
|proplists:delete(reuse_socket,Options)],
Source_sink)),
case receive_job_id(State) of
{ok, Job} ->
{reply, {ok, Job, D}, State};
E = {error, _Reason} ->
{reply, E, State}
end
end;
handle_call({new_lapd_monitor, Span, Ts, Opts}, {Pid, _tag}, State) ->
Reply = new_signalling_monitor(Pid, State, Span, Ts, "lapd_monitor", Opts),
{reply, Reply, State};
handle_call({new_level_detector, Span, Ts, Threshold, Options, EH}, _From,
State = #state{ event_dict = ED,
job_event_target = JET}) ->
Attrs = case proplists:get_value("type", Options ++ [{"type", "both"}]) of
"backwards_compatible" ->
[{"level", Threshold}];
Type ->
[{"threshold", Threshold}, {"type", Type}]
end,
Attrs_and_period = case proplists:get_value("period", Options) of
undefined -> Attrs;
Period -> [{"period", Period}|Attrs]
end,
send_xml(State, xml:new("level_detector", Attrs_and_period,
xml:pcm_source(Span, Ts))),
case receive_job_id(State) of
{ok, Job} ->
New_ED = case EH of