-
Notifications
You must be signed in to change notification settings - Fork 622
/
LsfExecutor.groovy
202 lines (163 loc) · 6.27 KB
/
LsfExecutor.groovy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
/*
* Copyright (c) 2013-2018, Centre for Genomic Regulation (CRG).
* Copyright (c) 2013-2018, Paolo Di Tommaso and the respective authors.
*
* This file is part of 'Nextflow'.
*
* Nextflow is free software: you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation, either version 3 of the License, or
* (at your option) any later version.
*
* Nextflow is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with Nextflow. If not, see <http://www.gnu.org/licenses/>.
*/
package nextflow.executor
import java.nio.file.Path
import groovy.util.logging.Slf4j
import nextflow.processor.TaskRun
import nextflow.util.MemoryUnit
/**
* Processor for LSF resource manager (DRAFT)
*
* See
* http://en.wikipedia.org/wiki/Platform_LSF
* https://doc.zih.tu-dresden.de/hpc-wiki/bin/view/Compendium/PlatformLSF
* https://www.ibm.com/support/knowledgecenter/SSETD4/product_welcome_lsf.html
*
* @author Paolo Di Tommaso <paolo.ditommaso@gmail.com>
*/
@Slf4j
class LsfExecutor extends AbstractGridExecutor {
/**
* Gets the directives to submit the specified task to the cluster for execution
*
* @param task A {@link TaskRun} to be submitted
* @param result The {@link List} instance to which add the job directives
* @return A {@link List} containing all directive tokens and values.
*/
protected List<String> getDirectives(TaskRun task, List<String> result) {
result << '-o' << task.workDir.resolve(TaskRun.CMD_LOG).toString()
// add other parameters (if any)
if( task.config.queue ) {
result << '-q' << (task.config.queue as String)
}
//number of cpus for multiprocessing/multi-threading
if( task.config.cpus > 1 ) {
result << "-n" << task.config.cpus.toString()
result << "-R" << "span[hosts=1]"
}
if( task.config.time ) {
result << '-W' << task.config.getTime().format('HH:mm')
}
if( task.config.getMemory() ) {
def mem = task.config.getMemory()
// LSF mem limit can be both per-process and per-job
// depending a system configuration setting -- see https://www.ibm.com/support/knowledgecenter/SSETD4_9.1.3/lsf_config_ref/lsf.conf.lsb_job_memlimit.5.dita
// When per-process is used (default) the amount of requested memory
// is divided by the number of used cpus (processes)
if( task.config.cpus > 1 && !perJobMemLimit ) {
long bytes = mem.toBytes().intdiv(task.config.cpus as int)
result << '-M' << String.valueOf(MemoryUnit.of(bytes).toMega())
}
else {
result << '-M' << String.valueOf(mem.toMega())
}
result << '-R' << "rusage[mem=${mem.toMega()}]"
}
// -- the job name
result << '-J' << getJobNameFor(task)
// -- at the end append the command script wrapped file name
result.addAll( task.config.getClusterOptionsAsList() )
return result
}
protected boolean isPerJobMemLimit() {
session.getExecConfigProp(name, 'perJobMemLimit', false)
}
/**
* The command line to submit this job
*
* @param task The {@link TaskRun} instance to submit for execution to the cluster
* @param scriptFile The file containing the job launcher script
* @return A list representing the submit command line
*/
@Override
List<String> getSubmitCommandLine(TaskRun task, Path scriptFile ) { ['bsub'] }
/**
* @return {@code true} since BSC grid requires the script to be piped to the {@code bsub} command
*/
@Override
protected boolean pipeLauncherScript() { true }
protected String getHeaderToken() { '#BSUB' }
/**
* Parse the string returned by the {@code bsub} command and extract the job ID string
*
* @param text The string returned when submitting the job
* @return The actual job ID string
*/
@Override
def parseJobId(String text) {
def pattern = ~/Job <(\d+)> is submitted/
for( String line : text.readLines() ) {
def m = pattern.matcher(line)
if( m.find() ) {
return m.group(1)
}
}
new IllegalStateException("[LSF] Invalid submit response:\n$text\n\n");
}
@Override
protected List<String> getKillCommand() { ['bkill'] }
@Override
protected List<String> queueStatusCommand( queue ) {
def result = ['bjobs', '-o', 'JOBID STAT SUBMIT_TIME delimiter=\',\'', '-noheader']
if( queue )
result << '-q' << queue.toString()
return result
}
private static Map DECODE_STATUS = [
'PEND': QueueStatus.PENDING,
'RUN': QueueStatus.RUNNING,
'PSUSP': QueueStatus.HOLD,
'USUSP': QueueStatus.HOLD,
'SSUSP': QueueStatus.HOLD,
'DONE': QueueStatus.DONE,
'EXIT': QueueStatus.ERROR,
'UNKWN': QueueStatus.ERROR,
'ZOMBI': QueueStatus.ERROR,
]
@Override
protected Map<String, QueueStatus> parseQueueStatus(String text) {
def result = [:]
text.eachLine { String line ->
def cols = line.split(',')
if( cols.size() == 3 ) {
result.put( cols[0], DECODE_STATUS.get(cols[1]) )
}
else {
log.debug "[LSF] invalid status line: `$line`"
}
}
return result
}
private static String SPECIAL_CHARS = ' []|&!<>'
@Override
protected String wrapHeader( String str ) {
boolean needWrap = false
if( !str ) return str
for( int i=0; i<SPECIAL_CHARS.size(); i++ ) {
for( int x=0; x<str.size(); x++ ) {
if( str.charAt(x) == SPECIAL_CHARS.charAt(i) ) {
needWrap = true
break
}
}
}
return needWrap ? "\"$str\"" : str
}
}