Add simple input driver interface, support 3D Mouse devices

.gitignore

@@ -38,6 +38,10 @@ testdata/scad/misc/use-tests.scad
 /*.h
 /*.dump
 /*.pl
+/lexer_lex.cpp
+/parser_yacc.cpp
+/openscad_adaptor.cpp
+/openscad_interface.cpp
 /OpenSCAD.app
 /openscad.appdata.xml
 /openscad.pro.user

CMakeLists.txt

@@ -132,6 +132,17 @@ if(NOT HEADLESS)
   message(STATUS "QScintilla: ${QT5QSCINTILLA_VERSION_STRING}")
   add_definitions(-DUSE_SCINTILLA_EDITOR)
   add_definitions(-DENABLE_MDI)
+
+  find_package(Qt5DBus QUIET)
+  if (Qt5DBus_FOUND)
+    message(STATUS "DBus input driver enabled")
+    add_definitions(-DENABLE_DBUS)
+    set(INPUT_DRIVER_DBUS_SOURCES src/input/DBusInputDriver.cc)
+    qt5_add_dbus_interface(INPUT_DRIVER_DBUS_SOURCES org.openscad.OpenSCAD.xml openscad_interface)
+    qt5_add_dbus_adaptor(INPUT_DRIVER_DBUS_SOURCES org.openscad.OpenSCAD.xml input/DBusInputDriver.h DBusInputDriver openscad_adaptor)
+  else()
+    message(STATUS "DBus input driver disabled as the QtDBus module could not be found.")
+  endif()
 
 #  add_definitions(${Qt5Widgets_DEFINITIONS})
 #  add_definitions(${Qt5OpenGL_DEFINITIONS})
@@ -358,12 +369,16 @@ set(OFFSCREEN_SOURCES
   src/render.cc
   src/OpenCSGRenderer.cc)
 
+set(INPUT_DRIVER_SOURCES
+  ${INPUT_DRIVER_DBUS_SOURCES})
+
 set(GUI_SOURCES
   src/mainwin.cc
   src/OpenSCADApp.cc
   src/EventFilter.h
   src/WindowManager.cc
   src/Preferences.cc
+  src/SettingsWriter.cc
   src/FontListDialog.cc
   src/FontListTableView.cc
   src/LibraryInfoDialog.cc
@@ -396,6 +411,13 @@ set(GUI_SOURCES
   src/parameter/parametertext.cpp
   src/parameter/parametervector.cpp
   src/parameter/parametervirtualwidget.cpp
+  src/input/AxisConfigWidget.cc
+  src/input/ButtonConfigWidget.cc
+  src/input/InputDriver.cc
+  src/input/InputDriverManager.cc
+  src/input/InputEventMapper.cc
+  src/input/WheelIgnorer.cc
+  ${INPUT_DRIVER_SOURCES}
   )
 
 # header-only code
@@ -432,6 +454,11 @@ endif()
 
 set(RESOURCE_FILES icons/OpenSCAD.icns)
 
+if(ENABLE_SPNAV)
+  add_definitions(-DENABLE_SPNAV)
+  list(APPEND Sources src/input/SpaceNavInputDriver.cc)
+endif()
+
 add_executable(OpenSCAD ${Sources} ${RESOURCE_FILES})
 
 # FIXME: snapshot, ICON = icons/icon-nightly.icns
@@ -451,6 +478,10 @@ elseif(UNIX)
   )
 endif()
 
+if(ENABLE_SPNAV)
+  target_link_libraries(OpenSCAD spnav)
+endif()
+
 set(COMMON_LIBRARIES
     ${CGAL_LIBRARY}
     ${GMP_LIBRARIES}
@@ -469,6 +500,6 @@ set(COMMON_LIBRARIES
 
 target_link_libraries(OpenSCAD ${COMMON_LIBRARIES})
 if(NOT HEADLESS)
-  target_link_libraries(OpenSCAD Qt5::Core Qt5::Widgets Qt5::OpenGL Qt5::Concurrent ${QT5QSCINTILLA_LIBRARY})
+  target_link_libraries(OpenSCAD Qt5::Core Qt5::Widgets Qt5::OpenGL Qt5::Concurrent ${QT5QSCINTILLA_LIBRARY} ${Qt5DBus_LIBRARIES})
 endif()
 

features/hidapi.prf

@@ -0,0 +1,53 @@
+# Detect hidapi, then use this priority list to determine
+# which library to use:
+#
+# Priority
+# 1. HIDAPI_INCLUDEPATH / HIDAPI_LIBPATH (qmake parameter, not checked it given on commandline)
+# 2. OPENSCAD_LIBRARIES (environment variable)
+# 3. system's standard include paths from pkg-config
+
+# read environment variables
+OPENSCAD_LIBRARIES_DIR = $$(OPENSCAD_LIBRARIES)
+HIDAPI_DIR = $$(HIDAPIDIR)
+
+!isEmpty(OPENSCAD_LIBRARIES_DIR) {
+  isEmpty(HIDAPI_INCLUDEPATH) {
+    exists($$OPENSCAD_LIBRARIES_DIR/include/hidapi) {
+      HIDAPI_INCLUDEPATH = $$OPENSCAD_LIBRARIES_DIR/include/hidapi
+      HIDAPI_LIBPATH = $$OPENSCAD_LIBRARIES_DIR/lib
+    }
+  }
+}
+
+win*: {
+  # Use included HIDAPI on MXE/Windows build.
+  HIDAPI_CFLAGS = -I../src/hidapi
+  HIDAPI_LIBS = -lsetupapi
+  HEADERS += src/hidapi/hidapi.h
+  SOURCES += src/hidapi/hid.c
+} else {
+  isEmpty(HIDAPI_INCLUDEPATH) {
+    HIDAPI_CFLAGS = $$system("pkg-config --silence-errors --cflags hidapi-libusb")
+  } else {
+    HIDAPI_CFLAGS = -I$$HIDAPI_INCLUDEPATH
+  }
+
+  isEmpty(HIDAPI_LIBPATH) {
+    HIDAPI_LIBS = $$system("pkg-config --silence-errors --libs hidapi-libusb")
+  } else {
+    macx: {
+      HIDAPI_LIBS = -L$$HIDAPI_LIBPATH -lhidapi -framework IOKit -framework CoreFoundation
+    } else {
+      HIDAPI_LIBS = -L$$HIDAPI_LIBPATH -lhidapi-libusb
+    }
+  }
+}
+
+!isEmpty(HIDAPI_CFLAGS) {
+  QMAKE_CXXFLAGS += $$HIDAPI_CFLAGS
+  LIBS += $$HIDAPI_LIBS
+  DEFINES += ENABLE_HIDAPI
+
+  HEADERS += src/input/HidApiInputDriver.h
+  SOURCES += src/input/HidApiInputDriver.cc
+}

features/spnav.prf

@@ -0,0 +1,46 @@
+# Detect spnav, then use this priority list to determine
+# which library to use:
+#
+# Priority
+# 1. SPNAV_INCLUDEPATH / SPNAV_LIBPATH (qmake parameter, not checked it given on commandline)
+# 2. OPENSCAD_LIBRARIES (environment variable)
+# 3. system's standard include paths from pkg-config
+
+# read environment variables
+OPENSCAD_LIBRARIES_DIR = $$(OPENSCAD_LIBRARIES)
+SPNAV_DIR = $$(SPNAVDIR)
+
+!isEmpty(OPENSCAD_LIBRARIES_DIR) {
+  isEmpty(SPNAV_INCLUDEPATH) {
+    exists($$OPENSCAD_LIBRARIES_DIR/include/spnav.h) {
+      SPNAV_INCLUDEPATH = $$OPENSCAD_LIBRARIES_DIR/include
+      SPNAV_LIBPATH = $$OPENSCAD_LIBRARIES_DIR/lib
+    }
+  }
+}
+
+!win*: {
+  isEmpty(SPNAV_INCLUDEPATH) {
+    exists(/usr/include/spnav.h) {
+      SPNAV_INCLUDEPATH = /usr/include
+      SPNAV_LIBPATH = /usr/lib
+    }
+    exists(/usr/local/include/spnav.h) {
+      SPNAV_INCLUDEPATH = /usr/local/include
+      SPNAV_LIBPATH = /usr/local/lib
+    }
+    exists(/opt/include/spnav.h) {
+      SPNAV_INCLUDEPATH = /opt/include
+      SPNAV_LIBPATH = /opt/lib
+    }
+  }
+}
+
+!isEmpty(SPNAV_INCLUDEPATH) {
+  QMAKE_CXXFLAGS += -I$$SPNAV_INCLUDEPATH
+  LIBS += -L$$SPNAV_LIBPATH -lspnav
+  DEFINES += ENABLE_SPNAV
+
+  HEADERS += src/input/SpaceNavInputDriver.h
+  SOURCES += src/input/SpaceNavInputDriver.cc
+}

icons/license.txt

@@ -2,6 +2,18 @@ Taken from http://tango.freedesktop.org/Tango_Icon_Library, version 0.8.90 / pub
 
 - prefsFeatures.png (converted from preferences-system.svg)
 
+https://openclipart.org/detail/35425/tango-desktop-peripherals / Tango Icon Library / public domain:
+
+- prefsInput.png
+
+https://commons.wikimedia.org/wiki/File:Input-gaming.svg / Tango Icon Library / public domain:
+
+- prefsInputAxis.png (Button removed)
+
+https://commons.wikimedia.org/wiki/File:Input-keyboard.svg / Tango Icon Library / public domain:
+
+- prefsInputButtons.png
+
 https://openclipart.org/detail/2281/information-icons-set-by-kuba / public domain:
 
 - information-icons-error.png

info.pri

@@ -0,0 +1,38 @@
+message("Configuration")
+message("=============")
+message("")
+
+contains(CONFIG, debug) {
+  message("Debug mode: enabled")
+} else {
+  message("Debug mode: disabled")
+}
+
+contains(DEFINES, ENABLE_EXPERIMENTAL) {
+  message("Experimental features: enabled")
+} else {
+  message("Experimental features: disabled")
+}
+
+message("")
+message("Input Drivers")
+contains(DEFINES, ENABLE_HIDAPI) {
+  message("- HID API Driver (enabled)")
+} else {
+  message("- HID API Driver (disabled)")
+}
+contains(DEFINES, ENABLE_SPNAV) {
+  message("- Space Navigator Library Driver (enabled)")
+} else {
+  message("- Space Navigator Library Driver (disabled)")
+}
+contains(DEFINES, ENABLE_JOYSTICK) {
+  message("- Joystick Driver (enabled)")
+} else {
+  message("- Joystick Driver (disabled)")
+}
+contains(DEFINES, ENABLE_DBUS) {
+  message("- DBus Remote Driver (enabled)")
+} else {
+  message("- DBus Remote Driver (disabled)")
+}

openscad.pro

@@ -16,7 +16,7 @@
 #   resource folder. E.g. using SUFFIX=-nightly will name the
 #   resulting binary openscad-nightly.
 #
-# Please see the 'Building' sections of the OpenSCAD user manual 
+# Please see the 'Building' sections of the OpenSCAD user manual
 # for updated tips & workarounds.
 #
 # https://en.wikibooks.org/wiki/OpenSCAD_User_Manual
@@ -178,6 +178,8 @@ CONFIG += fontconfig
 CONFIG += gettext
 CONFIG += libxml2
 CONFIG += libzip
+CONFIG += hidapi
+CONFIG += spnav
 
 #Uncomment the following line to enable the QScintilla editor
 !nogui {
@@ -225,7 +227,9 @@ FORMS   += src/MainWindow.ui \
            src/launchingscreen.ui \
            src/LibraryInfoDialog.ui \
            src/parameter/ParameterWidget.ui \
-           src/parameter/ParameterEntryWidget.ui
+           src/parameter/ParameterEntryWidget.ui \
+           src/input/ButtonConfigWidget.ui \
+           src/input/AxisConfigWidget.ui
 
 # AST nodes
 FLEXSOURCES += src/lexer.l 
@@ -268,6 +272,7 @@ HEADERS += src/version_check.h \
            src/OpenSCADApp.h \
            src/WindowManager.h \
            src/Preferences.h \
+           src/SettingsWriter.h \
            src/OpenCSGWarningDialog.h \
            src/AboutDialog.h \
            src/FontListDialog.h \
@@ -369,7 +374,13 @@ HEADERS += src/version_check.h \
            src/parameter/parameterset.h \
            src/parameter/ignoreWheelWhenNotFocused.h \
            src/QWordSearchField.h \
-           src/QSettingsCached.h
+           src/QSettingsCached.h \
+           src/input/InputDriver.h \
+           src/input/InputEventMapper.h \
+           src/input/InputDriverManager.h \
+           src/input/AxisConfigWidget.h \
+           src/input/ButtonConfigWidget.h \
+           src/input/WheelIgnorer.h
 
 SOURCES += \
            src/libsvg/libsvg.cc \
@@ -386,7 +397,9 @@ SOURCES += \
            src/libsvg/transformation.cc \
            src/libsvg/util.cc \
            \
-           src/version_check.cc \
+           src/version_check.cc
+
+SOURCES += \
            src/ProgressWidget.cc \
            src/linalg.cc \
            src/Camera.cc \
@@ -448,6 +461,7 @@ SOURCES += \
            src/rendersettings.cc \
            src/highlighter.cc \
            src/Preferences.cc \
+           src/SettingsWriter.cc \
            src/OpenCSGWarningDialog.cc \
            src/editor.cc \
            src/GLView.cc \
@@ -510,8 +524,14 @@ SOURCES += \
            src/parameter/parametervirtualwidget.cpp \
            src/parameter/ignoreWheelWhenNotFocused.cpp \
            src/QWordSearchField.cc\
+           src/QSettingsCached.cc \
            \
-           src/QSettingsCached.cc
+           src/input/InputDriver.cc \
+           src/input/InputEventMapper.cc \
+           src/input/InputDriverManager.cc \
+           src/input/AxisConfigWidget.cc \
+           src/input/ButtonConfigWidget.cc \
+           src/input/WheelIgnorer.cc
 
 # CGAL
 HEADERS += src/ext/CGAL/convex_hull_3_bugfix.h \
@@ -545,6 +565,32 @@ HEADERS += src/ext/libtess2/Include/tesselator.h \
            src/ext/libtess2/Source/sweep.h \
            src/ext/libtess2/Source/tess.h
 
+unix:!macx {
+  QT += dbus
+  DEFINES += ENABLE_DBUS
+  DBUS_ADAPTORS += org.openscad.OpenSCAD.xml
+  DBUS_INTERFACES += org.openscad.OpenSCAD.xml
+
+  HEADERS += src/input/DBusInputDriver.h
+  SOURCES += src/input/DBusInputDriver.cc
+}
+
+unix:!macx {
+  DEFINES += ENABLE_JOYSTICK
+
+  HEADERS += src/input/JoystickInputDriver.h
+  SOURCES += src/input/JoystickInputDriver.cc
+}
+
+!lessThan(QT_MAJOR_VERSION, 5) {
+  qtHaveModule(gamepad) {
+    QT += gamepad
+    DEFINES += ENABLE_QGAMEPAD
+    HEADERS += src/input/QGamepadInputDriver.h
+    SOURCES += src/input/QGamepadInputDriver.cc
+  }
+}
+
 unix:!macx {
   SOURCES += src/imageutils-lodepng.cc
   SOURCES += src/OffscreenContextGLX.cc
@@ -666,5 +712,9 @@ man.path = $$PREFIX/share/man/man1
 man.extra = cp -f doc/openscad.1 \"\$(INSTALL_ROOT)$${man.path}/$${FULLNAME}.1\"
 INSTALLS += man
 
+info: {
+    include(info.pri)
+}
+
 DISTFILES += \
     sounds/complete.wav

openscad.qrc

@@ -1,5 +1,8 @@
 <RCC>
   <qresource prefix="/">
+    <file>icons/prefsInput.png</file>
+    <file>icons/prefsInputAxis.png</file>
+    <file>icons/prefsInputButtons.png</file>
     <file>images/zoom-text-in-white.png</file>
     <file>images/zoom-text-in.png</file>
     <file>images/zoom-text-out-white.png</file>