-
-
Notifications
You must be signed in to change notification settings - Fork 216
/
qgismobileapp.qml
3934 lines (3366 loc) · 129 KB
/
qgismobileapp.qml
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/***************************************************************************
qgismobileapp.qml
-------------------
begin : 10.12.2014
copyright : (C) 2014 by Matthias Kuhn
email : matthias (at) opengis.ch
***************************************************************************/
/***************************************************************************
* *
* This program is free software; you can redistribute it and/or modify *
* it under the terms of the GNU General Public License as published by *
* the Free Software Foundation; either version 2 of the License, or *
* (at your option) any later version. *
* *
***************************************************************************/
import QtQuick 2.14
import QtQuick.Controls 2.14
import QtQuick.Controls.Material 2.14
import QtQuick.Effects
import QtQuick.Window 2.14
import QtQml 2.14
import QtSensors 5.14
import QtCore
import org.qgis 1.0
import org.qfield 1.0
import Theme 1.0
ApplicationWindow {
id: mainWindow
objectName: 'mainWindow'
visible: true
flags: Qt.Window | Qt.WindowTitleHint | Qt.WindowSystemMenuHint | (Qt.platform.os === "ios" ? Qt.MaximizeUsingFullscreenGeometryHint : 0) | (Qt.platform.os !== "ios" && Qt.platform.os !== "android" ? Qt.WindowMinMaxButtonsHint | Qt.WindowCloseButtonHint : 0)
Material.theme: Theme.darkTheme ? "Dark" : "Light"
Material.accent: Theme.mainColor
property double sceneTopMargin: platformUtilities.sceneMargins(mainWindow)["top"]
property double sceneBottomMargin: platformUtilities.sceneMargins(mainWindow)["bottom"]
Timer {
id: refreshSceneMargins
running: false
repeat: false
interval: 50
readonly property bool screenIsPortrait: (Screen.primaryOrientation === Qt.PortraitOrientation || Screen.primaryOrientation === Qt.InvertedPortraitOrientation)
onScreenIsPortraitChanged: {
start();
}
onTriggered: {
mainWindow.sceneTopMargin = platformUtilities.sceneMargins(mainWindow)["top"];
mainWindow.sceneBottomMargin = platformUtilities.sceneMargins(mainWindow)["bottom"];
}
}
Settings {
property alias x: mainWindow.x
property alias y: mainWindow.y
property alias width: mainWindow.width
property alias height: mainWindow.height
property int minimumSize: Qt.platform.os !== "ios" && Qt.platform.os !== "android" ? 300 : 50
Component.onCompleted: {
if (Qt.platform.os !== "ios" && Qt.platform.os !== "android") {
width = Math.max(width, minimumSize);
height = Math.max(height, minimumSize);
x = Math.min(x, mainWindow.screen.width - width);
y = Math.min(y, mainWindow.screen.height - height);
}
}
}
FocusStack {
id: focusstack
}
//this keyHandler is because otherwise the back-key is not handled in the mainWindow. Probably this could be solved cuter.
Item {
id: keyHandler
objectName: "keyHandler"
visible: true
focus: true
property int previousVisibilityState: Window.Windowed
Keys.onReleased: event => {
if (event.key === Qt.Key_Back || event.key === Qt.Key_Escape) {
if (featureForm.visible) {
featureForm.hide();
} else if (stateMachine.state === 'measure') {
mainWindow.closeMeasureTool();
} else {
mainWindow.close();
}
event.accepted = true;
} else if (event.key === Qt.Key_F11) {
if (Qt.platform.os !== "android" && Qt.platform.os !== "ios") {
if (mainWindow.visibility !== Window.FullScreen) {
previousVisibilityState = mainWindow.visibility;
mainWindow.visibility = Window.FullScreen;
} else {
mainWindow.visibility = Window.Windowed;
if (previousVisibilityState === Window.Maximized) {
mainWindow.showMaximized();
}
}
}
}
}
Component.onCompleted: focusstack.addFocusTaker(this)
}
//currentRubberband provides the rubberband depending on the current state (digitize or measure)
property Rubberband currentRubberband
property LayerObserver layerObserverAlias: layerObserver
property QgsGpkgFlusher gpkgFlusherAlias: gpkgFlusher
signal closeMeasureTool
signal changeMode(string mode)
Item {
id: stateMachine
property string lastState
states: [
State {
name: "browse"
PropertyChanges {
target: identifyTool
deactivated: false
}
},
State {
name: "digitize"
PropertyChanges {
target: identifyTool
deactivated: false
}
PropertyChanges {
target: mainWindow
currentRubberband: digitizingRubberband
}
},
State {
name: 'measure'
PropertyChanges {
target: identifyTool
deactivated: true
}
PropertyChanges {
target: mainWindow
currentRubberband: measuringTool.measuringRubberband
}
PropertyChanges {
target: featureForm
state: "Hidden"
}
}
]
state: "browse"
}
onChangeMode: mode => {
if (stateMachine.state === mode)
return;
stateMachine.lastState = stateMachine.state;
stateMachine.state = mode;
switch (stateMachine.state) {
case 'browse':
projectInfo.stateMode = mode;
platformUtilities.setHandleVolumeKeys(false);
displayToast(qsTr('You are now in browse mode'));
break;
case 'digitize':
projectInfo.stateMode = mode;
platformUtilities.setHandleVolumeKeys(qfieldSettings.digitizingVolumeKeys);
dashBoard.ensureEditableLayerSelected();
if (dashBoard.activeLayer) {
displayToast(qsTr('You are now in digitize mode on layer %1').arg(dashBoard.activeLayer.name));
} else {
displayToast(qsTr('You are now in digitize mode'));
}
break;
case 'measure':
platformUtilities.setHandleVolumeKeys(qfieldSettings.digitizingVolumeKeys);
informationDrawer.elevationProfile.populateLayersFromProject();
displayToast(qsTr('You are now in measure mode'));
break;
}
}
onCloseMeasureTool: {
overlayFeatureFormDrawer.close();
changeMode(stateMachine.lastState);
}
/**
* The position source to access GNSS devices
*/
Positioning {
id: positionSource
objectName: "positionSource"
deviceId: positioningSettings.positioningDevice
property bool currentness: false
property alias destinationCrs: positionSource.coordinateTransformer.destinationCrs
property real bearingTrueNorth: 0.0
coordinateTransformer: CoordinateTransformer {
destinationCrs: mapCanvas.mapSettings.destinationCrs
transformContext: qgisProject ? qgisProject.transformContext : CoordinateReferenceSystemUtils.emptyTransformContext()
deltaZ: 0
skipAltitudeTransformation: positioningSettings.skipAltitudeCorrection
verticalGrid: positioningSettings.verticalGrid
}
elevationCorrectionMode: positioningSettings.elevationCorrectionMode
antennaHeight: positioningSettings.antennaHeightActivated ? positioningSettings.antennaHeight : 0
logging: positioningSettings.logging
onProjectedPositionChanged: {
if (active) {
bearingTrueNorth = PositioningUtils.bearingTrueNorth(positionSource.projectedPosition, mapCanvas.mapSettings.destinationCrs);
if (gnssButton.followActive) {
gnssButton.followLocation(false);
}
}
}
onOrientationChanged: {
if (active && gnssButton.followOrientationActive) {
gnssButton.followOrientation();
}
}
}
PositioningSettings {
id: positioningSettings
onPositioningActivatedChanged: {
if (positioningActivated) {
displayToast(qsTr("Activating positioning service"));
positionSource.active = true;
} else {
positionSource.active = false;
}
}
}
Connections {
target: positionSource.device
function onLastErrorChanged() {
displayToast(qsTr('Positioning device error: %1').arg(positionSource.device.lastError), 'error');
}
}
Timer {
id: positionTimer
property bool geocoderLocatorFiltersChecked: false
interval: 2500
repeat: true
running: positionSource.active
triggeredOnStart: true
onTriggered: {
if (positionSource.positionInformation) {
positionSource.currentness = ((Date.now() - positionSource.positionInformation.utcDateTime.getTime()) / 1000) < 30;
if (!geocoderLocatorFiltersChecked && positionSource.valid) {
locatorItem.locatorFiltersModel.setGeocoderLocatorFiltersDefaulByPosition(positionSource.positionInformation);
geocoderLocatorFiltersChecked = true;
}
}
}
}
Item {
id: mapCanvas
objectName: "mapCanvas"
clip: true
DragHandler {
id: freehandHandler
property bool isDigitizing: false
enabled: freehandButton.visible && freehandButton.freehandDigitizing && !digitizingToolbar.rubberbandModel.frozen && (!featureForm.visible || digitizingToolbar.geometryRequested)
acceptedDevices: !qfieldSettings.mouseAsTouchScreen ? PointerDevice.Stylus | PointerDevice.Mouse : PointerDevice.Stylus
grabPermissions: PointerHandler.CanTakeOverFromHandlersOfSameType | PointerHandler.CanTakeOverFromHandlersOfDifferentType | PointerHandler.ApprovesTakeOverByAnything
onActiveChanged: {
if (active) {
geometryEditorsToolbar.canvasFreehandBegin();
} else {
geometryEditorsToolbar.canvasFreehandEnd();
var screenLocation = centroid.position;
var screenFraction = settings.value("/QField/Digitizing/FreehandRecenterScreenFraction", 5);
var threshold = Math.min(mainWindow.width, mainWindow.height) / screenFraction;
if (screenLocation.x < threshold || screenLocation.x > mainWindow.width - threshold || screenLocation.y < threshold || screenLocation.y > mainWindow.height - threshold) {
mapCanvas.mapSettings.setCenter(mapCanvas.mapSettings.screenToCoordinate(screenLocation));
}
}
}
onCentroidChanged: {
if (active) {
if (centroid.position !== Qt.point(0, 0)) {
coordinateLocator.sourceLocation = centroid.position;
if (!geometryEditorsToolbar.canvasClicked(centroid.position)) {
digitizingToolbar.addVertex();
}
}
}
}
}
HoverHandler {
id: hoverHandler
enabled: !(positionSource.active && positioningSettings.positioningCoordinateLock) && (!digitizingToolbar.rubberbandModel || !digitizingToolbar.rubberbandModel.frozen)
acceptedDevices: !qfieldSettings.mouseAsTouchScreen ? PointerDevice.Stylus | PointerDevice.Mouse : PointerDevice.Stylus
grabPermissions: PointerHandler.TakeOverForbidden
property bool hasBeenHovered: false
property bool skipHover: false
function pointInItem(point, item) {
var itemCoordinates = item.mapToItem(mainWindow.contentItem, 0, 0);
return point.position.x >= itemCoordinates.x && point.position.x <= itemCoordinates.x + item.width && point.position.y >= itemCoordinates.y && point.position.y <= itemCoordinates.y + item.height;
}
onPointChanged: {
if (skipHover || !mapCanvasMap.hovered) {
return;
}
// when hovering various toolbars, reset coordinate locator position for nicer UX
if (!freehandHandler.active && (pointInItem(point, digitizingToolbar) || pointInItem(point, elevationProfileButton))) {
coordinateLocator.sourceLocation = mapCanvas.mapSettings.coordinateToScreen(digitizingToolbar.rubberbandModel.lastCoordinate);
} else if (!freehandHandler.active && pointInItem(point, geometryEditorsToolbar)) {
coordinateLocator.sourceLocation = mapCanvas.mapSettings.coordinateToScreen(geometryEditorsToolbar.editorRubberbandModel.lastCoordinate);
} else if (!freehandHandler.active) {
// after a click, it seems that the position is sent once at 0,0 => weird)
if (point.position !== Qt.point(0, 0)) {
coordinateLocator.sourceLocation = point.position;
}
}
}
onActiveChanged: {
if (!active) {
coordinateLocator.sourceLocation = undefined;
}
}
onHoveredChanged: {
if (mapCanvasMap.pinched) {
return;
}
if (skipHover) {
if (!hovered) {
mapCanvasMap.hovered = false;
dummyHoverTimer.restart();
}
return;
}
mapCanvasMap.hovered = hovered;
if (hovered) {
hasBeenHovered = true;
} else {
if (currentRubberband && currentRubberband.model.vertexCount > 1) {
coordinateLocator.sourceLocation = mapCanvas.mapSettings.coordinateToScreen(currentRubberband.model.lastCoordinate);
} else if (geometryEditorsToolbar.editorRubberbandModel && geometryEditorsToolbar.editorRubberbandModel.vertexCount > 1) {
coordinateLocator.sourceLocation = mapCanvas.mapSettings.coordinateToScreen(geometryEditorsToolbar.editorRubberbandModel.lastCoordinate);
} else {
coordinateLocator.sourceLocation = undefined;
}
}
}
}
/* The second hover handler is a workaround what appears to be an issue with
* Qt whereas synthesized mouse event would trigger the first HoverHandler even though
* PointerDevice.TouchScreen was explicitly taken out of the accepted devices.
* The timer is needed as adding additional fingers onto a device re-triggers hovered
* changes in unpredictable order.
*/
Timer {
id: dummyHoverTimer
interval: 750
repeat: false
onTriggered: {
hoverHandler.skipHover = false;
}
}
HoverHandler {
id: dummyHoverHandler
enabled: !qfieldSettings.mouseAsTouchScreen && !(positionSource.active && positioningSettings.positioningCoordinateLock)
acceptedDevices: PointerDevice.TouchScreen
grabPermissions: PointerHandler.TakeOverForbidden
onHoveredChanged: {
if (hovered) {
dummyHoverTimer.stop();
hoverHandler.skipHover = true;
// Unfortunately, Qt fails to set the hovered property to false when stylus leaves proximity
// of the screen, we've got to compensate for that
mapCanvasMap.hovered = false;
if (!qfieldSettings.fingerTapDigitizing) {
coordinateLocator.sourceLocation = undefined;
}
}
}
}
/* Initialize a MapSettings object. This will contain information about
* the current canvas extent. It is shared between the base map and all
* map canvas items and is used to transform map coordinates to pixel
* coordinates.
* It may change any time and items that hold a reference to this property
* are responsible to handle this properly.
*/
property MapSettings mapSettings: mapCanvasMap.mapSettings
/* Placement and size. Share right anchor with featureForm */
anchors.top: parent.top
anchors.left: parent.left
anchors.right: parent.right
anchors.bottom: parent.bottom
Rectangle {
id: mapCanvasBackground
anchors.fill: parent
color: mapCanvas.mapSettings.backgroundColor
}
/* The map canvas */
MapCanvas {
id: mapCanvasMap
property bool isEnabled: !dashBoard.opened && !welcomeScreen.visible && !qfieldSettings.visible && !qfieldLocalDataPickerScreen.visible && !qfieldCloudScreen.visible && !qfieldCloudPopup.visible && !codeReader.visible && !sketcher.visible && !overlayFeatureFormDrawer.visible
interactive: isEnabled && !screenLocker.enabled
isMapRotationEnabled: qfieldSettings.enableMapRotation
incrementalRendering: true
quality: qfieldSettings.quality
forceDeferredLayersRepaint: trackings.count > 0
freehandDigitizing: freehandButton.freehandDigitizing && freehandHandler.active
rightMargin: featureForm.x > 0 ? featureForm.width : 0
bottomMargin: informationDrawer.height > mainWindow.sceneBottomMargin ? informationDrawer.height : 0
anchors.fill: parent
function pointInItem(point, item) {
var itemCoordinates = item.mapToItem(mainWindow.contentItem, 0, 0);
return point.x >= itemCoordinates.x && point.x <= itemCoordinates.x + item.width && point.y >= itemCoordinates.y && point.y <= itemCoordinates.y + item.height;
}
onClicked: (point, type) => {
if (type === "stylus" && (overlayFeatureFormDrawer.opened || (featureForm.visible && pointInItem(point, featureForm)))) {
return;
}
if (!digitizingToolbar.geometryRequested && featureForm.state == "FeatureFormEdit") {
return;
}
if (locatorItem.state == "on") {
locatorItem.state = "off";
return;
}
if (type === "stylus") {
if (pointInItem(point, digitizingToolbar) || pointInItem(point, zoomToolbar) || pointInItem(point, mainToolbar) || pointInItem(point, mainMenuBar) || pointInItem(point, geometryEditorsToolbar) || pointInItem(point, locationToolbar) || pointInItem(point, digitizingToolbarContainer) || pointInItem(point, locatorItem)) {
return;
}
// Check if geometry editor is taking over
const positionLocked = positionSource.active && positioningSettings.positioningCoordinateLock;
if (geometryEditorsToolbar.stateVisible) {
if (!positionLocked) {
geometryEditorsToolbar.canvasClicked(point, type);
}
return;
}
if ((stateMachine.state === "digitize" && digitizingFeature.currentLayer) || stateMachine.state === "measure") {
if (!positionLocked && (!featureForm.visible || digitizingToolbar.geometryRequested)) {
if (Number(currentRubberband.model.geometryType) === Qgis.GeometryType.Point || Number(currentRubberband.model.geometryType) === Qgis.GeometryType.Null) {
digitizingToolbar.confirm();
} else {
digitizingToolbar.addVertex();
}
}
} else {
if (!featureForm.canvasOperationRequested && !overlayFeatureFormDrawer.visible && featureForm.state !== "FeatureFormEdit") {
identifyTool.isMenuRequest = false;
identifyTool.identify(point);
}
}
}
}
onConfirmedClicked: point => {
// Check if geometry editor is taking over
const positionLocked = positionSource.active && positioningSettings.positioningCoordinateLock;
if (geometryEditorsToolbar.stateVisible) {
if (!positionLocked) {
geometryEditorsToolbar.canvasClicked(point, '');
}
return;
}
if (qfieldSettings.fingerTapDigitizing && ((stateMachine.state === "digitize" && digitizingFeature.currentLayer) || stateMachine.state === "measure")) {
if (!positionLocked && (!featureForm.visible || digitizingToolbar.geometryRequested)) {
coordinateLocator.sourceLocation = point;
}
} else if (!featureForm.canvasOperationRequested && !overlayFeatureFormDrawer.visible && featureForm.state !== "FeatureFormEdit") {
identifyTool.isMenuRequest = false;
identifyTool.identify(point);
}
}
onLongPressed: (point, type) => {
if (type === "stylus") {
if (overlayFeatureFormDrawer.opened || (featureForm.visible && pointInItem(point, featureForm))) {
return;
}
// Check if geometry editor is taking over
if (geometryEditorsToolbar.canvasLongPressed(point, type)) {
return;
}
if (stateMachine.state === "digitize" && dashBoard.activeLayer) {
// the sourceLocation test checks if a (stylus) hover is active
if ((Number(currentRubberband.model.geometryType) === Qgis.GeometryType.Line && currentRubberband.model.vertexCount >= 2) || (Number(currentRubberband.model.geometryType) === Qgis.GeometryType.Polygon && currentRubberband.model.vertexCount >= 2)) {
digitizingToolbar.addVertex();
// When it's released, it will normally cause a release event to close the attribute form.
// We get around this by temporarily switching the closePolicy.
overlayFeatureFormDrawer.closePolicy = Popup.CloseOnEscape;
digitizingToolbar.confirm();
return;
}
}
// do not use else, as if it was catch it has return before
identifyTool.isMenuRequest = false;
identifyTool.identify(point);
} else {
// Check if geometry editor is taking over
if (geometryEditorsToolbar.canvasLongPressed(point)) {
return;
}
canvasMenu.point = mapCanvas.mapSettings.screenToCoordinate(point);
canvasMenu.popup(point.x, point.y);
identifyTool.isMenuRequest = true;
identifyTool.identify(point);
}
}
onRightClicked: (point, type) => {
canvasMenu.point = mapCanvas.mapSettings.screenToCoordinate(point);
canvasMenu.popup(point.x, point.y);
identifyTool.isMenuRequest = true;
identifyTool.identify(point);
}
onLongPressReleased: type => {
if (type === "stylus") {
// The user has released the long press. We can re-enable the default close behavior for the feature form.
// The next press will be intentional to close the form.
overlayFeatureFormDrawer.closePolicy = Popup.CloseOnEscape | Popup.CloseOnPressOutside;
}
}
}
/**************************************************
* Overlays, including:
* - Coordinate Locator
* - Location Marker
* - Identify Highlight
* - Digitizing Rubberband
**************************************************/
/** The identify tool **/
IdentifyTool {
id: identifyTool
property bool isMenuRequest: false
mapSettings: mapCanvas.mapSettings
model: isMenuRequest ? canvasMenuFeatureListModel : featureForm.model
searchRadiusMm: 3
}
/** A rubberband for measuring **/
MeasuringTool {
id: measuringTool
visible: stateMachine.state === 'measure'
anchors.fill: parent
measuringRubberband.model.currentCoordinate: coordinateLocator.currentCoordinate
measuringRubberband.mapSettings: mapCanvas.mapSettings
}
/** Tracking sessions **/
Repeater {
id: trackings
model: trackingModel
onCountChanged: {
if (count > 0) {
// Start positioning if not yet active
if (!positionSource.active) {
positioningSettings.positioningActivated = true;
}
}
}
TrackingSession {
}
}
/** A rubberband for ditizing **/
Rubberband {
id: digitizingRubberband
mapSettings: mapCanvas.mapSettings
model: RubberbandModel {
frozen: false
currentCoordinate: coordinateLocator.currentCoordinate
measureValue: {
if (coordinateLocator.positionLocked) {
switch (positioningSettings.digitizingMeasureType) {
case Tracker.Timestamp:
return coordinateLocator.positionInformation.utcDateTime.getTime();
case Tracker.GroundSpeed:
return coordinateLocator.positionInformation.speed;
case Tracker.Bearing:
return coordinateLocator.positionInformation.direction;
case Tracker.HorizontalAccuracy:
return coordinateLocator.positionInformation.hacc;
case Tracker.VerticalAccuracy:
return coordinateLocator.positionInformation.vacc;
case Tracker.PDOP:
return coordinateLocator.positionInformation.pdop;
case Tracker.HDOP:
return coordinateLocator.positionInformation.hdop;
case Tracker.VDOP:
return coordinateLocator.positionInformation.vdop;
}
} else {
return Number.NaN;
}
}
vectorLayer: digitizingToolbar.geometryRequested ? digitizingToolbar.geometryRequestedLayer : dashBoard.activeLayer
crs: mapCanvas.mapSettings.destinationCrs
}
visible: stateMachine.state === "digitize"
}
GeometryRenderer {
id: geometryEditorRenderer
}
/** A rubberband for the different geometry editors **/
Rubberband {
id: geometryEditorsRubberband
color: '#96000000'
mapSettings: mapCanvas.mapSettings
model: RubberbandModel {
frozen: false
currentCoordinate: coordinateLocator.currentCoordinate
crs: mapCanvas.mapSettings.destinationCrs
geometryType: Qgis.GeometryType.Line
}
}
BookmarkHighlight {
id: bookmarkHighlight
mapSettings: mapCanvas.mapSettings
}
Navigation {
id: navigation
mapSettings: mapCanvas.mapSettings
location: positionSource.active ? positionSource.projectedPosition : GeometryUtils.emptyPoint()
proximityAlarm: positioningSettings.preciseViewProximityAlarm && informationDrawer.positioningPreciseView.visible && informationDrawer.positioningPreciseView.hasAcceptableAccuracy && !informationDrawer.positioningPreciseView.hasAlarmSnoozed
proximityAlarmThreshold: positioningSettings.preciseViewPrecision
}
NavigationHighlight {
id: navigationHighlight
navigation: navigation
}
LinePolygon {
id: elevationProfileHighlight
visible: informationDrawer.elevationProfile.visible
mapSettings: mapCanvas.mapSettings
geometry: QgsGeometryWrapper {
qgsGeometry: informationDrawer.elevationProfile.profileCurve
crs: informationDrawer.elevationProfile.crs
}
color: "#FFFFFF"
lineWidth: 4
}
/** A coordinate locator for digitizing **/
CoordinateLocator {
id: coordinateLocator
anchors.fill: parent
anchors.bottomMargin: informationDrawer.height > mainWindow.sceneBottomMargin ? informationDrawer.height : 0
visible: stateMachine.state === "digitize" || stateMachine.state === 'measure'
highlightColor: digitizingToolbar.isDigitizing ? currentRubberband.color : "#CFD8DC"
mapSettings: mapCanvas.mapSettings
currentLayer: dashBoard.activeLayer
positionInformation: positionSource.positionInformation
positionLocked: positionSource.active && positioningSettings.positioningCoordinateLock
rubberbandModel: geometryEditorsToolbar.stateVisible ? geometryEditorsToolbar.editorRubberbandModel : digitizingToolbar.rubberbandModel
averagedPosition: positionSource.averagedPosition
averagedPositionCount: positionSource.averagedPositionCount
overrideLocation: positionLocked ? positionSource.projectedPosition : undefined
}
/* Location marker reflecting the current GNSS position */
LocationMarker {
id: locationMarker
visible: positionSource.active && positionSource.positionInformation && positionSource.positionInformation.latitudeValid
mapSettings: mapCanvas.mapSettings
location: positionSource.projectedPosition
accuracy: positionSource.projectedHorizontalAccuracy
direction: positionSource.positionInformation && positionSource.positionInformation.directionValid ? positionSource.positionInformation.direction : -1
speed: positionSource.positionInformation && positionSource.positionInformation.speedValid ? positionSource.positionInformation.speed : -1
orientation: !isNaN(positionSource.orientation) ? positionSource.orientation + positionSource.bearingTrueNorth < 0 ? 360 + positionSource.orientation + positionSource.bearingTrueNorth : positionSource.orientation + positionSource.bearingTrueNorth : -1
}
/* Rubberband for vertices */
Item {
// highlighting geometry (point, line, surface)
Rubberband {
id: editingRubberband
vertexModel: geometryEditingVertexModel
mapSettings: mapCanvas.mapSettings
}
// highlighting vertices
VertexRubberband {
id: vertexRubberband
model: geometryEditingVertexModel
mapSettings: mapCanvas.mapSettings
}
}
/* Highlight the currently selected item on the feature list */
FeatureListSelectionHighlight {
id: featureListHighlight
visible: !moveFeaturesToolbar.moveFeaturesRequested
selectionModel: featureForm.selection
mapSettings: mapCanvas.mapSettings
color: "yellow"
focusedColor: "#ff7777"
selectedColor: Theme.mainColor
width: 5
}
/* Highlight the currently selected item being moved */
FeatureListSelectionHighlight {
id: moveFeaturesHighlight
visible: moveFeaturesToolbar.moveFeaturesRequested
showSelectedOnly: true
selectionModel: featureForm.selection
mapSettings: mapCanvas.mapSettings
// take rotation into account
property double rotationRadians: -mapSettings.rotation * Math.PI / 180
translateX: mapToScreenTranslateX.screenDistance * Math.cos(rotationRadians) - mapToScreenTranslateY.screenDistance * Math.sin(rotationRadians)
translateY: mapToScreenTranslateY.screenDistance * Math.cos(rotationRadians) + mapToScreenTranslateX.screenDistance * Math.sin(rotationRadians)
color: "yellow"
focusedColor: "#ff7777"
selectedColor: Theme.mainColor
width: 5
}
/* Highlight features identified by locator or relation editor widgets */
GeometryHighlighter {
id: locatorHighlightItem
}
MapToScreen {
id: mapToScreenTranslateX
mapSettings: mapCanvas.mapSettings
mapDistance: moveFeaturesToolbar.moveFeaturesRequested ? mapCanvas.mapSettings.center.x - moveFeaturesToolbar.startPoint.x : 0
}
MapToScreen {
id: mapToScreenTranslateY
mapSettings: mapCanvas.mapSettings
mapDistance: moveFeaturesToolbar.moveFeaturesRequested ? mapCanvas.mapSettings.center.y - moveFeaturesToolbar.startPoint.y : 0
}
ProcessingAlgorithmPreview {
id: processingAlgorithmPreview
algorithm: featureForm.algorithm
mapSettings: mapCanvas.mapSettings
}
}
Geofencer {
id: geofencer
position: positionSource.projectedPosition
positionCrs: mapCanvas.mapSettings.destinationCrs
readonly property int longVibration: 1000
readonly property int shortVibration: 500
onIsWithinChanged: {
if (behavior == Geofencer.AlertWhenInsideGeofencedArea && geofencer.isWithin) {
platformUtilities.vibrate(longVibration);
displayToast(qsTr("Position has trespassed into ‘%1’").arg(isWithinAreaName), 'error');
} else if (behavior == Geofencer.AlertWhenOutsideGeofencedArea && !geofencer.isWithin) {
platformUtilities.vibrate(longVibration);
displayToast(qsTr("Position outside areas after leaving ‘%1’").arg(lastWithinAreaName), 'error');
} else if (behavior == Geofencer.InformWhenEnteringLeavingGeofencedArea) {
if (isWithin) {
platformUtilities.vibrate(shortVibration);
displayToast(qsTr("Position entered into ‘%1’").arg(isWithinAreaName));
} else if (lastWithinAreaName != '') {
platformUtilities.vibrate(shortVibration);
displayToast(qsTr("Position left from ‘%1’").arg(lastWithinAreaName));
}
}
}
}
MultiEffect {
id: geofencerFeedback
anchors.fill: geofencerFeedbackSource
source: geofencerFeedbackSource
visible: true
blurEnabled: true
blurMax: 64
blur: 2.0
opacity: 0
SequentialAnimation {
id: geofencerFeedbackAnimation
running: geofencer.isAlerting
loops: Animation.Infinite
onRunningChanged: {
if (!running) {
geofencerFeedback.opacity = 0;
}
}
OpacityAnimator {
target: geofencerFeedback
from: 0
to: 0.75
duration: 1000
}
OpacityAnimator {
target: geofencerFeedback
from: 0.75
to: 0
duration: 1000
}
}
}
Rectangle {
id: geofencerFeedbackSource
width: Math.min(250, mainWindow.width / 2)
height: width
radius: width / 2
visible: false
x: parent.width - width / 2
y: locationToolbar.y + gnssButton.y + (gnssButton.height / 2) - height / 2
color: Theme.errorColor
}
InformationDrawer {
id: informationDrawer
navigation: navigation
positionSource: positionSource
positioningSettings: positioningSettings
}
/**************************************************
* Map Canvas Overlays
* - Decorations
* - Scale Bar
* - UI elements such as QfToolButtons
**************************************************/
Item {
id: mapCanvasOverlays
anchors.fill: mapCanvas
anchors.bottomMargin: informationDrawer.height
Rectangle {
id: titleDecorationBackground
visible: titleDecoration.text != ''
anchors.left: parent.left
anchors.leftMargin: 56
anchors.top: parent.top
anchors.topMargin: mainWindow.sceneTopMargin + 4
width: parent.width - anchors.leftMargin * 2
height: 48
radius: 4
color: '#55000000'
Text {
id: titleDecoration
width: parent.width - 4
height: parent.height
leftPadding: 2
rightPadding: 2
horizontalAlignment: Text.AlignHCenter
verticalAlignment: Text.AlignVCenter
wrapMode: Text.WordWrap
elide: Text.ElideRight
font: Theme.strongFont
fontSizeMode: Text.Fit
text: ''
}
}
Rectangle {
id: copyrightDecorationBackground
visible: copyrightDecoration.text != ''
anchors.left: parent.left
anchors.leftMargin: 56
anchors.bottom: parent.bottom
anchors.bottomMargin: 56
width: parent.width - anchors.leftMargin * 2
height: visible ? Math.min(copyrightDecoration.height, 48) : 0
radius: 4
clip: true
color: '#55000000'
Text {
id: copyrightDecoration
anchors.bottom: parent.bottom
width: parent.width - 4
leftPadding: 2
rightPadding: 2
horizontalAlignment: Text.AlignHCenter
verticalAlignment: Text.AlignBottom
wrapMode: Text.WordWrap
elide: Text.ElideRight
font: Theme.tinyFont
text: ''
}
}
ParametizedImage {
id: imageDecoration
visible: source != ''
anchors.left: parent.left
anchors.leftMargin: 56
anchors.bottom: copyrightDecorationBackground.top