/
PKGBUILD
68 lines (57 loc) · 2.13 KB
/
PKGBUILD
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
# Maintainer: Biswapriyo Nath <nathbappai@gmail.com>
_realname=pangomm
pkgbase=mingw-w64-${_realname}-2.48
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}-2.48"
pkgver=2.52.0
pkgrel=1
provides=("${MINGW_PACKAGE_PREFIX}-${_realname}248")
conflicts=("${MINGW_PACKAGE_PREFIX}-${_realname}248")
replaces=("${MINGW_PACKAGE_PREFIX}-${_realname}248")
pkgdesc="C++ bindings for Pango (V2.48) (mingw-w64)"
url="https://www.gtkmm.org/"
arch=('any')
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32' 'clangarm64')
license=('spdx:LGPL-2.1-or-later')
depends=("${MINGW_PACKAGE_PREFIX}-cairomm-1.16"
"${MINGW_PACKAGE_PREFIX}-glibmm-2.68"
"${MINGW_PACKAGE_PREFIX}-pango")
makedepends=("${MINGW_PACKAGE_PREFIX}-meson"
"${MINGW_PACKAGE_PREFIX}-pkgconf"
"${MINGW_PACKAGE_PREFIX}-cc")
source=("https://download.gnome.org/sources/${_realname}/${pkgver%.*}/${_realname}-${pkgver}.tar.xz")
sha256sums=('34a134126a6484ff12f774358c36ecc44d0e9df094e1b83796d9774bb7d24947')
prepare() {
cd "${srcdir}/${_realname}-${pkgver}"
}
build() {
mkdir -p "build-${MSYSTEM}" && cd "build-${MSYSTEM}"
declare -a _extra_config
if check_option "debug" "n"; then
_extra_config+=("--buildtype=release")
else
_extra_config+=("--buildtype=debug")
fi
CFLAGS+=" -Wno-attributes" \
CXXFLAGS+=" -Wno-attributes" \
MSYS2_ARG_CONV_EXCL="--prefix=" \
${MINGW_PREFIX}/bin/meson.exe setup \
--prefix="${MINGW_PREFIX}" \
"${_extra_config[@]}" \
--wrap-mode=nodownload \
--default-library=both \
--auto-features=enabled \
-Dmaintainer-mode=false \
-Dbuild-documentation=false \
"../${_realname}-${pkgver}"
${MINGW_PREFIX}/bin/meson.exe compile
}
check() {
cd "${srcdir}/build-${MSYSTEM}"
${MINGW_PREFIX}/bin/meson.exe test || true
}
package() {
cd "${srcdir}/build-${MSYSTEM}"
DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/meson.exe install
install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}-2.48/COPYING"
install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING.tools" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}-2.48/COPYING.tools"
}