-
-
Notifications
You must be signed in to change notification settings - Fork 359
/
Images.pm
2289 lines (1795 loc) · 67.9 KB
/
Images.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
# This file is part of Product Opener.
#
# Product Opener
# Copyright (C) 2011-2023 Association Open Food Facts
# Contact: contact@openfoodfacts.org
# Address: 21 rue des Iles, 94100 Saint-Maur des Fossés, France
#
# Product Opener is free software: you can redistribute it and/or modify
# it under the terms of the GNU Affero General Public License as
# published by the Free Software Foundation, either version 3 of the
# License, or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License
# along with this program. If not, see <http://www.gnu.org/licenses/>.
=head1 NAME
ProductOpener::Images - adds, processes, manages and displays product photos
=head1 DESCRIPTION
C<ProductOpener::Images> is used to:
- upload product images
- select and crop product images
- run OCR on images
- display product images
=head1 Product images on disk
Product images are stored in html/images/products/[product barcode split with slashes]/
For each product, this directory contains:
=over
=item [image number].[extension].orig (e.g. 1.jpg.orig, 2.jpg.orig etc.)
Original images uploaded by users or imported
=item [image number].jpg
Same image saved as JPEG with specific settings, and after some minimal processing (auto orientation, removing EXIF data, flattening PNG images to remove transparency).
Those images are not displayed on the web site (except on the product edit form), but can be selected and cropped.
=item [image number].[100|400].jpg
Same image saved with a maximum width and height of 100 and 400 pixels. Those thumbnails are used in the product edit form to show the available images.
=item [image number].json
OCR output from Google Cloud Vision.
When a new image is uploaded, a symbolic link to it is created in /new_images.
This triggers a script to generate and save the OCR: C<run_cloud_vision_ocr.pl>.
=item [front|ingredients|nutrition|packaging]_[2 letter language code].[product revision].[full|100|200|400].jpg
Cropped and selected image for the front of the product, the ingredients list, the nutrition facts table, and the packaging information / recycling instructions,
in 4 different sizes (full size, 100 / 200 / 400 pixels maximum width or height).
The product revision is a number that is incremented for each change to the product (each image upload and each image selection are also individual changes that
create a new revision).
The selected images are shown on the website, in the app etc.
When a new image is selected for a given field (e.g. ingredients) and language (e.g. French), the existing selected images are kept.
(e.g. we can have ingredients_fr.21.100.jpg and a new ingredients_fr.28.100.jpg).
Previously selected images are shown only when people access old product revisions.
Cropping coordinates for all revisions are stored in the "images" field of the product, so we could regenerate old selected and cropped images on demand.
=back
=cut
package ProductOpener::Images;
use ProductOpener::PerlStandards;
use Exporter qw< import >;
BEGIN {
use vars qw(@ISA @EXPORT_OK %EXPORT_TAGS);
@EXPORT_OK = qw(
&display_search_image_form
&process_search_image_form
&get_code_and_imagefield_from_file_name
&get_imagefield_from_string
&is_protected_image
&process_image_upload
&process_image_move
&process_image_crop
&process_image_unselect
&scan_code
&display_select_manage
&display_select_crop
&display_select_crop_init
&display_image
&display_image_thumb
&extract_text_from_image
&send_image_to_cloud_vision
&send_image_to_robotoff
@CLOUD_VISION_FEATURES_FULL
@CLOUD_VISION_FEATURES_TEXT
); # symbols to export on request
%EXPORT_TAGS = (all => [@EXPORT_OK]);
}
use vars @EXPORT_OK;
use ProductOpener::Store qw/get_string_id_for_lang retrieve store/;
use ProductOpener::Config qw/:all/;
use ProductOpener::Paths qw/%BASE_DIRS ensure_dir_created_or_die/;
use ProductOpener::Products qw/:all/;
use CGI qw/:cgi :form escapeHTML/;
use Image::Magick;
use Barcode::ZBar;
use Imager;
use Imager::zxing;
use Image::OCR::Tesseract 'get_ocr';
use ProductOpener::Products qw/:all/;
use ProductOpener::Lang qw/$lc %Lang lang/;
use ProductOpener::Display qw/:all/;
use ProductOpener::URL qw/format_subdomain/;
use ProductOpener::Users qw/%User/;
use ProductOpener::Text qw/remove_tags_and_quote/;
use Data::DeepAccess qw(deep_get);
use IO::Compress::Gzip qw(gzip $GzipError);
use Log::Any qw($log);
use Encode;
use JSON::MaybeXS;
use MIME::Base64;
use LWP::UserAgent;
use File::Copy;
=head1 SUPPORTED IMAGE TYPES
gif, jpeg, jpf, png, heic
=cut
my $supported_extensions = "gif|jpeg|jpg|png|heic";
=head1 FUNCTIONS
=cut
sub display_select_manage ($object_ref) {
my $id = "manage";
my $html = <<HTML
<div class=\"select_crop select_manage\" id=\"$id\"></div>
<hr class="floatclear" />
HTML
;
return $html;
}
sub display_select_crop ($object_ref, $id_lc, $language, $request_ref) {
# $id_lc = shift -> id_lc = [front|ingredients|nutrition|packaging]_[new_]?[lc]
my $id = $id_lc;
my $message = $Lang{"protected_image_message"}{$lc};
my $imagetype = $id_lc;
my $display_lc = $lc;
if ($id_lc =~ /^(.*?)_(new_)?(.*)$/) {
$imagetype = $1;
$display_lc = $3;
}
my $note = '';
if (defined $Lang{"image_" . $imagetype . "_note"}{$lc}) {
$note = "<p class=\"note\">→ " . $Lang{"image_" . $imagetype . "_note"}{$lc} . "</p>";
}
my $label = $Lang{"image_" . $imagetype}{$lc};
my $html = '';
if (is_protected_image($object_ref, $id_lc) and (not $User{moderator}) and (not $request_ref->{admin})) {
$html .= <<HTML;
<p>$message</p>
<label for="$id">$label (<span class="tab_language">$language</span>)</label>
<div class=\"select_crop\" id=\"$id\" data-info="protect"></div>
HTML
}
else {
$html .= <<HTML;
<label for="$id">$label (<span class="tab_language">$language</span>)</label>
$note
<div class=\"select_crop\" id=\"$id\"></div>
<hr class="floatclear" />
HTML
}
my @fields = qw(imgid x1 y1 x2 y2);
foreach my $field (@fields) {
my $value = "";
if (defined $object_ref->{"$id.$field"}) {
$value = $object_ref->{"$id.$field"};
}
$html
.= '<input type="hidden" name="'
. "${id}_$field"
. '" id="'
. "${id}_$field"
. '" value="'
. $value . '" />' . "\n";
}
my $size = $display_size;
my $product_ref = $object_ref;
my $display_url = '';
if ( (defined $product_ref->{images})
and (defined $product_ref->{images}{$id})
and (defined $product_ref->{images}{$id}{sizes})
and (defined $product_ref->{images}{$id}{sizes}{$size}))
{
$display_url = "$id." . $product_ref->{images}{$id}{rev} . ".$display_size.jpg";
}
$html
.= '<input type="hidden" name="'
. "${id}_display_url"
. '" id="'
. "${id}_display_url"
. '" value="'
. $display_url . '" />' . "\n";
return $html;
}
sub display_select_crop_init ($object_ref) {
$log->debug("display_select_crop_init", {object_ref => $object_ref}) if $log->is_debug();
my $path = product_path($object_ref);
my $images = '';
defined $object_ref->{images} or $object_ref->{images} = {};
# Construct an array of images that we can sort by upload time
# The imgid number is incremented by 1 for each new image, but when we move images
# from one product to another, they might not be sorted by upload time.
my @images = ();
# There may be occasions where max_imgid was not incremented correctly (e.g. a crash)
# so we add 5 to it to check if we have other images to show
for (my $imgid = 1; $imgid <= (($object_ref->{max_imgid} || 0) + 5); $imgid++) {
if (defined $object_ref->{images}{$imgid}) {
push @images, $imgid;
}
}
foreach my $imgid (sort {$object_ref->{images}{$a}{uploaded_t} <=> $object_ref->{images}{$b}{uploaded_t}} @images) {
my $uploader = $object_ref->{images}{$imgid}{uploader};
my $uploaded_date = display_date($object_ref->{images}{$imgid}{uploaded_t});
$images .= <<JS
{
imgid: "$imgid",
thumb_url: "$imgid.$thumb_size.jpg",
crop_url: "$imgid.$crop_size.jpg",
display_url: "$imgid.$display_size.jpg",
uploader: "$uploader",
uploaded: "$uploaded_date",
},
JS
;
}
$images =~ s/,\n?$//;
return <<HTML
\$([]).selectcrop('init_images', [
$images
]);
\$(".select_crop").selectcrop('init', {img_path : "//images.$server_domain/images/products/$path/"});
\$(".select_crop").selectcrop('show');
HTML
;
}
sub scan_code ($file) {
my $code = undef;
print STDERR "scan_code file: $file\n";
# obtain image data
my $magick = Image::Magick->new();
my $imagemagick_error = $magick->Read($file);
local $log->context->{file} = $file;
# ImageMagick can trigger an exception for some images that it can read anyway
# Exception codes less than 400 are warnings and not errors (see https://www.imagemagick.org/script/perl-magick.php#exceptions )
# e.g. Exception 365: CorruptImageProfile `xmp' @ warning/profile.c/SetImageProfileInternal/1704
if (($imagemagick_error) and ($imagemagick_error =~ /(\d+)/) and ($1 >= 400)) {
$log->warn("cannot read file to scan barcode", {error => $imagemagick_error}) if $log->is_warn();
}
else {
# create a reader/decoder
my $scanner = Barcode::ZBar::ImageScanner->new();
# configure the reader/decoder
$scanner->parse_config("enable");
# wrap image data
my $image = Barcode::ZBar::Image->new();
$image->set_format('Y800');
for (my $i = 1; $i <= 4; $i++) {
$image->set_size($magick->Get(qw(columns rows)));
my $raw = $magick->ImageToBlob(magick => 'GRAY', depth => 8);
$image->set_data($raw);
# scan the image for barcodes
my $n = $scanner->scan_image($image);
# extract results
foreach my $symbol ($image->get_symbols()) {
$code = $symbol->get_data();
my $type = $symbol->get_type();
$log->debug("barcode found", {code => $code, type => $type}) if $log->is_debug();
print STDERR "scan_code code found: $code\n";
if (($code !~ /^\d+|(?:[\^(\N{U+001D}\N{U+241D}]|https?:\/\/).+$/)) {
$code = undef;
next;
}
last;
}
if (defined $code) {
last;
}
$magick->Rotate(degrees => 90);
}
}
if (not(defined $code)) {
my $decoder = Imager::zxing::Decoder->new();
$decoder->set_formats("DataMatrix|QRCode|MicroQRCode|DataBar|DataBarExpanded");
my $imager = Imager->new();
$imager->read(file => $file)
or die "Cannot read $file: ", $imager->errstr;
my @results = $decoder->decode($imager);
# extract results
foreach my $result (@results) {
if (not($result->is_valid())) {
next;
}
$code = $result->text();
my $type = $result->format();
$log->debug("barcode found", {code => $code, type => $type}) if $log->is_debug();
print STDERR "scan_code code found: $code\n";
if (($code !~ /^\d+|(?:[\^(\N{U+001D}\N{U+241D}]|https?:\/\/).+$/)) {
$code = undef;
next;
}
last;
}
}
if (defined $code) {
$code = normalize_code($code);
print STDERR "scan_code return code: $code\n";
}
return $code;
}
sub display_search_image_form ($id, $request_ref) {
my $html = '';
my $product_image_with_barcode = $Lang{product_image_with_barcode}{$lc};
$product_image_with_barcode =~ s/( |\ )?:$//;
my $template_data_ref = {
product_image_with_barcode => $product_image_with_barcode,
id => $id,
};
# Do not load jquery file upload twice, if it was loaded by another form
if ($request_ref->{scripts} !~ /jquery.fileupload.js/) {
$request_ref->{scripts} .= <<JS
<script type="text/javascript" src="/js/dist/jquery.iframe-transport.js"></script>
<script type="text/javascript" src="/js/dist/jquery.fileupload.js"></script>
<script type="text/javascript" src="/js/dist/load-image.all.min.js"></script>
<script type="text/javascript" src="/js/dist/canvas-to-blob.js"></script>
JS
;
}
$request_ref->{initjs} .= <<JS
\/\/ start off canvas blocks for small screens
\$('#imgupload_search_$id').fileupload({
sequentialUploads: true,
dataType: 'json',
url: '/cgi/product.pl',
formData : [{name: 'jqueryfileupload', value: 1}, {name: 'action', value: 'process'}, {name: 'type', value:'search_or_add'}],
resizeMaxWidth : 2000,
resizeMaxHeight : 2000,
done: function (e, data) {
if (data.result.location) {
\$(location).attr('href',data.result.location);
}
if (data.result.error) {
\$("#imgsearcherror_$id").html(data.result.error);
\$("#imgsearcherror_$id").show();
}
},
fail : function (e, data) {
\$("#imgsearcherror_$id").show();
},
always : function (e, data) {
\$("#progressbar_$id").hide();
\$("#imgsearchbutton_$id").show();
\$("#imgsearchmsg_$id").hide();
},
start: function (e, data) {
\$("#imgsearchbutton_$id").hide();
\$("#imgsearcherror_$id").hide();
\$("#imgsearchmsg_$id").show();
\$("#progressbar_$id").show();
\$("#progressmeter_$id").css('width', "0%");
},
sent: function (e, data) {
if (data.dataType &&
data.dataType.substr(0, 6) === 'iframe') {
// Iframe Transport does not support progress events.
// In lack of an indeterminate progress bar, we set
// the progress to 100%, showing the full animated bar:
\$("#progressmeter_$id").css('width', "100%");
}
},
progress: function (e, data) {
\$("#progressmeter_$id").css('width', parseInt(data.loaded / data.total * 100, 10) + "%");
\$("#imgsearchdebug_$id").html(data.loaded + ' / ' + data.total);
}
});
\/\/ end off canvas blocks for small screens
JS
;
process_template('web/common/includes/display_search_image_form.tt.html', $template_data_ref, \$html, $request_ref)
|| return "template error: " . $tt->error();
return $html;
}
sub process_search_image_form ($filename_ref) {
my $imgid = "imgupload_search";
my $file = undef;
my $code = undef;
if ($file = single_param($imgid)) {
if ($file =~ /\.($supported_extensions)$/i) {
$log->debug("processing image search form", {imgid => $imgid, file => $file}) if $log->is_debug();
my $extension = lc($1);
my $filename = get_string_id_for_lang("no_language", remote_addr() . '_' . $`);
ensure_dir_created_or_die($BASE_DIRS{CACHE_TMP});
open(my $out, ">", "$BASE_DIRS{CACHE_TMP}/$filename.$extension");
while (my $chunk = <$file>) {
print $out $chunk;
}
close($out);
$code = scan_code("$BASE_DIRS{CACHE_TMP}/$filename.$extension");
if (defined $code) {
$code = normalize_code($code);
}
${$filename_ref} = "$BASE_DIRS{CACHE_TMP}/$filename.$extension";
}
}
return $code;
}
=head2 get_code_and_imagefield_from_file_name ( $l $filename )
This function is used to guess if an image is the front of the product,
its list of ingredients, or the nutrition facts table, based on the filename.
It is used in particular for bulk upload of photos sent by manufacturers.
The file names have many different formats, but they very often include the barcode of the product,
and sometimes an indication of what the image is.
Producers are advised to use the [front|ingredients|nutrition|packaging]_[language code] format,
but in practice we receive many other names.
The %file_names_to_imagefield_regexps structure below contains some patterns
used to guess what the image is about.
=cut
# the regexps apply to canonicalized strings
# i.e. lowercased / unaccented strings in most European languages
my %file_names_to_imagefield_regexps = (
en => [["ingredients" => "ingredients"], ["nutrition" => "nutrition"],],
es => [["ingredientes" => "ingredients"], ["nutricion" => "nutrition"],],
fr => [["ingredients" => "ingredients"], ["nutrition" => "nutrition"],],
);
sub get_code_and_imagefield_from_file_name ($l, $filename) {
my $code;
my $imagefield;
# codes with spaces
# 4 LR GROS LOUE_3 251 320 080 419_3D avant.png
$filename =~ s/(\d) (\d)/$1$2/g;
# Look for the barcode
if ($filename =~ /(\d{8}\d*)/) {
$code = $1;
# Make sure it's not a date like 20200201..
# e.g. IMG_20200810_111131.jpg
if ($filename =~ /(^|[^0-9])20(18|19|(2[0-9]))(0|1)/) {
$code = undef;
}
else {
$code = normalize_code($code);
}
}
# Check for a specified imagefield
$filename =~ s/(table|nutrition(_|-)table)/nutrition/i;
if ($filename =~ /((front|ingredients|nutrition|packaging)((_|-)\w\w\b)?)/i) {
$imagefield = lc($1);
$imagefield =~ s/-/_/;
}
# If the photo file name is just the barcode + some stopwords, assume it is the front image
# but [code]_2.jpg etc. should not be considered the front image
elsif (($filename =~ /^\d{8}\d*(-|_|\.| )*(photo|visuel|image)?(-|_|\.| )*\d*\.($supported_extensions)$/i)
and not($filename =~ /^\d{8}\d*(-|_|\.| )+\d{1,2}\.($supported_extensions)$/i))
{ # [code] + number between 0 and 99
$imagefield = "front";
}
elsif (defined $file_names_to_imagefield_regexps{$l}) {
my $filenameid = get_string_id_for_lang($l, $filename);
foreach my $regexp_ref (@{$file_names_to_imagefield_regexps{$l}}) {
my $regexp = $regexp_ref->[0];
if ($filenameid =~ /$regexp/) {
$imagefield = $regexp_ref->[1];
last;
}
}
}
if (not defined $imagefield) {
$imagefield = "other";
}
$log->debug("get_code_and_imagefield_from_file_name",
{l => $l, filename => $filename, code => $code, imagefield => $imagefield})
if $log->is_debug();
return ($code, $imagefield);
}
sub get_imagefield_from_string ($l, $filename) {
my $imagefield;
# Check for a specified imagefield
$filename =~ s/(table|nutrition(_|-)table)/nutrition/i;
if ($filename =~ /((front|ingredients|nutrition|packaging)((_|-)\w\w\b)?)/i) {
$imagefield = lc($1);
$imagefield =~ s/-/_/;
}
elsif (defined $file_names_to_imagefield_regexps{$l}) {
my $filenameid = get_string_id_for_lang($l, $filename);
foreach my $regexp_ref (@{$file_names_to_imagefield_regexps{$l}}) {
my $regexp = $regexp_ref->[0];
if ($filenameid =~ /$regexp/) {
$imagefield = $regexp_ref->[1];
last;
}
}
}
if (not defined $imagefield) {
$imagefield = "other";
}
$log->debug("get_imagefield_from_string", {l => $l, filename => $filename, imagefield => $imagefield})
if $log->is_debug();
return $imagefield;
}
sub get_selected_image_uploader ($product_ref, $imagefield) {
# Retrieve the product's image data
my $imgid = deep_get($product_ref, "images", $imagefield, "imgid");
# Retrieve the uploader of the image
if (defined $imgid) {
my $uploader = deep_get($product_ref, "images", $imgid, "uploader");
return $uploader;
}
return;
}
sub is_protected_image ($product_ref, $imagefield) {
my $selected_uploader = get_selected_image_uploader($product_ref, $imagefield);
my $owner = $product_ref->{owner};
if ( (not $server_options{producers_platform})
and (defined $owner)
and (defined $selected_uploader)
and ($selected_uploader eq $owner))
{
return 1; #image should be protected
}
return 0; # image should not be protected
}
=head2 process_image_upload ( $product_id, $imagefield, $user_id, $time, $comment, $imgid_ref, $debug_string_ref )
Process an image uploaded to a product (from the web site, from the API, or from an import):
- Read the image
- Create a JPEG version
- Create resized versions
- Store the image in the product data
=head3 Arguments
=head4 Product id $product_id
=head4 Image field $imagefield
Indicates what the image is and its language, or indicate a path to the image file
(for imports and when uploading an image with a barcode)
Format: [front|ingredients|nutrition|packaging|other]_[2 letter language code]
=head4 User id $user_id
=head4 Timestamp of the image $time
=head4 Comment $comment
=head4 Reference to an image id $img_id
Used to return the number identifying the image to the caller.
=head4 Debug string reference $debug_string_ref
Used to return some debug information to the caller.
=cut
sub process_image_upload ($product_id, $imagefield, $user_id, $time, $comment, $imgid_ref, $debug_string_ref) {
# $time = shift -> usually current time (images just uploaded), except for images moved from another product
# $imgid_ref = shift -> to return the imgid (new image or existing image)
# $debug_string_ref = shift -> to return debug information to clients
$log->debug("process_image_upload", {product_id => $product_id, imagefield => $imagefield}) if $log->is_debug();
# The product_id can be prefixed by a server (e.g. off:[code]) with a different $www_root
my $product_www_root = www_root_for_product_id($product_id);
my $product_data_root = data_root_for_product_id($product_id);
# debug message passed back to apps in case of an error
my $debug = "product_id: $product_id - user_id: $user_id - imagefield: $imagefield";
my $bogus_imgid;
not defined $imgid_ref and $imgid_ref = \$bogus_imgid;
my $path = product_path_from_id($product_id);
my $imgid = -1;
my $new_product_ref = {};
my $file = undef;
my $extension = 'jpg';
# Image that was already read by barcode scanner: can't read it again
# $image_field can be a path to the image file (for imports and when uploading an image with a barcode)
my $tmp_filename;
if ($imagefield =~ /\//) {
$tmp_filename = $imagefield;
$imagefield = 'search';
if ($tmp_filename) {
open($file, q{<}, "$tmp_filename")
or $log->error("Could not read file", {path => $tmp_filename, error => $!});
if ($tmp_filename =~ /\.($supported_extensions)$/i) {
$extension = lc($1);
}
}
}
else {
$file = single_param('imgupload_' . $imagefield);
if (!$file) {
# mobile app may not set language code
my $old_imagefield = $imagefield;
$old_imagefield =~ s/_\w\w$//;
$file = single_param('imgupload_' . $old_imagefield);
if (!$file) {
# producers platform: name="files[]"
$file = single_param("files[]");
}
}
}
local $log->context->{imagefield} = $imagefield;
local $log->context->{uploader} = $user_id;
local $log->context->{file} = $file;
local $log->context->{time} = $time;
# Check if we have already received this image before
my $images_ref = retrieve("$product_data_root/products/$path/images.sto");
defined $images_ref or $images_ref = {};
my $file_size = -s $file;
if (($file_size > 0) and (defined $images_ref->{$file_size})) {
$log->debug(
"we have already received an image with the same size",
{file_size => $file_size, imgid => $images_ref->{$file_size}}
) if $log->is_debug();
${$imgid_ref} = $images_ref->{$file_size};
$debug .= " - we have already received an image with this file size: $file_size - imgid: $$imgid_ref";
${$debug_string_ref} = $debug;
return -3;
}
if ($file) {
$log->debug("processing uploaded file", {file => $file}) if $log->is_debug();
# We may have a "blob" without file name and extension
# extension was initialized to jpg and we will let ImageMagick read it anyway if it's something else.
if ($file =~ /\.($supported_extensions)$/i) {
$extension = lc($1);
$extension eq 'jpeg' and $extension = 'jpg';
}
my $filename = get_string_id_for_lang("no_language", remote_addr() . '_' . $`);
my $current_product_ref = retrieve_product($product_id);
$imgid = ($current_product_ref->{max_imgid} || 0) + 1;
# if for some reason the images directories were not created at product creation (it can happen if the images directory's permission / ownership are incorrect at some point)
# create them
# Create the directories for the product
my $target_image_dir = "$product_www_root/images/products/$path";
ensure_dir_created_or_die($target_image_dir);
my $lock_path = "$target_image_dir/$imgid.lock";
while ((-e $lock_path) or (-e "$target_image_dir/$imgid.jpg")) {
$imgid++;
$lock_path = "$target_image_dir/$imgid.lock";
}
mkdir($lock_path, 0755)
or $log->warn("could not create lock file for the image", {path => $lock_path, error => $!});
local $log->context->{imgid} = $imgid;
$log->debug("new imgid: ", {imgid => $imgid, extension => $extension}) if $log->is_debug();
my $img_orig = "$target_image_dir/$imgid.$extension.orig";
$log->debug("writing the original image", {img_orig => $img_orig}) if $log->is_debug();
open(my $out, ">", $img_orig)
or $log->warn("could not open image path for saving", {path => $img_orig, error => $!});
while (my $chunk = <$file>) {
print $out $chunk;
}
close($out);
# Read the image
my $source = Image::Magick->new;
my $imagemagick_error = $source->Read($img_orig);
if (($imagemagick_error) and ($imagemagick_error =~ /(\d+)/) and ($1 >= 400))
{ # ImageMagick returns a string starting with a number greater than 400 for errors
$log->error("cannot read image",
{path => "$target_image_dir/$imgid.$extension", error => $imagemagick_error});
$debug .= " - could not read image: $imagemagick_error";
${$debug_string_ref} = $debug;
return -5;
}
$source->AutoOrient();
$source->Strip(); #remove orientation data and all other metadata (EXIF)
# remove the transparency when there is an alpha channel (e.g. in PNG files) by adding a white background
if ($source->Get('matte')) {
$log->debug("png file, trying to remove the alpha background") if $log->is_debug();
my $bg = Image::Magick->new;
$bg->Set(size => $source->Get('width') . "x" . $source->Get('height'));
$bg->ReadImage('canvas:white');
$bg->Composite(compose => 'Over', image => $source);
$source = $bg;
}
my $img_jpg = "$target_image_dir/$imgid.jpg";
$source->Set('quality', 95);
$imagemagick_error = $source->Write("jpeg:$img_jpg");
# We also check for the existence of the image file as sometimes ImageMagick does not return an error
# but does not write the file (e.g. conversion from pdf to jpg)
if (($imagemagick_error) or (!-e $img_jpg)) {
$log->error("cannot write image", {path => $img_jpg, error => $imagemagick_error});
$debug .= " - could not write image: $imagemagick_error";
${$debug_string_ref} = $debug;
return -5;
}
# Check that we don't already have the image
my $size_orig = -s $img_orig;
my $size_jpg = -s $img_jpg;
local $log->context->{img_size_orig} = $size_orig;
local $log->context->{img_size_jpg} = $size_jpg;
$debug .= " - size of image file received: $size_orig - saved jpg: $size_jpg";
$log->debug("comparing existing images with size of new image",
{img_orig => $img_orig, size_orig => $size_orig, img_jpg => $img_jpg, size_jpg => $size_jpg})
if $log->is_debug();
for (my $i = 0; $i < $imgid; $i++) {
# We did not store original files sizes in images.sto and original files in [imgid].[extension].orig before July 2020,
# but we stored original PNG files before they were converted to JPG in [imgid].png
# We compare both the sizes of the original files and the converted files
my @existing_images = ("$target_image_dir/$i.jpg");
if (-e "$target_image_dir/$i.$extension.orig") {
push @existing_images, "$target_image_dir/$i.$extension.orig";
}
if (($extension ne "jpg") and (-e "$target_image_dir/$i.$extension")) {
push @existing_images, "$target_image_dir/$i.$extension";
}
foreach my $existing_image (@existing_images) {
my $existing_image_size = -s $existing_image;
foreach my $size ($size_orig, $size_jpg) {
$log->debug(
"comparing image",
{
existing_image_index => $i,
existing_image => $existing_image,
existing_image_size => $existing_image_size
}
) if $log->is_debug();
if ((defined $existing_image_size) and ($existing_image_size == $size)) {
$log->debug(
"image with same size detected",
{
existing_image_index => $i,
existing_image => $existing_image,
existing_image_size => $existing_image_size
}
) if $log->is_debug();
# check the image was stored inside the
# product, it is sometimes missing
# (e.g. during crashes)
my $product_ref = retrieve_product($product_id);
if ( (defined $product_ref)
and (defined $product_ref->{images})
and (exists $product_ref->{images}{$i}))
{
$log->debug("unlinking image",
{imgid => $imgid, file => "$target_image_dir/$imgid.$extension"})
if $log->is_debug();
unlink $img_orig;
unlink $img_jpg;
rmdir("$target_image_dir/$imgid.lock");
${$imgid_ref} = $i;
$debug .= " - we already have an image with this file size: $size - imgid: $i";
${$debug_string_ref} = $debug;
return -3;
}
else {
print STDERR "missing image $i in product.sto, keeping image $imgid\n";
}
}
}
}
}
# Check the image is big enough so that we do not get thumbnails from other sites
if (
(($source->Get('width') < 640) and ($source->Get('height') < 160))
and ( (not defined $options{users_who_can_upload_small_images})
or (not defined $options{users_who_can_upload_small_images}{$user_id}))
)
{
unlink "$target_image_dir/$imgid.$extension";
rmdir("$target_image_dir/$imgid.lock");
$debug .= " - image too small - width: " . $source->Get('width') . " - height: " . $source->Get('height');
${$debug_string_ref} = $debug;
return -4;
}
# Generate resized versions
$new_product_ref->{"images.$imgid.w"} = $source->Get('width');
$new_product_ref->{"images.$imgid.h"} = $source->Get('height');
foreach my $max ($thumb_size, $crop_size) {
my ($w, $h) = ($source->Get('width'), $source->Get('height'));
if ($w > $h) {
if ($w > $max) {
$h = $h * $max / $w;
$w = $max;
}
}
else {
if ($h > $max) {
$w = $w * $max / $h;
$h = $max;
}
}
my $geometry = $w . 'x' . $h;
my $img = $source->Clone();
$img->Resize(geometry => "$geometry^");
$img->Extent(
geometry => "$geometry",
gravity => "center"
);
_set_magickal_options($img, $w);
$imagemagick_error = $img->Write("jpeg:$target_image_dir/$imgid.$max.jpg");
if (($imagemagick_error) and ($imagemagick_error =~ /(\d+)/) and ($1 >= 400))
{ # ImageMagick returns a string starting with a number greater than 400 for errors
$log->warn(
"could not write jpeg",
{
path => "jpeg:$target_image_dir/$imgid.$max.jpg",
error => $imagemagick_error
}