-
Notifications
You must be signed in to change notification settings - Fork 1
/
flatten.nw
58 lines (56 loc) · 1.68 KB
/
flatten.nw
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
\section{Flatting a grammar}
[[flattengrammar]] introduces enough new nonterminals to put the grammar in
a form in which:
\begin{itemize}
\item The child of every while or optional node is a nonterminal.
\item Every child of every cat node is a terminal or a nontermal.
\end{itemize}
This flattening simplifies the use of semantic actions, and it also is
a first step toward emitting a yacc grammar.
@
<<*>>=
procedure flattengrammar(g)
work := []
every lhs := !g.ntlist do
every put(work, lhs | g.nonterms[lhs])
g.ntlist := []
while lhs := get(work) & node := get(work) do {
put(g.ntlist, lhs)
flattenpair(g, work, lhs, node)
}
return g
end
<<*>>=
procedure flattenpair(g, work, lhs, node)
static epsilon
initial { epsilon := Cat([]) }
case type(node) of {
"Opt" | "Clo" :
if not member(g.nonterms, node.node) then
node.node := cutnode(g, work, lhs, node.node)
"Cat" : every n := node.list[i := 1 to *node.list] &
not member(g.nonterms | g.terms, n) do
node.list[i] := cutnode(g, work, lhs, n)
"Alt" : every n := node.list[i := 1 to *node.list] do
if type(n) == "Cat" then
flattenpair(g, work, lhs, n)
else if not member(g.nonterms | g.terms, n) then
node.list[i] := cutnode(g, work, lhs, n)
"string" : &null
default : error("impossible node type")
}
return
end
procedure cutnode(g, work, lhs, node)
g.nonterms[s := gensym(lhs)] := node
every push(work, node | s)
return s
end
<<*>>=
procedure gensym(id)
static syms
initial syms := table()
/id = "XX"
/syms[id] := create(seq())
return id || "_" || @ syms[id]
end