-
Notifications
You must be signed in to change notification settings - Fork 120
/
LP_file_format.jl
173 lines (154 loc) · 5.37 KB
/
LP_file_format.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
function _internal_save_lp(io::IO, p::Polymake.BigObject, lp::Polymake.BigObject, max::Bool)
# we cannot pass an IO object, so we use shell_execute to capture the stdout and write
# the string to the IO object
# to pass the object to the polymake shell we use a randomly generated variable name
rstr = randstring(['A':'Z'; 'a':'z'], 12)
Polymake.call_function(:User, :set_shell_scalar, rstr * "_poly", p)
Polymake.call_function(:User, :set_shell_scalar, rstr * "_lp", lp)
out, err = Polymake.shell_execute(
"""polytope::poly2lp(\$$(rstr)_poly, \$$(rstr)_lp, $(max ? 1 : 0));"""
)
write(io, out)
Polymake.call_function(:User, :set_shell_scalar, rstr * "_poly", 0)
Polymake.call_function(:User, :set_shell_scalar, rstr * "_lp", 0)
nothing
end
function _internal_save_mps(io::IO, p::Polymake.BigObject, lp::Polymake.BigObject)
rstr = randstring(['A':'Z'; 'a':'z'], 12)
Polymake.call_function(:User, :set_shell_scalar, rstr * "_poly", p)
Polymake.call_function(:User, :set_shell_scalar, rstr * "_lp", lp)
out, err = Polymake.shell_execute("""polytope::poly2mps(\$$(rstr)_poly, \$$(rstr)_lp);""")
write(io, out)
Polymake.call_function(:User, :set_shell_scalar, rstr * "_poly", 0)
Polymake.call_function(:User, :set_shell_scalar, rstr * "_lp", 0)
nothing
end
function _internal_save_lp(
filename::String, p::Polymake.BigObject, lp::Polymake.BigObject, max::Bool
)
Polymake.polytope.poly2lp(p, lp, max, filename)
nothing
end
function _internal_save_mps(filename::String, p::Polymake.BigObject, lp::Polymake.BigObject)
Polymake.polytope.poly2mps(p, lp, Polymake.Set{Int}(), filename)
nothing
end
@doc raw"""
save_lp(target::Union{String, IO}, lp::Union{MixedIntegerLinearProgram,LinearProgram})
Save a (mixed integer) linear program to an `.lp` file using the LP file format.
# Examples
Take the square $[-1/2,3/2]^2$ with objective $[1,1]$ and one integer variable.
Print the object in LP format to stdout:
```jldoctest
julia> c = cube(2, -1//2, 3//2)
Polytope in ambient dimension 2
julia> milp = mixed_integer_linear_program(c, [1,1], integer_variables=[1])
Mixed integer linear program
julia> save_lp(stdout, milp)
MAXIMIZE
obj: +1 x1 +1 x2
Subject To
ie0: +2 x1 >= -1
ie1: -2 x1 >= -3
ie2: +2 x2 >= -1
ie3: -2 x2 >= -3
BOUNDS
x1 free
x2 free
GENERAL
x1
END
```
"""
function save_lp(
target::Union{String,IO},
lp::Union{MixedIntegerLinearProgram{QQFieldElem},LinearProgram{QQFieldElem}},
)
_internal_save_lp(
target, pm_object(feasible_region(lp)), pm_object(lp), lp.convention == :max
)
end
@doc raw"""
save_mps(target::String, lp::Union{MixedIntegerLinearProgram,LinearProgram})
Save a (mixed integer) linear program to an `.mps` file using the MPS file format.
# Examples
Create the square $[-1/2,3/2]^2$ with objective $[1,1]$ and one integer variable.
Print the object in MPS format to stdout:
```jldoctest
julia> c = cube(2, -1//2, 3//2)
Polytope in ambient dimension 2
julia> milp = mixed_integer_linear_program(c, [1,1], integer_variables=[1])
Mixed integer linear program
julia> save_mps(stdout, milp)
* Class: MIP
* Rows: 5
* Columns: 2
* Format: MPS
*
NAME unnamed#0
ROWS
N C0000000
G R0000000
G R0000001
G R0000002
G R0000003
COLUMNS
M0000000 'MARKER' 'INTORG'
x1 C0000000 1 R0000000 1
x1 R0000001 -1
M0000000 'MARKER' 'INTEND'
x2 C0000000 1 R0000002 1
x2 R0000003 -1
RHS
B R0000000 -0.5 R0000001 -1.5
B R0000002 -0.5 R0000003 -1.5
BOUNDS
FR BND x1
FR BND x2
ENDATA
```
"""
function save_mps(
target::Union{String,IO},
lp::Union{MixedIntegerLinearProgram{QQFieldElem},LinearProgram{QQFieldElem}},
)
_internal_save_mps(target, pm_object(feasible_region(lp)), pm_object(lp))
end
@doc raw"""
load_mps(file::String)
Load a (mixed integer) linear program from an `.mps` file using the MPS file format.
"""
function load_mps(file::String)
poly = Polymake.polytope.mps2poly(file)::Polymake.BigObject
if Polymake.exists(poly, "LP")
lp = poly.LP
Polymake.attach(lp, "convention", "max")
return linear_program(polyhedron(poly), lp, :max)
elseif Polymake.exists(poly, "MILP")
milp = poly.MILP
Polymake.attach(milp, "convention", "max")
return mixed_integer_linear_program(polyhedron(poly), milp, :max)
else
error("load_mps: cannot find LP or MILP subobject in polymake object")
end
end
@doc raw"""
load_lp(file::String)
Load a (mixed integer) linear program from an `.lp` file using the LP file format.
"""
function load_lp(file::String)
poly = Polymake.polytope.lp2poly(file; nocheck=true)::Polymake.BigObject
if Polymake.exists(poly, "LP")
lp = poly.LP
convention = occursin("MAXIMIZE", String(Polymake.getdescription(lp))) ? :max : :min
Polymake.attach(lp, "convention", String(convention))
return linear_program(polyhedron(poly), lp, convention)
elseif Polymake.exists(poly, "MILP")
milp = poly.MILP
convention = occursin("MAXIMIZE", String(Polymake.getdescription(milp))) ? :max : :min
Polymake.attach(milp, "convention", String(convention))
return mixed_integer_linear_program(polyhedron(poly), milp, convention)
else
error("load_lp: cannot find LP or MILP subobject in polymake object")
end
end