generated from opensafely/research-template
-
Notifications
You must be signed in to change notification settings - Fork 0
/
621_part2_analyses_option1_table2b_rateratios.do
180 lines (162 loc) · 6.4 KB
/
621_part2_analyses_option1_table2b_rateratios.do
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
local mypath="`c(pwd)'/analysis/"
do `mypath'/000_filepaths.do
**// Outcome rates and rate ratios
**//////////////////////////////////////////////
use $outdir/input_part2_clean.dta, clear
drop if group==4
local grouplabel1="COVID-19 with diabetes"
local grouplabel2="COVID-19 without diabetes"
local grouplabel3="Pneumonia with diabetes"
gen expos=(group==1)
set more off
tempname rates
postfile `rates' outindex groupindex str30(outcome) str30(group) person_time numevents rate rate_lo rate_hi ///
rateratio rateratio_lo rateratio_hi ///
adj_rateratio adj_rateratio_lo adj_rateratio_hi ///
fulladj_rateratio fulladj_rateratio_lo fulladj_rateratio_hi ///
ipw_rateratio ipw_rateratio_lo ipw_rateratio_hi ///
sipw_rateratio sipw_rateratio_lo sipw_rateratio_hi ///
using $resultsdir/part2_option1_table2b_rateratios.dta, replace
**// Loop over outcomes
local outindex=0
foreach outcome in "stroke_thrombotic" "stroke_haemorrhagic" "stroke_tia" "stroke_any" "mi" "dvt_any" "pe_any" "hf" "any_cvd" "aki_any" "liver" ///
"anxiety" "depression" "psychosis" "antidepressant" "anxiolytic" "antipsychotic" "mood_stabiliser" "sleep_insomnia" "sleep_hypersomnia" "sleep_apnoea" "fatigue" "death" {
local outindex=`outindex'+1
gen myend=(min(date_`outcome', date_censor)-date_patient_index)/(365.25/12)
gen ln_myend=ln(myend)
gen myselect=(myend>0)
gen delta=(date_`outcome'==min(date_`outcome', date_censor))
capture stset myend, f(delta) id(patient_id)
**// Loop over exposure groups
capture stptime if group==1 & myselect==1, title(person-months) per(10000)
if _rc==0 {
post `rates' (`outindex') (1) ("`outcome'") ("`grouplabel1'") (`r(ptime)') (`r(failures)') (`r(rate)') (`r(lb)') (`r(ub)') (.) (.) (.) (.) (.) (.) (.) (.) (.) (.) (.) (.) (.) (.) (.)
}
if _rc!=0 {
post `rates' (`outindex') (1) ("`outcome'") ("`grouplabel1'") (.) (.) (.) (.) (.) (.) (.) (.) (.) (.) (.) (.) (.) (.) (.) (.) (.) (.) (.) (.)
}
forvalues k=2(1)2 {
replace myselect=(myend>0)
capture stptime if group==`k' & myselect==1, title(person-months) per(10000)
if _rc==0 {
local person_time=r(ptime)
local numevents=r(failures)
local rate=r(rate)
local rate_lo=r(lb)
local rate_hi=r(ub)
}
if _rc!=0 {
local person_time=.
local numevents=.
local rate=.
local rate_lo=.
local rate_hi=.
}
**// Loop over model specifications (comparing group 1 and group k)
forvalues m=1(1)5 {
**// Rate ratio
if `m'==1 {
capture nbreg delta expos if (group==1 | group==`k') & myselect==1, offset(ln_myend) nonrtolerance
}
**// Age/sex adjusted rate ratio
if `m'==2 {
capture nbreg delta expos i.cat_sex i.cat_age if (group==1 | group==`k') & myselect==1, offset(ln_myend) vce(robust) nonrtolerance
}
**// Fully adjusted rate ratio
if `m'==3 {
capture nbreg delta expos i.cat_sex i.cat_age i.cat_ethnic i.cat_imd i.cat_hist_cvd i.cat_hist_renal i.cat_smoking i.cat_alcohol i.cat_bmi ///
if (group==1 | group==`k') & myselect==1, offset(ln_myend) vce(robust) nonrtolerance
}
**// IPW rate ratio
if `m'==4 {
capture logit expos i.cat_sex i.cat_age i.cat_ethnic i.cat_imd i.cat_hist_cvd i.cat_hist_renal i.cat_smoking i.cat_alcohol i.cat_bmi if (group==1 | group==`k') & myselect==1
if _rc==0 {
predict propensity
gen ipw=(expos/propensity)+((1-expos)/(1-propensity))
}
capture nbreg delta expos if (group==1 | group==`k') & myselect==1 [pweight=ipw], offset(ln_myend) vce(robust) nonrtolerance
}
**// Trimmed and standardised IPW rate ratios
if `m'==5 {
capture describe propensity
if _rc==0 {
replace myselect=0 if propensity<0.1 | propensity>0.9
count if group==1 & myselect==1
local count_expos=r(N)
count if (group==1 | group==`k') & myselect==1
local count_denom=r(N)
local myp=`count_expos'/`count_denom'
gen sipw=(expos*`myp'/propensity)+(((1-expos)*(1-`myp'))/(1-propensity))
}
capture nbreg delta expos if (group==1 | group==`k') & myselect==1 [pweight=sipw], offset(ln_myend) vce(robust) nonrtolerance
}
if _rc==0 {
matrix M1=e(b)
matrix M2=e(V)
local rateratio`m'=exp(M1[1,1])
local rateratio`m'_lo=exp(M1[1,1]-1.96*M2[1,1]^0.5)
local rateratio`m'_hi=exp(M1[1,1]+1.96*M2[1,1]^0.5)
}
if _rc!=0 {
local rateratio`m'=.
local rateratio`m'_lo=.
local rateratio`m'_hi=.
}
}
post `rates' (`outindex') (`k') ("`outcome'") ("`grouplabel`k''") (`person_time') (`numevents') (`rate') (`rate_lo') (`rate_hi') ///
(`rateratio1') (`rateratio1_lo') (`rateratio1_hi') ///
(`rateratio2') (`rateratio2_lo') (`rateratio2_hi') ///
(`rateratio3') (`rateratio3_lo') (`rateratio3_hi') ///
(`rateratio4') (`rateratio4_lo') (`rateratio4_hi') ///
(`rateratio5') (`rateratio5_lo') (`rateratio5_hi')
foreach myvar in propensity ipw sipw {
capture drop `myvar'
}
}
foreach myvar in myselect myend ln_myend delta _st _d _t _t0 {
capture drop `myvar'
}
}
postclose `rates'
use $resultsdir/part2_option1_table2b_rateratios.dta, clear
**// Labelling
gen type=""
order type, before(outcome)
do `mypath'/003_outlab.do
do `mypath'/004_typelab.do
**// Tidy
sort outindex groupindex
gen temp1=1 if type==type[_n-1]
replace type="" if temp1==1
gen temp2=1 if outcome==outcome[_n-1]
replace outcome="" if (temp2==1 | lower(outcome)=="death")
drop outindex groupindex temp1 temp2
describe type-group, varlist
foreach myvar in `r(varlist)' {
gen str=strlen(`myvar')
summ str
format `myvar' %-`r(max)'s
drop str
}
format person_time %12.1fc
format numevents %12.0fc
**// Format rates
format rate rate_lo rate_hi %12.1fc
tostring rate, gen(temp1) force usedisplayformat
tostring rate_lo, gen(temp2) force usedisplayformat
tostring rate_hi, gen(temp3) force usedisplayformat
gen rate_ci=temp1+" ("+temp2+", "+temp3+")"
drop rate rate_lo rate_hi temp*
rename rate_ci rate
**// Format rate ratios
foreach myvar in "rateratio" "adj_rateratio" "fulladj_rateratio" "ipw_rateratio" "sipw_rateratio" {
format `myvar' `myvar'_lo `myvar'_hi %12.2fc
tostring `myvar', gen(temp1) force usedisplayformat
tostring `myvar'_lo, gen(temp2) force usedisplayformat
tostring `myvar'_hi, gen(temp3) force usedisplayformat
gen `myvar'_ci=temp1+" ("+temp2+", "+temp3+")"
drop `myvar' `myvar'_lo `myvar'_hi temp*
rename `myvar'_ci `myvar'
}
do `mypath'/005_table_edit.do
save $resultsdir/part2_option1_table2b_rateratios.dta, replace