add support for Hybrid MBR

example/hybrid-mbr.nix

@@ -0,0 +1,62 @@
+{ disks ? [ "/dev/sda" ], ... }:
+{
+  disk = {
+    main = {
+      type = "disk";
+      device = builtins.elemAt disks 0;
+      content = {
+        type = "hybrid_table";
+        efiGptPartitionFirst = false;
+        hybrid_partitions = [
+          {
+            type = "hybrid_partition";
+            gptPartitionNumber = 1;
+            mbrPartitionType = "0x0c";
+            mbrBootableFlag = false;
+          }
+        ];
+        content = {
+          type = "table";
+          format = "gpt";
+          partitions = [
+            {
+              type = "partition";
+              name = "TOW-BOOT-FI";
+              start = "0%";
+              end = "32MiB";
+              fs-type = "fat32";
+              content = {
+                type = "filesystem";
+                format = "vfat";
+                mountpoint = null;
+              };
+            }
+            {
+              type = "partition";
+              name = "ESP";
+              start = "32MiB";
+              end = "512MiB";
+              bootable = true;
+              content = {
+                type = "filesystem";
+                format = "vfat";
+                mountpoint = "/boot";
+              };
+            }
+            {
+              type = "partition";
+              name = "root";
+              start = "512MiB";
+              end = "100%";
+              content = {
+                type = "filesystem";
+                format = "ext4";
+                mountpoint = "/";
+              };
+            }
+          ];
+        };
+      };
+    };
+  };
+}

types/default.nix

@@ -24,7 +24,7 @@ rec {
 
     # option for valid contents of devices
     deviceType = lib.mkOption {
-      type = lib.types.nullOr (diskoLib.subType { inherit (subTypes) table btrfs filesystem zfs mdraid luks lvm_pv swap; });
+      type = lib.types.nullOr (diskoLib.subType { inherit (subTypes) table hybrid_table btrfs filesystem zfs mdraid luks lvm_pv swap; });
       default = null;
       description = "The type of device";
     };
@@ -133,7 +133,7 @@ rec {
           || lib.hasSuffix "Hook" n
           || isAttrsOfSubmodule o
           # TODO don't hardcode diskoLib.subType options.
-          || n == "content" || n == "partitions"
+          || n == "content" || n == "partitions" || n == "hybrid_partitions"
         );
       in
       lib.toShellVars
@@ -342,7 +342,9 @@ rec {
     btrfs_subvol = ./btrfs_subvol.nix;
     filesystem = ./filesystem.nix;
     table = ./table.nix;
+    hybrid_table = ./hybrid_table.nix;
     partition = ./partition.nix;
+    hybrid_partition = ./hybrid_partition.nix;
     swap = ./swap.nix;
     lvm_pv = ./lvm_pv.nix;
     lvm_vg = ./lvm_vg.nix;

types/hybrid_partition.nix

@@ -0,0 +1,59 @@
+{ config, options, lib, diskoLib, ... }:
+{
+  options = {
+    type = lib.mkOption {
+      type = lib.types.enum [ "hybrid_partition" ];
+      internal = true;
+      description = "Type";
+    };
+    gptPartitionNumber = lib.mkOption {
+      type = lib.types.int;
+      description = "GPT partition number";
+    };
+    mbrPartitionType = lib.mkOption {
+      type = lib.types.nullOr lib.types.str;
+      default = null;
+      description = "MBR type code";
+    };
+    mbrBootableFlag = lib.mkOption {
+      type = lib.types.bool;
+      default = false;
+      description = "Set the bootable flag (aka the active flag) on any or all of your hybridized partitions";
+    };
+    _meta = lib.mkOption {
+      internal = true;
+      readOnly = true;
+      type = lib.types.functionTo diskoLib.jsonType;
+      default = dev: {};
+      description = "Metadata";
+    };
+    _create = diskoLib.mkCreateOption {
+      inherit config options;
+      default = { dev, partNum }: ''
+        ${lib.optionalString (config.mbrPartitionType != null) ''
+          sfdisk --label-nested dos --part-type ${dev} ${(toString partNum)} ${config.mbrPartitionType}
+        ''}
+        ${lib.optionalString config.mbrBootableFlag ''
+          sfdisk --label-nested dos --activate ${dev} ${(toString partNum)}
+        ''}
+      '';
+    };
+    _mount = diskoLib.mkMountOption {
+      inherit config options;
+      default = { dev }: {};
+    };
+    _config = lib.mkOption {
+      internal = true;
+      readOnly = true;
+      default = dev: {};
+      description = "NixOS configuration";
+    };
+    _pkgs = lib.mkOption {
+      internal = true;
+      readOnly = true;
+      type = lib.types.functionTo (lib.types.listOf lib.types.package);
+      default = pkgs: lib.optionals (config.mbrPartitionType != null) [ pkgs.util-linux ];
+      description = "Packages";
+    };
+  };
+}

types/hybrid_table.nix

@@ -0,0 +1,59 @@
+{ config, options, lib, diskoLib, subTypes, ... }:
+{
+  options = {
+    type = lib.mkOption {
+      type = lib.types.enum [ "hybrid_table" ];
+      internal = true;
+      description = "Hybrid MBR/GPT Partition table";
+    };
+    efiGptPartitionFirst = lib.mkOption {
+      type = lib.types.bool;
+      default = true;
+      description = "Place EFI GPT (0xEE) partition first in MBR (good for GRUB)";
+    };
+    hybrid_partitions = lib.mkOption {
+      type = lib.types.listOf subTypes.hybrid_partition;
+      default = [ ];
+      description = "List of one to three GPT partitions to be added to the hybrid MBR";
+    };
+    content = diskoLib.deviceType;
+    _meta = lib.mkOption {
+      internal = true;
+      readOnly = true;
+      type = lib.types.functionTo diskoLib.jsonType;
+      default = dev:
+        diskoLib.deepMergeMap (partition: partition._meta dev) config.partitions;
+      description = "Metadata";
+    };
+    _create = diskoLib.mkCreateOption {
+      inherit config options;
+      default = { dev }: ''
+        ${(config.content._create { inherit dev; })}
+
+        sgdisk -h \
+          ${lib.concatMapStringsSep ":" (hp: (toString hp.gptPartitionNumber)) config.hybrid_partitions}${lib.optionalString (!config.efiGptPartitionFirst) ":EE"} \
+          ${dev}
+
+        ${lib.concatImapStrings (i: hp: hp._create {inherit dev; partNum = i + (if config.efiGptPartitionFirst then 1 else 0 );}) config.hybrid_partitions}
+      '';
+    };
+    _mount = diskoLib.mkMountOption {
+      inherit config options;
+      default = { dev }: config.content._mount { inherit dev; };
+    };
+    _config = lib.mkOption {
+      internal = true;
+      readOnly = true;
+      default = dev: config.content._config dev;
+      description = "NixOS configuration";
+    };
+    _pkgs = lib.mkOption {
+      internal = true;
+      readOnly = true;
+      type = lib.types.functionTo (lib.types.listOf lib.types.package);
+      default = pkgs:
+        [ pkgs.gptfdisk ] ++ (config.content._pkgs pkgs);
+      description = "Packages";
+    };
+  };
+}