/
src.pro
134 lines (117 loc) · 3.83 KB
/
src.pro
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
include (../../../variables.pri)
TEMPLATE = lib
LANGUAGE = C++
TARGET = dmxusb
CONFIG += plugin
QT += gui core
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
INCLUDEPATH += ../../interfaces
exists( $$[QT_INSTALL_LIBS]/libQtSerialPort.a ) {
CONFIG += serialport
}
serialport {
message(Building with QtSerialport support.)
DEFINES += QTSERIAL
} else {
# Use FTD2XX by default only in Windows. Uncomment the two rows with curly
# braces to use ftd2xx interface on unix.
win32 {
CONFIG += ftd2xx
message(Building with FTD2xx support.)
}
# FTD2XX is a proprietary interface by FTDI Ltd. and would therefore taint the
# 100% FLOSS codebase of QLC if distributed along with QLC sources. Download
# the latest driver package from http://www.ftdichip.com/Drivers/D2XX.htm and
# extract its contents under FTD2XXDIR below (unix: follow the instructions in
# the package README.dat to install under /usr/local/) before compiling this
# plugin.
#
# Use forward slashes '/' instead of Windows backslashes '\\' for paths here!
CONFIG(ftd2xx) {
win32 {
# Windows target
FTD2XXDIR = C:/Qt/CDM21200
LIBS += -L$$FTD2XXDIR/i386 -lftd2xx
LIBS += $$FTD2XXDIR/i386/libftd2xx.a
INCLUDEPATH += $$FTD2XXDIR
QMAKE_LFLAGS += -shared
} else {
# Unix target
INCLUDEPATH += /usr/local/include
LIBS += -lftd2xx -L/usr/local/lib
}
DEFINES += FTD2XX
} else {
greaterThan(QT_MAJOR_VERSION, 4) {
macx:QT_CONFIG -= no-pkg-config
}
packagesExist(libftdi1) {
CONFIG += link_pkgconfig
PKGCONFIG += libftdi1 libusb-1.0
DEFINES += LIBFTDI1
message(Building with libFTDI1 support.)
} else {
packagesExist(libftdi) {
CONFIG += link_pkgconfig
PKGCONFIG += libftdi libusb
DEFINES += LIBFTDI
message(Building with libFTDI support.)
} else {
error(Neither libftdi-0.X nor libftdi-1.X found!)
}
}
}
}
HEADERS += ../../interfaces/qlcioplugin.h
HEADERS += dmxusb.h \
dmxusbwidget.h \
dmxusbconfig.h \
enttecdmxusbpro.h \
enttecdmxusbopen.h \
stageprofi.h \
vinceusbdmx512.h \
qlcftdi.h
unix:!macx: HEADERS += nanodmx.h euroliteusbdmxpro.h
SOURCES += ../../interfaces/qlcioplugin.cpp
SOURCES += dmxusb.cpp \
dmxusbwidget.cpp \
dmxusbconfig.cpp \
enttecdmxusbpro.cpp \
enttecdmxusbopen.cpp \
stageprofi.cpp \
vinceusbdmx512.cpp
INCLUDEPATH += ../../midi/common
HEADERS += ../../midi/common/midiprotocol.h
SOURCES += ../../midi/common/midiprotocol.cpp
unix:!macx: SOURCES += nanodmx.cpp euroliteusbdmxpro.cpp
serialport {
SOURCES += qlcftdi-qtserial.cpp
} else {
CONFIG(ftd2xx) {
SOURCES += qlcftdi-ftd2xx.cpp
} else {
SOURCES += qlcftdi-libftdi.cpp
}
}
unix:!macx {
# Rules to make USB DMX devices readable & writable by normal users
udev.path = /etc/udev/rules.d
udev.files = z65-dmxusb.rules
INSTALLS += udev
}
TRANSLATIONS += DMX_USB_de_DE.ts
TRANSLATIONS += DMX_USB_es_ES.ts
TRANSLATIONS += DMX_USB_fi_FI.ts
TRANSLATIONS += DMX_USB_fr_FR.ts
TRANSLATIONS += DMX_USB_it_IT.ts
TRANSLATIONS += DMX_USB_nl_NL.ts
TRANSLATIONS += DMX_USB_cz_CZ.ts
TRANSLATIONS += DMX_USB_pt_BR.ts
TRANSLATIONS += DMX_USB_ca_ES.ts
TRANSLATIONS += DMX_USB_ja_JP.ts
# This must be after "TARGET = " and before target installation so that
# install_name_tool can be run before target installation
macx:include(../../../macx/nametool.pri)
# Plugin installation
target.path = $$INSTALLROOT/$$PLUGINDIR
INSTALLS += target