-
Notifications
You must be signed in to change notification settings - Fork 6
/
core.clj
392 lines (372 loc) · 14.5 KB
/
core.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
(ns dynadoc.core
(:require [clojure.edn :as edn]
[clojure.java.io :as io]
[clojure.string :as str]
[clojure.repl :as repl]
[clojure.walk :as walk]
[ring.middleware.resource :refer [wrap-resource]]
[ring.middleware.file :refer [wrap-file]]
[ring.middleware.reload :refer [wrap-reload]]
[ring.middleware.content-type :refer [wrap-content-type]]
[ring.middleware.keyword-params :refer [wrap-keyword-params]]
[ring.middleware.params :refer [wrap-params]]
[ring.util.response :refer [redirect not-found]]
[ring.util.request :refer [body-string]]
[org.httpkit.server :refer [run-server send!]]
[rum.core :as rum]
[dynadoc.common :as common]
[dynadoc.static :as static]
[dynadoc.utils :as u]
[dynadoc.example :as ex]
[dynadoc.watch :as watch]
[dynadoc.aliases]
[eval-soup.core :as es]
[clojure.tools.cli :as cli]
[clojure.data.codec.base64 :as base64])
(:import [java.util.zip ZipEntry ZipOutputStream]))
(defonce *web-server (atom nil))
(defonce *options (atom nil))
(defn get-examples
([ns-sym var-sym]
(let [examples (get-in @ex/registry-ref [ns-sym var-sym])]
(vec
(for [i (range (count examples))]
(-> (get examples i)
u/process-example
(assoc :id (str ns-sym "/" var-sym "/" i)))))))
([ns-sym]
(reduce
(fn [m [k v]]
(assoc m k {:sym k
:examples (vec
(for [i (range (count v))]
(-> (get v i)
u/process-example
(assoc :id (str ns-sym "/" k "/" i)))))}))
{}
(get @ex/registry-ref ns-sym))))
(defn var-map->vars [ns-sym var-map]
(if (empty? var-map)
[]
(->> (merge (get-examples ns-sym) var-map)
vals
(sort-by #(-> % :sym str))
vec)))
(defn get-cljs-nses-and-vars-dynamically []
(when-let [*env (:*cljs-env @*options)]
(require 'cljs.analyzer.api)
(let [all-ns (resolve (symbol "cljs.analyzer.api" "all-ns"))
ns-publics (resolve (symbol "cljs.analyzer.api" "ns-publics"))]
(reduce
(fn [m ns-sym]
(let [var-map (reduce
(fn [m [var-sym {:keys [doc arglists anonymous] :as parsed-var}]]
(if anonymous
m
(assoc m var-sym
{:sym var-sym
:meta {:doc doc
:arglists (if (= 'quote (first arglists))
(second arglists)
arglists)}
:examples (get-examples ns-sym var-sym)
:methods (some-> parsed-var
:protocol-info
:methods
keys
sort)
:protocol (some-> parsed-var
:protocol
name
symbol)})))
{}
(ns-publics *env ns-sym))
vars (var-map->vars ns-sym var-map)]
(assoc m ns-sym vars)))
{}
(all-ns *env)))))
(defn get-cljs-nses-and-vars []
(or (get-cljs-nses-and-vars-dynamically)
(->> (static/get-cljs-nses-and-vars)
(reset! watch/*cljs-info)
u/flatten-vals)))
(defn get-cljs-nses [cljs-nses-and-vars]
(->> (keys cljs-nses-and-vars)
(map #(hash-map
:sym %
:type :cljs
:var-syms (mapv :sym (get cljs-nses-and-vars %))))
(remove #(-> % :var-syms empty?))))
(defn get-cljs-vars [cljs-nses-and-vars ns]
(->> (get cljs-nses-and-vars ns)
(sort-by #(-> % :sym str))
vec))
(defn get-clj-nses []
(->> (all-ns)
(map #(hash-map
:sym (ns-name %)
:type :clj
:var-syms (vec (keys (ns-publics %)))))
(remove #(-> % :var-syms empty?))))
(defn get-clj-var-info [ns-sym var-sym]
(let [sym (symbol (str ns-sym) (str var-sym))]
{:sym var-sym
:meta (-> sym
find-var
meta
(select-keys [:arglists :doc]))
:source (try (repl/source-fn sym)
(catch Exception _))
:spec (try
(require 'clojure.spec.alpha)
(let [form (resolve (symbol "clojure.spec.alpha" "form"))]
(with-out-str
(clojure.pprint/pprint
(form sym))))
(catch Exception _))
:examples (get-examples ns-sym var-sym)}))
(defn get-clj-vars [ns-sym]
(->> (ns-publics ns-sym)
keys
(reduce
(fn [m var-sym]
(if (str/includes? (name var-sym) ".proxy$")
m
(assoc m var-sym (get-clj-var-info ns-sym var-sym))))
{})
(var-map->vars ns-sym)))
(defn page-state [uri {:keys [type ns-sym var-sym static? nses cljs-nses-and-vars] :as opts}]
(let [cljs-nses-and-vars (or cljs-nses-and-vars (get-cljs-nses-and-vars))
nses (or nses
(->> (concat (get-clj-nses) (get-cljs-nses cljs-nses-and-vars))
(sort-by #(-> % :sym str))
vec))
vars (case type
:clj (cond
var-sym [(get-clj-var-info ns-sym var-sym)]
ns-sym (get-clj-vars ns-sym))
:cljs (cond
var-sym [(some (fn [var]
(when (-> var :sym (= var-sym))
var))
(get-cljs-vars cljs-nses-and-vars ns-sym))]
ns-sym (get-cljs-vars cljs-nses-and-vars ns-sym))
nil)
rel-path (-> (remove empty? (str/split uri #"/"))
count
(- 1)
(repeat "../")
str/join)]
(merge opts
{:static? static?
:nses nses
:ns-meta (when (= type :clj)
(some-> ns-sym the-ns meta))
:vars vars
:rel-path rel-path
:check-for-updates? (and (not ns-sym)
(not var-sym)
(not static?)
(not (:dev? @*options))
(not (:disable-update-checker? @*options)))})))
(defn page [uri opts]
(let [state (page-state uri opts)]
(-> "template.html" io/resource slurp
(str/replace "{{rel-path}}" (:rel-path state))
(str/replace "{{content}}" (rum/render-html (common/app (atom state))))
(str/replace "{{initial-state}}" (-> (pr-str state)
(.getBytes "UTF-8")
base64/encode
(String. "UTF-8"))))))
(def public-files
["main.js"
"paren-soup-dark.css"
"paren-soup-light.css"
"style.css"
"fonts/FiraCode-Bold.otf"
"fonts/FiraCode-Light.otf"
"fonts/FiraCode-Medium.otf"
"fonts/FiraCode-Regular.otf"
"fonts/FiraCode-Retina.otf"
"fonts/glyphicons-halflings-regular.eot"
"fonts/glyphicons-halflings-regular.svg"
"fonts/glyphicons-halflings-regular.ttf"
"fonts/glyphicons-halflings-regular.woff"
"fonts/glyphicons-halflings-regular.woff2"])
(defn export [{:strs [pages export-filter type ns-sym var-sym]}]
(let [type (some-> type keyword)
ns-sym (some-> ns-sym symbol)
var-sym (when var-sym
(edn/read-string var-sym))
zip-file (io/file "dynadoc-export.zip")]
(with-open [zip (ZipOutputStream. (io/output-stream zip-file))]
(case pages
"single"
(cond
(some? var-sym)
(do
(.putNextEntry zip (ZipEntry. "index.html"))
(io/copy (page
"/index.html"
{:type type
:ns-sym ns-sym
:var-sym var-sym
:static? true
:hide-sidebar? true})
zip)
(.closeEntry zip))
(some? ns-sym)
(let [cljs-nses-and-vars (get-cljs-nses-and-vars)
var-syms (map :sym
(case type
:cljs (get-cljs-vars cljs-nses-and-vars ns-sym)
:clj (get-clj-vars ns-sym)))]
(.putNextEntry zip (ZipEntry. "index.html"))
(io/copy (page
"/index.html"
{:type type
:ns-sym ns-sym
:static? true
:hide-sidebar? true
:cljs-nses-and-vars cljs-nses-and-vars})
zip)
(.closeEntry zip)
(doseq [var-sym var-syms
:let [path (common/var-sym->url "" true type ns-sym var-sym)]]
(.putNextEntry zip (ZipEntry. path))
(io/copy (page path
{:type type
:ns-sym ns-sym
:var-sym var-sym
:static? true
:hide-sidebar? true
:cljs-nses-and-vars cljs-nses-and-vars})
zip)
(.closeEntry zip))))
"multiple"
(let [clj-nses (get-clj-nses)
cljs-nses-and-vars (get-cljs-nses-and-vars)
cljs-nses (get-cljs-nses cljs-nses-and-vars)
nses (if-let [search (some-> export-filter re-pattern)]
(filter #(re-find search (-> % :sym str))
(sort-by :sym (concat clj-nses cljs-nses)))
(sort-by :sym (concat clj-nses cljs-nses)))]
(.putNextEntry zip (ZipEntry. "index.html"))
(io/copy (page "/index.html"
{:static? true
:cljs-nses-and-vars cljs-nses-and-vars
:nses nses})
zip)
(.closeEntry zip)
(doseq [{:keys [sym type var-syms]} nses
:let [path (str (name type) "/" sym ".html")]]
(.putNextEntry zip (ZipEntry. path))
(io/copy (page path
{:type type
:ns-sym sym
:static? true
:cljs-nses-and-vars cljs-nses-and-vars
:nses nses})
zip)
(.closeEntry zip)
(doseq [var-sym var-syms
:let [path (common/var-sym->url "" true type sym var-sym)]]
(.putNextEntry zip (ZipEntry. path))
(io/copy (page path
{:type type
:ns-sym sym
:var-sym var-sym
:static? true
:cljs-nses-and-vars cljs-nses-and-vars
:nses nses})
zip)
(.closeEntry zip)))))
(doseq [path public-files]
(.putNextEntry zip (ZipEntry. path))
(io/copy
(io/input-stream
(or (io/resource (str "dynadoc-extend/" path))
(io/resource (str "dynadoc-public/" path))))
zip)
(.closeEntry zip)))
zip-file))
(defn handler [{:keys [uri] :as request}]
(or (case uri
"/"
{:status 200
:headers {"Content-Type" "text/html"}
:body (page uri {:static? false})}
"/eval"
{:status 200
:headers {"Content-Type" "text/plain"}
:body (->> request
:body
.bytes
slurp
edn/read-string
(#(es/code->results % {:disable-security? true}))
(mapv u/form->serializable)
pr-str)}
"/dynadoc-export.zip"
{:status 200
:headers {"Content-Type" "application/zip"}
:body (export (:params request))}
"/watch"
(watch/watch-request request)
nil)
(let [[type ns-sym var-sym] (u/parse-uri uri)]
(when (contains? #{:clj :cljs} type)
{:status 200
:headers {"Content-Type" "text/html"}
:body (page uri {:static? false :type type :ns-sym ns-sym :var-sym var-sym})}))
(not-found "Page not found")))
(defn print-server [server]
(println
(str "Started Dynadoc on http://localhost:"
(-> server meta :local-port)))
server)
(defn start
([opts]
(-> handler
(wrap-resource "dynadoc-public")
(wrap-resource "dynadoc-extend")
(start opts)))
([app opts]
(when-not @*web-server
; start watcher if parsing cljs statically
(when-not (:*cljs-env opts)
(add-watch watch/*cljs-info :cljs-info
(fn [_ _ _ cljs-info]
(doseq [[channel uri] @watch/*channel->uri]
(let [[type ns-sym var-sym] (u/parse-uri uri)]
(->> {:static? false :cljs-nses-and-vars (u/flatten-vals cljs-info)
:type type :ns-sym ns-sym :var-sym var-sym}
(page-state uri)
pr-str
(send! channel))))))
(watch/init-watcher!))
; start server
(->> (merge {:port 0} opts)
(reset! *options)
(run-server (-> app wrap-content-type wrap-params wrap-keyword-params))
(reset! *web-server)
print-server))))
(defn dev-start [opts]
(when-not @*web-server
(.mkdirs (io/file "target" "dynadoc-public"))
(start (-> #'handler
(wrap-reload)
(wrap-file "target/dynadoc-public"))
opts)))
(defn -main [& args]
(let [cli (cli/parse-opts args u/cli-options)]
(cond
;; if there are CLI errors, print error messages and usage summary
(:errors cli)
(println (:errors cli) "\n" (:summary cli))
;; if user asked for CLI usage, print the usage summary
(get-in cli [:options :usage])
(println (:summary cli))
;; in other cases start Dynadoc
:otherwise
(start (:options cli)))))