[vcpkg] Add vcpkg_install_copyright() portfile function

docs/maintainers/maintainer-guide.md

@@ -106,6 +106,18 @@ This means that the user should see:
 Examples:
  * [`brotli`](https://github.com/microsoft/vcpkg/blob/4f0a640e4c5b74166b759a862d7527c930eff32e/ports/brotli/install.patch) creates the `unofficial-brotli` package, producing target `unofficial::brotli::brotli`.
 
+### Install copyright file
+
+Each port has to provide a file named `copyright` in the folder `${CURRENT_PACKAGES_DIR}/share/${PORT}`. You can install the copyright file using the following code:
+
+```cmake
+file(INSTALL "${SOURCE_PATH}LICENSE" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}" RENAME copyright)
+```
+
+Replace `LICENSE` with the actual file name.
+
+If there are multiple license files, use [`vcpkg_install_copyright()`](vcpkg_install_copyright.md) instead.
+
 ## Features
 
 ### Do not use features to implement alternatives

docs/maintainers/portfile-functions.md

@@ -48,6 +48,7 @@
 - [vcpkg\_host\_path\_list](vcpkg_host_path_list.md)
 - [vcpkg\_install\_cmake](vcpkg_install_cmake.md) (deprecated, use [vcpkg\_cmake\_install](ports/vcpkg-cmake/vcpkg_cmake_install.md))
 - [vcpkg\_install\_gn](vcpkg_install_gn.md) (deprecated, use [vcpkg\_gn\_install](ports/vcpkg-gn/vcpkg_gn_install.md))
+- [vcpkg_install_copyright](vcpkg_install_copyright.md)
 - [vcpkg\_install\_make](vcpkg_install_make.md)
 - [vcpkg\_install\_meson](vcpkg_install_meson.md)
 - [vcpkg\_install\_msbuild](vcpkg_install_msbuild.md)

docs/maintainers/vcpkg_install_copyright.md

@@ -0,0 +1,39 @@
+# vcpkg_install_copyright
+
+The latest version of this document lives in the [vcpkg repo](https://github.com/Microsoft/vcpkg/blob/master/docs/maintainers/vcpkg_install_copyright.md).
+
+Merges multiple copyright files into a single file and install it.
+
+## Usage:
+
+```cmake
+vcpkg_install_copyright(FILE_LIST <license.md> <license_gpl.md>...)
+```
+
+## Parameters:
+
+### FILE_LIST
+
+Specifies a list of license files relative to `${SOURCE_PATH}`. You must provide at least 2 files.
+
+If you want to install just a single license file, please use
+
+```cmake
+file(INSTALL "${SOURCE_PATH}/LICENSE" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}" RENAME copyright)
+```
+
+## Notes
+
+This function concatinates the contents of multiple copyright files to a single file.
+
+The resulting `copyright` file looks similar to this:
+
+```
+LICENSE-LGPL2.txt:
+
+Lorem ipsum dolor...
+
+LICENSE-MIT.txt:
+
+Lorem ipsum dolor sit amet...
+```

scripts/cmake/vcpkg_install_copyright.cmake

@@ -0,0 +1,33 @@
+function(vcpkg_install_copyright)
+    cmake_parse_arguments(PARSE_ARGV 0 arg "" "" "FILE_LIST")
+
+    if(DEFINED arg_UNPARSED_ARGUMENTS)
+        message(FATAL_ERROR "${CMAKE_CURRENT_FUNCTION} was passed extra arguments: ${arg_UNPARSED_ARGUMENTS}")
+    endif()
+
+    if(NOT DEFINED arg_FILE_LIST)
+        message(FATAL_ERROR "FILE_LIST must be specified")
+    endif()
+
+    list(LENGTH arg_FILE_LIST FILE_LIST_LENGTH)
+    if(FILE_LIST_LENGTH LESS_EQUAL 1)
+        message(FATAL_ERROR "Don't use ${CMAKE_CURRENT_FUNCTION} to install a single license file.")
+    endif()
+
+    set(out_string "")
+
+    foreach(file_item IN LISTS arg_FILE_LIST)
+        string(PREPEND file_item "${SOURCE_PATH}/")
+
+        if(NOT EXISTS "${file_item}" OR IS_DIRECTORY "${file_item}")
+            message(FATAL_ERROR "The file ${file_item} does not exist or is a directory.")
+        endif()
+
+        get_filename_component(file_name ${file_item} NAME)
+        file(READ "${file_item}" file_contents)
+
+        string(APPEND out_string "${file_name}:\n\n${file_contents}\n\n")
+    endforeach()
+
+    file(WRITE "${CURRENT_PACKAGES_DIR}/share/${PORT}/copyright" "${out_string}")
+endfunction()

scripts/ports.cmake

@@ -45,6 +45,7 @@ include("${SCRIPTS}/cmake/vcpkg_get_program_files_platform_bitness.cmake")
 include("${SCRIPTS}/cmake/vcpkg_get_windows_sdk.cmake")
 include("${SCRIPTS}/cmake/vcpkg_host_path_list.cmake")
 include("${SCRIPTS}/cmake/vcpkg_install_cmake.cmake")
+include("${SCRIPTS}/cmake/vcpkg_install_copyright.cmake")
 include("${SCRIPTS}/cmake/vcpkg_install_gn.cmake")
 include("${SCRIPTS}/cmake/vcpkg_install_make.cmake")
 include("${SCRIPTS}/cmake/vcpkg_install_meson.cmake")