app-pda/libimobiledevice: bump 1.2.0, app-pda/*: small fixes

Signed-off-by: David Heidelberg <david@ixit.cz>

app-pda/libimobiledevice/Manifest

@@ -0,0 +1 @@
+DIST libimobiledevice-1.2.0.tar.bz2 631495 SHA256 786b0de0875053bf61b5531a86ae8119e320edab724fc62fe2150cc931f11037 SHA512 0de5f768aeb5d62445892855d84ceaff776f6667733c351ed6c34bf9d500802762d1a06e5efdf57f33cafc9ee788041cd9b6748fb9bad6c2e4ae2f9b9aa93589 WHIRLPOOL ca0d709fcc844811fa19b1b149afd81c15f75c213384789b1bc1a4ec838f12ffa33c6f78753befd4eae81156cb1c002d24e7ddc50a59f374164c33ddfd37ddb6

app-pda/libimobiledevice/libimobiledevice-1.2.0.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_2,3_3,3_4} )
+AUTOTOOLS_PRUNE_LIBTOOL_FILES=all
+inherit autotools-utils multilib python-r1
+
+DESCRIPTION="Support library to communicate with Apple iPhone/iPod Touch devices"
+HOMEPAGE="http://www.libimobiledevice.org/"
+SRC_URI="http://www.libimobiledevice.org/downloads/${P}.tar.bz2"
+
+# While COPYING* doesn't mention 'or any later version', all the headers do, hence use +
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0/4" # based on SONAME of libimobiledevice.so
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="gnutls python static-libs"
+
+RDEPEND=">=app-pda/libplist-1.11:=[python?,${PYTHON_USEDEP}]
+	>=app-pda/libusbmuxd-1.0.9:=
+	gnutls? (
+		dev-libs/libgcrypt:0
+		>=dev-libs/libtasn1-1.1
+		>=net-libs/gnutls-2.2.0
+		)
+	!gnutls? ( dev-libs/openssl:0 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	python? (
+		${PYTHON_DEPS}
+		>=dev-python/cython-0.17[${PYTHON_USEDEP}]
+		)"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DOCS=( AUTHORS NEWS README )
+
+pkg_setup() {
+	# Prevent linking to the installed copy
+	if has_version "<${CATEGORY}/${P}"; then
+		rm -f "${EROOT}"/usr/$(get_libdir)/${PN}$(get_libname)
+	fi
+}
+
+src_configure() {
+	local myeconfargs=( $(use_enable static-libs static) )
+	use gnutls && myeconfargs+=( --disable-openssl )
+	use python || myeconfargs+=( --without-cython )
+
+	python_foreach_impl autotools-utils_src_configure
+}
+
+src_compile() {
+	python_foreach_impl autotools-utils_src_compile
+}
+
+src_install() {
+	python_foreach_impl autotools-utils_src_install
+	dohtml docs/html/*
+
+	if use python; then
+		insinto /usr/include/${PN}/cython
+		doins cython/imobiledevice.pxd
+	fi
+}

app-pda/libimobiledevice/metadata.xml

@@ -0,0 +1,5 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<herd>pda</herd>
+</pkgmetadata>

app-pda/libplist/libplist-1.12.ebuild

@@ -13,7 +13,7 @@ SRC_URI="http://www.libimobiledevice.org/downloads/${P}.tar.bz2"
 
 LICENSE="GPL-2 LGPL-2.1"
 SLOT="0/2" # based on SONAME of libplist.so
-KEYWORDS="amd64 ~arm ~ppc ~ppc64 x86 ~amd64-fbsd"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-fbsd"
 IUSE="python static-libs"
 
 RDEPEND=">=dev-libs/libxml2-2.7.8"