Add Github actions build/test/publish/release pipeline

.github/scripts/build.fish

@@ -0,0 +1,21 @@
+#! /usr/bin/env fish
+
+echo "Using $(fish --version)"
+
+# Load utility functions
+set utilsFilePath (dirname (status --current-filename))"/utils.fish"
+source "$utilsFilePath"
+
+if ! set -q "GITHUB_RUN_NUMBER"
+    error "Github run number (\$GITHUB_RUN_NUMBER) environment variable not set, cannot create prerelease build."
+    exit 1
+end
+
+set revision "b$GITHUB_RUN_NUMBER"
+set outputDir "$ARTIFACT_DIR"
+
+# Pack the projects
+packProject "$revision" "$outputDir" "ShopifySharp/ShopifySharp.csproj"
+packProject "$revision" "$outputDir" "ShopifySharp.Experimental/ShopifySharp.Experimental.fsproj"
+
+exit 0

.github/scripts/test.fish

@@ -0,0 +1,79 @@
+#! /usr/bin/env fish
+
+echo "Using $(fish --version)"
+
+set experimentalTestProject "ShopifySharp.Experimental.Tests/ShopifySharp.Experimental.Tests.fsproj"
+
+# Load utility functions
+set utilsFilePath (dirname (status --current-filename))"/utils.fish"
+source "$utilsFilePath"
+
+# Build and run the experimental project's tests all at once
+echo "Testing experimental project."
+buildProject "$experimentalTestProject"; or exit 1;
+executeTests \
+    "ShopifySharp.Experimental" \
+    "$netCoreApp" \
+    "$experimentalTestProject"
+success "Experimental tests succeeded."
+
+# Build the test project once, then let all individual test runs skip build.
+echo "Building test project."
+buildProject "$testProjectFile"; or exit 1;
+success "Test project build succeeded."
+
+# Regex for parsing categories from Trait attributes in test files
+set categoryRegex "Trait\(['\"]Category['\"], ['\"]([A-Za-z]+)['\"]" 
+set categories
+
+# Read every C# file in the test directory and parse the categories
+for file in (ls ./ShopifySharp.Tests/*.cs)
+    for category in (string match -agr "$categoryRegex" (cat "$file"))
+        switch (string lower "$category")
+            case "dotnetframework"
+                # This is a .NET Framework test, it will be run explicitly after the other categories.
+
+            case "shopifyexception"
+                # This is a test of Shopify rate limit exceptions, save it for last.
+
+            case "*"
+                set -a categories "$category"
+        end
+    end
+end
+
+# Run category tests
+if command -q parallel
+    # Tests can be run in parallel. Run up to five test categories at once.
+    set threads 5
+    # This is a little weird, but parallel needs to run fish and source the utils file so it can call the executeTests function
+    set fishCommand "source $utilsFilePath; and executeTests {} $netCoreApp; and exit 0"
+
+    parallel \
+        -j "$threads" \
+        --halt-on-error 1 \
+        fish -c \"$fishCommand\" \
+        ::: $categories
+    or exit 1;
+
+else
+    warn "GNU Parallel is not installed or could not be found. Testing categories one by one."
+
+    for category in $categories
+        executeTests "$category" "$netCoreApp"
+    end
+end
+
+# Run .NET Framework tests using .NET Framework 4.7.2
+if ! isArm64
+    # TODO: these tests need to be run on a Windows machine, they do not run on Linux/macOS
+    warn ".NET Framework tests are temporarily disabled."
+    #executeTests "DotNetFramework" "$netFramework"
+else
+    warn "Machine is running on arm64 which does not support .NET Framework. Unable to run .NET Framework tests."
+end
+
+# Run Shopify exception tests which attempt to trip the rate limit
+executeTests "ShopifyException" "$netCoreApp"
+
+exit 0

.github/scripts/utils.fish

@@ -0,0 +1,234 @@
+#! /usr/bin/env fish
+
+set config "Release"
+set verbosity "quiet"
+set netCoreApp "netcoreapp3.1"
+set netFramework "net472"
+set testDir "ShopifySharp.Tests"
+set testProjectFile "$testDir/ShopifySharp.Tests.csproj"
+
+function success
+    set_color green
+    echo "$argv"
+    set_color normal
+end
+
+function warn
+    # Surface warning messages in Github Actions: 
+    # https://docs.github.com/en/actions/using-workflows/workflow-commands-for-github-actions#example-setting-a-warning-message
+    set_color yellow
+    echo "::warning ::$argv"
+    set_color normal
+end
+
+function error
+    # Surface error messages in Github Actions:
+    # https://docs.github.com/en/actions/using-workflows/workflow-commands-for-github-actions#example-setting-an-error-message
+    set_color red
+    echo "::error ::$argv"
+    set_color normal
+end
+
+function isArm64
+    # Note that functions in fish return exit codes -- success is 0, failure is anything > 0
+    if test (uname -m) = "arm64"
+        return 0
+    else
+        return 1
+    end
+end
+
+function printTestResults -a testOutput
+    # Parse the test output for the line indicating how many tests were run
+    # The `string match` function will automatically write to console if a match is found
+    string match -er "Total tests:|Passed!|Failed!|Skipped!" "$line"
+
+    echo "$testOutput" > testoutput.txt
+end
+
+function executeTests -a category -a framework -a projectFile
+    if test -z "$framework"
+        set framework "$netCoreApp"
+    end
+
+    if test -z "$projectFile"
+        set projectFile "$testProjectFile"
+    end
+
+    if test -z "$category"
+        set_color red
+        echo "[error] Empty category passed to test function."
+
+        if status --is-interactive
+            return 1
+        else
+            exit 1
+        end
+    end
+
+    echo ""
+    echo "Running $category tests..."
+
+    set testOutput "$(dotnet test \
+        -c "$config" \
+        -f "$framework" \
+        --verbosity "$verbosity" \
+        --logger "trx;LogFileName=$category.trx" \
+        --results-directory "TestResults" \
+        --filter "Category=$category" \
+        --no-build \
+        "$projectFile"
+    )"; or begin
+        echo "$testOutput"
+        error "$category tests failed!"
+
+        if status --is-interactive
+            return 1
+        else
+            exit 1
+        end
+    end
+
+    if string match "No test is available" "$testOutput"
+        # Bad category name, no test was run
+        error "$category test was not run! Category may not exist."
+
+        if status --is-interactive
+            return 1
+        else
+            exit 1
+        end
+    end
+
+    success "$category tests passed."
+    return 0
+end
+
+function buildProject -a projectFile
+    if ! test -e "$projectFile"
+        error "Project file at $projectFile does not exist"
+
+        if status --is-interactive
+            return 1
+        else
+            exit 1
+        end
+    end
+
+    dotnet build \
+        -c "$config" \
+        --verbosity "$verbosity" \
+        "$projectFile"
+
+    if test $status -ne 0
+        if status --is-interactive
+            return 1
+        else
+            exit 1
+        end
+    end
+end
+
+function packProject -a revision -a outputDir -a projectFile
+    if test -z "$revision"
+        error "revision value is empty."
+
+        if status --is-interactive
+            return 1
+        else
+            exit 1
+        end
+    end
+
+    if test -z "$outputDir"
+        error "outputDir value is empty."
+
+        if status --is-interactive
+            return 1
+        else
+            exit 1
+        end
+    end
+
+    if ! test -e "$projectFile"
+        error "Project file at $projectFile does not exist"
+
+        if status --is-interactive
+            return 1
+        else
+            exit 1
+        end
+    end
+
+    dotnet pack \
+        -c "$config" \
+        --version-suffix "$revision" \
+        -o "$outputDir" \
+        "$projectFile";
+    or begin
+        if status --is-interactive
+            return 1
+        else
+            exit 1
+        end
+    end
+
+    success "Packed $project for prerelease."
+
+    dotnet pack \
+        -c Release \
+        -o "$outputDir" \
+        "$projectFile"; 
+    or begin
+        if status --is-interactive
+            return 1
+        else
+            exit 1
+        end
+    end
+
+    success "Packed $projectFile for release."
+end
+
+function countMissingPolicies -a file -d "Counts the number of missing execution policies compared to the number of new ShopifySharp services instantiated in a file."
+    if ! test -e "$file"
+        error "File at $file does not exist."
+
+        if status --is-interactive
+            return 1
+        else
+            exit 1
+        end
+    end
+
+    set totalNewServices (count (rg "new \w+Service\(" "$file"))
+    set totalPoliciesSet (count (rg "\.SetExecutionPolicy\(" "$file"))
+
+    if test $totalPoliciesSet -ge $totalNewServices
+        echo 0
+    else
+        echo (math $totalNewServices - $totalPoliciesSet)
+    end
+end
+
+function countMisconfiguredFixtures -a file -d "Counts the number of missing or misconfigured test fixture classes in a file."
+    if ! test -e "$file"
+        error "File at $file does not exist."
+
+        if status --is-interactive
+            return 1
+        else
+            exit 1
+        end
+    end
+
+    set totalAsyncLifetimes (count (rg "class \w+ *: *IAsyncLifetime" "$file"))
+    set totalTestClasses (count (rg "class \w+ *: *IClassFixture<\w+>" "$file"))
+
+    if test $totalAsyncLifetimes -gt $totalTestClasses
+        # There are more IAsyncLifetime fixtures defined in this file than are used, which could indicate a misconfiguration
+        echo (math $totalAsyncLifetimes - $totalTestClasses)
+    else
+        echo (math $totalTestClasses - $totalAsyncLifetimes)
+    end
+end