Combining non-commuting objects with gamma matrices

[jurajkl]

Hello,

I was wondering whether FeynCalc supports combining gamma matrices with other non-commuting objects.
E.g. if I have two objects X = \gamma^\mu A, and Y=\gamma^\nu B, where A and B are e.g. matrices in flavor space, is it possible to compute the Dirac trace
Tr_D ( [X, Y] ) = 4 g_{\mu \nu} [A, B] ?
My attempt at implementing this is:

DeclareNonCommutative[A, B]
X=A.GA[mu];
Y=B.GA[nu];
DiracSimplify[DiracTrace[Commutator[X, Y]]]

The result I would expect is:
Commutator[A,B]*4*Pair[LorentzIndex[mu], LorentzIndex[nu]]

The final commutator does not simplify to this, presumably, as the FeynCalc doesn't know that the matrices A and B aren't Dirac matrices.
Is there a way to do this within FeynCalc? If not, would this be a feature you would consider implementing at some point?
Thanks!

p.s. I am using mathematica 13.1 and FeynCalc 9.3.1

[vsht]

Hi,

in such cases I usually code some extra routines on top of FeynCalc that handle the splitting between Dirac matrices and other stuff. For example

DeclareNonCommutative[A, B]
X = A . GA[mu];
Y = B . GA[nu];
DiracSimplify[DiracTrace[Commutator[X, Y]]]

UnDeclareAllCommutators[];
Commutator[DiracGamma[x__], A] := 0;
Commutator[DiracGamma[x__], B] := 0;

Commutator[X, Y] // DotSimplify // ReplaceAll[#, DOT -> holdDOT] & // 
    ReplaceAll[#,
      holdDOT[r__, d__DiracGamma] /; FreeQ[{r}, DiracGamma] :> 
       holdDOT[r] holdDOT[d]
      ] & // ReplaceAll[#, holdDOT -> DOT] & // 
  DiracTrace // DiracSimplify
(*4 A . B Pair[LorentzIndex[mu], LorentzIndex[nu]] - 4 B . A Pair[LorentzIndex[mu], LorentzIndex[nu]]*)

Cheers,
Vladyslav

[jurajkl]

Works great, thanks a lot!