-
Notifications
You must be signed in to change notification settings - Fork 201
/
configure.ac
315 lines (264 loc) · 7.1 KB
/
configure.ac
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
# -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.
AC_PREREQ([2.63])
AC_INIT([naev], [0.4.0], [bobbens@gmail.com])
AC_CONFIG_SRCDIR([src/naev.c])
AC_CONFIG_HEADERS([src/config.h])
AC_CONFIG_AUX_DIR([build])
AM_INIT_AUTOMAKE([foreign])
# M4 defines __unix__ to be the empty string on UNIX-like systems. This
# causes AC_DEFINE to fail if it is used to define __unix__. This seems to
# fix the problem.
ifdef([__unix__], define([__unix__], [[__unix__]]))
#
# Checks for programs.
#
AC_PROG_CC
AC_PROG_RANLIB
PKG_PROG_PKG_CONFIG
AC_CHECK_PROG([CUT], [cut], [cut])
AS_IF([test -z "$CUT"],[
AC_ERROR([cut not found])
])
#
# Platform checks
#
AC_CANONICAL_HOST
AC_MSG_CHECKING([[if we need a __unix__ define]])
AC_COMPILE_IFELSE([
#ifndef __unix__
# if defined __APPLE__ /* add other known platforms here */
# error should have __unix__ but don't
# endif
#endif
], [AC_MSG_RESULT([no])],
[
AC_MSG_RESULT([yes])
AC_DEFINE([__unix__], 1,
[Define to 1 if running on a UNIX-like system where __unix__ is missing])
])
have_posix=yes
have_windows=no
have_darwin=no
case "$host" in
*-*-mingw*)
have_windows=yes
have_posix=no
;;
*-*-darwin*)
have_darwin=yes
;;
esac
#
# Checks for command-line arguments
#
AC_MSG_CHECKING([whether to enable additional debugging options])
AC_ARG_ENABLE([debug],
AC_HELP_STRING([--enable-debug=@<:@no|yes|paranoid@:>@],
[enable additional debugging options]), [
case "$enableval" in
no)
enable_debug=no
enable_paranoid_debug=no
;;
paranoid)
enable_debug=yes
enable_paranoid_debug=yes
;;
*)
enable_debug=yes
enable_paranoid_debug=no
;;
esac
], [
enable_debug=no
])
AC_MSG_RESULT([$enable_debug])
#
# Checks for libraries.
#
# SDL
AM_PATH_SDL
# libxml2
PKG_CHECK_MODULES([XML], [libxml-2.0], [], [
AC_ERROR([libxml-2.0 not found])
])
# FreeType
PKG_CHECK_MODULES([FREETYPE], [freetype2], [], [
AC_ERROR([freetype2 not found])
])
# vorbisfile
PKG_CHECK_MODULES([VORBISFILE], [vorbisfile >= 1.2.1], [], [
AC_ERROR([vorbisfile >= 1.2.1 not found])
])
# libpng
PKG_CHECK_MODULES([PNG], [libpng], [], [
AC_ERROR([libpng not found])
])
# OpenAL
AS_IF([test "$have_darwin" = "yes"], [
have_openal="yes"
OPENAL_AL_H="<OpenAL/al.h>"
OPENAL_ALC_H="<OpenAL/alc.h>"
OPENAL_CFLAGS=
OPENAL_LIBS="-framework OpenAL"
], [
AS_IF([test "$have_windows" = "yes"], [
have_openal="yes"
OPENAL_AL_H="<OpenAL/al.h>"
OPENAL_ALC_H="<OpenAL/alc.h>"
OPENAL_CFLAGS=
OPENAL_LIBS="-lOpenAL32"
], [
PKG_CHECK_MODULES([OPENAL], [openal], [have_openal=yes], [have_openal=no])
AS_IF([test "$have_openal" = "no"], [
AC_ERROR([OpenAL not found])
])
OPENAL_AL_H="<AL/al.h>"
OPENAL_ALC_H="<AL/alc.h>"
])
])
AC_DEFINE_UNQUOTED([OPENAL_AL_H], [$OPENAL_AL_H],
[Define to the equivalent of <AL/al.h> on your system])
AC_DEFINE_UNQUOTED([OPENAL_ALC_H], [$OPENAL_ALC_H],
[Define to the equivalent of <AL/alc.h> on your system])
# SDL_mixer
OLD_LIBS="$LIBS"
LIBS=""
AC_SEARCH_LIBS([Mix_OpenAudio], [SDL_mixer],
[have_sdlmixer=yes], [have_sdlmixer=no])
AS_IF([test "$have_sdlmixer" = "yes"], [
SDLMIXER_CFLAGS=
SDLMIXER_LIBS="$LIBS"
], [
SDLMIXER_CFLAGS=
SDLMIXER_LIBS=
])
LIBS="$OLD_LIBS"
# SDL_image
OLD_LIBS="$LIBS"
LIBS=""
AC_SEARCH_LIBS([IMG_Load], [SDL_image], [], [
AC_ERROR([SDL_image not found])
])
SDLIMAGE_CFLAGS=
SDLIMAGE_LIBS="$LIBS"
LIBS="$OLD_LIBS"
# OpenGL
AS_IF([test "$have_darwin" = "yes"], [
OPENGL_GL_H="<OpenGL/al.h>"
OPENGL_GLU_H="<OpenGL/alc.h>"
OPENGL_CFLAGS=
OPENGL_LIBS="-framework OpenGL"
], [
OPENGL_CFLAGS=
OLD_LIBS="$LIBS"
LIBS=""
AC_SEARCH_LIBS([glGenTextures], [OpenGL32 GL], [], [
AC_ERROR([OpenGL not found])
])
AC_SEARCH_LIBS([gluOrtho2D], [GLU32 GLU], [], [
AC_ERROR([GLU not found])
])
OPENGL_LIBS="$LIBS"
LIBS="$OLD_LIBS"
OPENGL_GL_H="<GL/al.h>"
OPENGL_GLU_H="<GL/glu.h>"
])
AC_DEFINE_UNQUOTED([OPENGL_GL_H], [$OPENGL_GL_H],
[Define to the equivalent of <GL/gl.h> on your system])
AC_DEFINE_UNQUOTED([OPENGL_GLU_H], [$OPENGL_GLU_H],
[Define to the equivalent of <GL/glu.h> on your system])
#
# Compiler flags
#
# global
GLOBAL_CFLAGS="-include \"\$(top_builddir)/src/config.h\""
GLOBAL_CFLAGS="$GLOBAL_CFLAGS -I\"\$(top_srcdir)/src\""
AS_IF([test "$enable_debug" = "yes"], [
GLOBAL_CFLAGS="$GLOBAL_CFLAGS -DLUA_USE_APICHECK"
])
# naev
NAEV_CFLAGS=""
NAEV_LIBS="\$(top_builddir)/src/tk/widget/libwidget.a"
AS_IF([test "$enable_debug" = "yes"], [
AC_DEFINE([DEBUGGING], 1, [Define to 1 to enable debug code])
AC_DEFINE([DEBUG], 1, [Define to 1 to enable debug code])
case "$host" in
*-linux-gnu)
NAEV_LIBS="$NAEV_LIBS -lbfd"
;;
esac
])
AS_IF([test "$enable_paranoid_debug" = "yes"], [
AC_DEFINE([DEBUG_PARANOID], 1, [Define to 1 to enable paranoid debug code])
])
CSPARSE_CFLAGS="-I\"\$(top_srcdir)/lib/csparse\""
CSPARSE_LIBS="\$(top_builddir)/lib/csparse/libcsparse.a"
LUA_CFLAGS="-I\"\$(top_srcdir)/lib/lua\""
LUA_LIBS="\$(top_builddir)/lib/lua/liblua.a"
NAEV_CFLAGS="$NAEV_CFLAGS $GLOBAL_CFLAGS $CSPARSE_CFLAGS $SDL_CFLAGS"
NAEV_CFLAGS="$NAEV_CFLAGS $XML_CFLAGS $FREETYPE_CFLAGS $LUA_CFLAGS"
NAEV_CFLAGS="$NAEV_CFLAGS $VORBISFILE_CFLAGS $OPENGL_CFLAGS $PNG_CFLAGS"
NAEV_CFLAGS="$NAEV_CFLAGS $SDLIMAGE_CFLAGS"
NAEV_LIBS="$NAEV_LIBS $CSPARSE_LIBS $SDL_LIBS $XML_LIBS"
NAEV_LIBS="$NAEV_LIBS $FREETYPE_LIBS $LUA_LIBS"
NAEV_LIBS="$NAEV_LIBS $VORBISFILE_LIBS $OPENGL_LIBS $PNG_LIBS"
NAEV_CFLAGS="$NAEV_CFLAGS $SDLIMAGE_LIBS"
AS_IF([test "$have_openal" = "yes"], [
NAEV_CFLAGS="$NAEV_CFLAGS $OPENAL_CFLAGS"
NAEV_LIBS="$NAEV_LIBS $OPENAL_LIBS"
])
AS_IF([test "$have_sdlmixer" = "yes"], [
NAEV_CFLAGS="$NAEV_CFLAGS $SDLMIXER_CFLAGS"
NAEV_LIBS="$NAEV_LIBS $SDLMIXER_LIBS"
])
AS_IF([test "$have_windows" = "yes"], [
NAEV_CFLAGS="$NAEV_CFLAGS -mwindows"
])
AC_SUBST([NAEV_CFLAGS])
AC_SUBST([NAEV_LIBS])
# liblua
LIBLUA_CFLAGS="$GLOBAL_CFLAGS"
AS_IF([test "$have_posix" = "yes"], [
LIBLUA_CFLAGS="$LIBLUA_CFLAGS -DLUA_USE_POSIX"
], [
LIBLUA_CFLAGS="$LIBLUA_CFLAGS -DLUA_ANSI"
])
AC_SUBST([LIBLUA_CFLAGS])
#
# Checks for typedefs, structures, and compiler characteristics.
#
AC_TYPE_OFF_T
AC_TYPE_SIZE_T
AC_TYPE_SSIZE_T
AC_TYPE_UINT16_T
AC_TYPE_UINT32_T
AC_TYPE_UINT64_T
AC_TYPE_UINT8_T
#
# Defines in config.h
#
# Version variables
VMAJOR=$(echo "$VERSION" | cut -d. -f1)
VMINOR=$(echo "$VERSION" | cut -d. -f2)
VREV=$(echo "$VERSION" | cut -d. -f3)
AC_DEFINE_UNQUOTED([VMAJOR], [$VMAJOR], [Define to the major version component])
AC_DEFINE_UNQUOTED([VMINOR], [$VMINOR], [Define to the minor version component])
AC_DEFINE_UNQUOTED([VREV], [$VREV], [Define to the revision version component])
AS_IF([test "$have_openal" = "yes"], [
AC_DEFINE([USE_OPENAL], 1, [Define to 1 if using OpenAL])
])
AS_IF([test "$have_sdlmixer" = "yes"], [
AC_DEFINE([USE_SDLMIX], 1, [Define to 1 if using SDL_mixer])
])
SHAVE_INIT([.], [enable])
AC_CONFIG_FILES([Makefile
lib/Makefile
lib/csparse/Makefile
lib/lua/Makefile
src/Makefile
src/tk/Makefile
src/tk/widget/Makefile
shave])
AC_OUTPUT