build.gradle

plugins {
    id "java-library"
    id "org.openmicroscopy.project" version "5.5.4"
    id "org.openmicroscopy.dsl" version "5.5.2"
}

group = "org.openmicroscopy"
version = "5.6.13"

ext {
    databaseType = "psql"
}
repositories {
    mavenLocal()
    mavenCentral()
}

java {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
}

dependencies {
    testImplementation("org.testng:testng:7.5")

    // Needs updating to later versions
    api("org.springframework:spring-orm:4.3.14.RELEASE")
    api("org.springframework:spring-context:4.3.14.RELEASE")
    api("org.springframework:spring-context-support:4.3.22.RELEASE")
    api("org.hibernate:hibernate-core:3.6.10.Final")
    api("org.hibernate:hibernate-search:3.4.2.Final")

    // Our libraries
    api("ome:formats-gpl:7.1.0")

    // Unidata
    api("edu.ucar:bufr:3.0"){
        exclude group: "edu.ucar", module: "netcdf"
    }
    api("edu.ucar:udunits:4.5.5")
}

test {
    testLogging {
        events "passed", "skipped", "failed", "standardOut", "standardError"
    }
    // enable TestNG support (default is JUnit)
    useTestNG() {
        suites "src/test/resources/unit.testng.xml"
    }
    dependsOn cleanTest
}

dsl {
    database databaseType

    outputDir file("build/${databaseType}")

    multiFile {
        java {
            template "object.vm"
            outputDir "java"
            formatOutput = { st ->
                "${st.getPackage()}/${st.getShortname()}.java"
            }
        }
    }

    singleFile {
        hibernate {
            template "cfg.vm"
            outputFile "resources/hibernate.cfg.xml"
        }

        sql {
            template "views.vm"
            outputFile "resources/views.sql"
        }

        enums {
            template "enums.vm"
            outputFile "resources/enums.properties"
        }
    }
}

processResources {
    with copySpec {
        from 'src/main/resources'
        // Set db profile
        filter { String line ->
            line.startsWith('omero.db.profile') ? 'omero.db.profile='+databaseType : line
        }
    }
}