-
Notifications
You must be signed in to change notification settings - Fork 40
/
BaseType.ooc
541 lines (443 loc) · 17.6 KB
/
BaseType.ooc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
import structs/[List, ArrayList]
import ../backend/cnaughty/AwesomeWriter, ../frontend/[BuildParams, Token]
import tinker/[Response, Resolver, Trail, Errors]
import Type, Declaration, VariableAccess, VariableDecl, TypeDecl,
InterfaceDecl, Node, ClassDecl, CoverDecl, Cast, FuncType,
FunctionCall, Module
NumericState: enum {
UNKNOWN, YES, NO
}
BaseType: class extends Type {
ref: Declaration = null
name: String
_numeric : NumericState = NumericState UNKNOWN
void? : Bool {
get { super() || name == "void" || name == "Void" }
}
typeArgs: List<VariableAccess> = null
init: func ~baseType (=name, .token) {
super(token)
}
pointerLevel: func -> Int { 0 }
isPointer: func -> Bool { name == "Pointer" }
write: func (w: AwesomeWriter, name: String) {
if(getRef() == null) {
Exception new(This, "Trying to write unresolved type " + toString()) throw()
}
match {
case getRef() instanceOf?(InterfaceDecl)=> writeInterfaceType(w, getRef() as InterfaceDecl)
case getRef() instanceOf?(TypeDecl) => writeRegularType (w, getRef() as TypeDecl)
case getRef() instanceOf?(VariableDecl) => writeGenericType (w, getRef() as VariableDecl)
}
if(name != null) w app(' '). app(name)
}
writeInterfaceType: func (w: AwesomeWriter, id: InterfaceDecl) {
w app(id getFatType() getInstanceType())
}
writeRegularType: func (w: AwesomeWriter, td: TypeDecl) {
if(td isExtern()) {
if(td instanceOf?(CoverDecl)) {
cDecl := getRef() as CoverDecl
fromType := cDecl getFromType()
if(fromType != null && cDecl isExtern()) {
// for extern covers, write directly the underlying
// type - since we don't even write a typedef.
w app(fromType getGroundType() toString())
return
}
}
// still have a chance to have an extern name
w app(td getExternName())
return
}
while(td instanceOf?(CoverDecl) && td as CoverDecl isAddon()) {
td = td as CoverDecl getBase() getNonMeta()
}
w app(td underName())
if(td instanceOf?(ClassDecl)) {
w app('*')
}
}
writeGenericType: func (w: AwesomeWriter, vd: VariableDecl) {
w app("uint8_t*")
}
equals?: func (other: This) -> Bool {
if(other class != this class) return false
return (other as BaseType name equals?(name))
}
addTypeArg: func (typeArg: VariableAccess) -> Bool {
if(!typeArgs) typeArgs = ArrayList<VariableAccess> new()
typeArgs add(typeArg); true
}
getName: func -> String { name }
suggest: func (decl: Declaration) -> Bool {
if(decl instanceOf?(TypeDecl) && decl as TypeDecl isAddon()) {
// The second rule of resolve club is: you do *NOT* resolve to an addon.
// Always resolve to the base instead.
return suggest(decl as TypeDecl getBase() getNonMeta())
}
ref = decl
if(name == "This" && getRef() instanceOf?(TypeDecl)) {
tDecl := getRef() as TypeDecl
name = tDecl getName()
}
return true
}
resolve: func (trail: Trail, res: Resolver) -> Response {
if(isResolved()) {
if(ref token module && ref token module dead) {
"%s outdated from module %s, re-resolving!" printfln(name, ref token module fullName)
ref = null
res wholeAgain(this, "re-resolved because of dead module")
} else {
return Response OK
}
}
if(!ref) {
depth := trail getSize() - 1
while(depth >= 0) {
node := trail get(depth, Node)
node resolveType(this, res, trail)
if(ref) {
break // break on first match
}
depth -= 1
}
}
if(!ref) {
if(res fatal) {
if(res params veryVerbose) {
trail toString() println()
}
msg := "Undefined type '%s'" format(getName())
similar := findSimilar(res)
if(similar) msg += similar
res throwError(UnresolvedType new(token, this, msg))
}
if(res params veryVerbose) {
" - type %s still not resolved, looping (ref = %p)" printfln(name, getRef())
}
return Response LOOP
} else if(ref instanceOf?(TypeDecl)) {
tDecl := ref as TypeDecl
if(!tDecl isMeta && !tDecl getTypeArgs() empty?()) {
if((typeArgs == null || typeArgs getSize() != tDecl getTypeArgs() getSize()) && !trail peek() instanceOf?(Cast)) {
message : String = match {
case typeArgs == null =>
"No"
case typeArgs getSize() < tDecl getTypeArgs() getSize() =>
"Too few"
case =>
"Too many"
}
res throwError(MismatchedTypeParams new(token, "%s type parameters for %s. It should match %s" format(message, toString(), tDecl getInstanceType() toString())))
}
}
}
if(typeArgs) {
trail push(this)
for(typeArg in typeArgs) {
response := typeArg resolve(trail, res)
if(!response ok()) {
trail pop(this)
return response
}
}
trail pop(this)
}
return Response OK
}
findSimilar: func (res: Resolver) -> String {
buff := Buffer new()
for(imp in res collectAllImports()) {
module := imp getModule()
type := module getTypes() get(name)
if(type) {
buff append(" (Hint: there's such a type in "). append(imp getPath()). append(")")
}
}
buff toString()
}
isResolved: func -> Bool {
if(ref == null) return false
if(ref token module && ref token module dead) return false
if(typeArgs == null) return true
for(typeArg in typeArgs) if(!typeArg isResolved()) {
return false
}
return true
}
getRef: func -> Declaration { ref }
setRef: func (=ref) {}
getTypeArgs: func -> List<VariableAccess> { typeArgs }
getScoreImpl: func (other: Type, scoreSeed: Int) -> Int {
//printf("%s vs %s, other isGeneric ? %s pointerLevel ? %d isPointer() ? %d, other isPointer() ? %d\n", toString(), other toString(), other isGeneric() toString(), other pointerLevel(), isPointer(), other getGroundType() isPointer())
if(void?) return This NOLUCK_SCORE
ourRef := getRef()
if(!ourRef) return -1
hisRef := other getRef()
if(!hisRef) return -1
if(other isGeneric() && other pointerLevel() == 0) {
// every type is always a match against a flat generic type
return scoreSeed
}
if(isGeneric() && other isPointer()) {
// a generic value is a match for a pointer
return scoreSeed / 2
}
if(isPointer() && hisRef instanceOf?(ClassDecl)) {
// objects are references in ooc
return scoreSeed / 4
}
if(ourRef instanceOf?(ClassDecl) && other isPointer()) {
// objects are still references in ooc
return scoreSeed / 4
}
ground := other getGroundType()
if(isPointer() && (ground isPointer() || ground pointerLevel() > 0)) {
// two pointers = okay
return scoreSeed / 2
}
if(other instanceOf?(BaseType)) {
if(ourRef == hisRef) {
// perfect match
return scoreSeed
}
// if we are one of his addons, we're good
if(hisRef instanceOf?(TypeDecl)) {
for(addon in hisRef as TypeDecl getAddons()) {
hisRef2 := addon base
//printf("Reviewing addon %s, ref %s (%s), vs %s (%s)\n", addon getNonMeta() toString(), ourRef toString(), ourRef token toString(), hisRef toString(), hisRef token toString())
if(ourRef == hisRef2) {
// perfect match
return scoreSeed
}
}
}
if(ourRef instanceOf?(TypeDecl) && hisRef instanceOf?(TypeDecl)) {
inheritsScore := ourRef as TypeDecl inheritsScore(hisRef as TypeDecl, scoreSeed - 1)
// something needs resolving
if(inheritsScore == -1) {
return -1
}
bothCovers := ourRef instanceOf?(CoverDecl) && hisRef instanceOf?(CoverDecl)
if(inheritsScore <= 0 && bothCovers) {
// well, try the other way around - covers are lax - but it'll be weaker this time
inheritsScore = hisRef as TypeDecl inheritsScore(ourRef as TypeDecl, scoreSeed / 2)
}
// cool, a match =)
if(inheritsScore > 0) {
return inheritsScore
}
}
if(isNumericType() && other isNumericType()) {
// a mild match - it's not too good to mix integer types. Maybe we need more safety here?
return scoreSeed / 4
}
}
return This NOLUCK_SCORE // no luck.
}
_computeNumeric: func {
// FIXME: that's quite ugly - and what about custom types?
if ((
name == "Int" || name == "UInt" || name == "Short" ||
name == "UShort"|| name == "Long" || name == "ULong" ||
name == "LLong" || name == "ULLong"|| name == "Int8" ||
name == "Int16" || name == "Int32" || name == "Int64" ||
name == "UInt8" || name == "UInt16"|| name == "UInt32"||
name == "UInt64"|| name == "SizeT" || name == "Float" ||
name == "Double"|| name == "SSizeT"|| name == "Octet" )) {
_numeric = NumericState YES
return
}
down := dig()
if(down && down isNumericType()) {
_numeric = NumericState YES
return
}
_numeric = NumericState NO
}
isNumericType: func -> Bool {
if(_numeric == NumericState UNKNOWN) _computeNumeric()
(_numeric == NumericState YES)
}
dereference: func -> Type {
digged := dig()
if(digged) {
return digged dereference()
}
null
}
clone: func -> This {
copy := new(name, token)
if(getTypeArgs()) for(typeArg in getTypeArgs()) {
copy addTypeArg(typeArg)
}
copy setRef(getRef())
copy
}
dig: func -> Type {
if(getRef() != null && getRef() instanceOf?(CoverDecl)) {
return ref as CoverDecl getFromType()
}
return null
}
checkedDigImpl: func (list: List<Type>, res: Resolver) {
if(getRef() == null) {
res wholeAgain(this, "Null ref while check-digging")
return
}
list add(this)
if(getRef() != null && getRef() instanceOf?(CoverDecl)) {
next := ref as CoverDecl getFromType()
if(next != null) {
if(list contains?(next)) {
buff := Buffer new()
isFirst := true
for(t in list) {
if(!isFirst) buff append(" -> ")
buff append(t toString())
isFirst = false
}
res throwError(CoverDeclLoop new(list first() token, "Loop in cover declaration: %s -> %s -> ..." format(buff toString(), next toString(), list getSize())))
}
next checkedDigImpl(list, res)
}
}
}
subclassOf?: func (t: Type) -> Bool {
if(!t instanceOf?(BaseType)) return false
bt := t as BaseType
if( ref == null || ! ref instanceOf?(TypeDecl)) return false
if(bt ref == null || !bt ref instanceOf?(TypeDecl)) return false
return ref as TypeDecl subclassOf?(bt ref as TypeDecl)
}
replace: func (oldie, kiddo: Node) -> Bool {
if(typeArgs) return typeArgs replace(oldie as VariableAccess, kiddo as VariableAccess)
false
}
toString: func -> String {
if(typeArgs == null) return getName()
sb := Buffer new()
sb append(getName())
sb append("<")
isFirst := true
if(typeArgs) for(typeArg in typeArgs) {
if(isFirst) isFirst = false
else sb append(", ")
sb append(typeArg toString())
}
sb append(">")
return sb toString()
}
searchTypeArg: func (typeArgName: String, finalScore: Int@) -> Type {
if(getRef() == null) {
finalScore = -1
return null
}
if(!getRef() instanceOf?(TypeDecl)) {
// only TypeDecl have typeArgs anyway.
return null
}
typeRef := getRef() as TypeDecl
if(typeRef typeArgs == null) return null
j := 0
for(arg in typeRef typeArgs) {
if(arg getName() == typeArgName) {
//printf("Looking for %s in %s (ref %s), candidate = %s, j = %d, typeArgs size() = %d\n", typeArgName, toString(), typeRef toString(), arg getName(), j, typeArgs ? typeArgs size() : -1)
if(typeArgs == null || typeArgs getSize() <= j) {
continue
}
candidate := typeArgs get(j)
ref := candidate getRef()
if(ref == null) return null
result : Type = null
//printf("Found candidate %s (which is a %s) for typeArg %s, ref is a %s, = %s\n", candidate toString(), candidate class name, typeArgName, ref class name, ref toString())
if(ref instanceOf?(TypeDecl)) {
// resolves to a known type
result = ref as TypeDecl getInstanceType()
} else if(ref instanceOf?(VariableDecl)) {
// resolves to an access to another generic type
result = BaseType new(ref as VariableDecl getName(), token)
result setRef(ref) // FIXME: that is experimental. is that a good idea?
} else if(ref instanceOf?(FuncType)) {
//printf("ref of %s is a %s!\n", candidate toString(), ref class name)
result = ref as FuncType
}
return result
}
j += 1
}
// FIXME: debug
// translate things like:
// HashMap<K, V> extends Iterator<V>
current := typeRef
while(current != null && current getSuperType() != null) {
result := searchInheritance(typeArgName, current, current getSuperType(), finalScore&)
if(finalScore == -1) return null
if(result) return result
current = current getSuperRef()
}
for(interfaceType in typeRef interfaceTypes) {
result := searchInheritance(typeArgName, typeRef, interfaceType, finalScore&)
if(finalScore == -1) return null
if(result) return result
}
superType := typeRef getSuperType()
if(superType != null) {
//printf("Searching for <%s> in super-type %s\n", typeArgName, superType toString())
return superType searchTypeArg(typeArgName, finalScore&)
}
return null
}
searchInheritance: func (typeArgName: String, current: TypeDecl, superType: Type, finalScore: Int@) -> Type {
j := 0
superRef := superType getRef() as TypeDecl
if(superRef == null) {
finalScore = -1
return null // something needs to be resolved further
}
superArgs := superRef getTypeArgs()
for(superArg in superArgs) {
if(superArg getName() == typeArgName) {
superRealArgs := superType getTypeArgs()
if(superRealArgs == null || superRealArgs getSize() < j) {
continue
}
candidate := superRealArgs get(j)
ref := candidate getRef()
if(ref == null) {
finalScore = -1
return null
}
result : Type = null
if(ref instanceOf?(TypeDecl)) {
// resolves to a known type
result = ref as TypeDecl getInstanceType()
} else if(ref instanceOf?(VariableDecl)) {
// resolves to an access to another generic type
result = BaseType new(ref as VariableDecl getName(), token)
result setRef(ref) // FIXME: that is experimental. is that a good idea?
}
return result
}
j += 1
}
null
}
realTypize: func (call: FunctionCall) -> Type {
finalScore := 0
solved := call resolveTypeArg(name, null, finalScore&)
if(solved) return solved
this
}
}
UnresolvedType: class extends Error {
type: Type
init: func (.token, =type, .message) {
super(token, message)
}
}
MismatchedTypeParams: class extends Error {
init: super func ~tokenMessage
}