Add getWeekYear helper

STATUS.md

@@ -137,7 +137,7 @@
 
 ### Week-numbering year helpers
 
-- [ ] `getWeekYear`
+- [x] `getWeekYear`
 - [ ] `setWeekYear`
 - [ ] `startOfWeekYear`
 

__tests__/getWeekYear_test.re

@@ -0,0 +1,20 @@
+open Jest;
+
+open Js.Date;
+
+describe("getWeekYear", () => {
+  open ExpectJs;
+
+  test("returns the local week-numbering year of the given date", () => {
+    let date = makeWithYMD(~year=2019., ~month=11., ~date=29., ());
+
+    date |> ReDate.getWeekYear |> expect |> toEqual(2020.);
+  });
+
+  test("allows to specify which day is the first day of the week", () => {
+    let date = makeWithYMD(~year=2019., ~month=11., ~date=23., ());
+    let getWeekYear' = ReDate.getWeekYear(~weekStartsOn=Monday);
+
+    date |> getWeekYear' |> expect |> toEqual(2019.);
+  });
+});

docs/week_numbering.md

@@ -0,0 +1,20 @@
+# Week numbering helpers
+
+#### getWeekYear
+
+> Get the local week-numbering year of the given date.
+
+`let getWeekYear: (~weekStartsOn: day=?, Js.Date.t) => float`
+
+```reason
+let date = Js.Date.makeWithYMD(~year=2018., ~month=4., ~date=10., ());
+
+date |> ReDate.getWeekYear;
+```
+
+```reason
+let date = Js.Date.makeWithYMD(~year=2018., ~month=10., ~date=14., ());
+let getWeekYear' = ReDate.getWeekYear(~weekStartsOn=Monday);
+
+date |> getWeekYear';
+```

src/ReDate.re

@@ -270,6 +270,25 @@ module Internal = {
     |> startOrEndOfWeek(weekStartsOn)
     |> makeDateWithStartOfDayHours;
 
+  let getWeekYear = (~weekStartsOn=Sunday, date) => {
+    let year = date |> Js.Date.getFullYear |> int_of_float;
+    let currentYear =
+      year |> float_of_int |> makeDateWithY |> startOfWeek(~weekStartsOn);
+    let nextYear =
+      year
+      |> succ
+      |> float_of_int
+      |> makeDateWithY
+      |> startOfWeek(~weekStartsOn);
+
+    Js.Date.(
+      date |> getTime >= (nextYear |> getTime)
+        ? year |> succ
+        : date |> getTime >= (currentYear |> getTime) ? year : year |> pred
+    )
+    |> float_of_int;
+  };
+
   let isLeap = year =>
     year mod 400 === 0 || year mod 4 === 0 && year mod 100 !== 0;
 
@@ -661,6 +680,10 @@ let differenceInCalendarYears = Internal.differenceIn(CalendarYears);
 
 let differenceInYears = Internal.differenceIn(Years);
 
+/* ——[Week-numbering year helpers]——————————— */
+
+let getWeekYear = Internal.getWeekYear;
+
 /* ——[Interval helpers]——————————— */
 
 let isWithinInterval = (interval, date) => {

src/ReDate.rei

@@ -213,6 +213,10 @@ let differenceInCalendarYears: (Js.Date.t, Js.Date.t) => int;
 
 let differenceInYears: (Js.Date.t, Js.Date.t) => int;
 
+/* ——[Week-numbering year helpers]——————————— */
+
+let getWeekYear: (~weekStartsOn: day=?, Js.Date.t) => float;
+
 /* ——[Interval helpers]——————————— */
 
 let isWithinInterval: (interval, Js.Date.t) => bool;