-
Notifications
You must be signed in to change notification settings - Fork 120
/
Attributes.jl
261 lines (194 loc) · 7.74 KB
/
Attributes.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
export underlying_morphism, domain, codomain, pullback, inverse, preimage
export pullback_type, domain_type, codomain_type, morphism_type
########################################################################
# (1) Properties for AbsSpecMor
########################################################################
# In an attempt to mimic inheritance, any new concrete instance of AbsSpecMor
# can internally store a SpecMor instance and must implement the method
# underlying_morphism to access it. Then, all functionality for SpecMor is
# automatically forwarded.
underlying_morphism(f::AbsSpecMor) = error("`underlying_morphism(f)` not implemented for `f` of type $(typeof(f))")
@Markdown.doc """
domain(f::AbsSpecMor)
On a morphism ``f : X → Y`` of affine schemes, this returns ``X``.
# Examples
```jldoctest
julia> Y = affine_space(QQ,3)
Spec of Multivariate Polynomial Ring in x1, x2, x3 over Rational Field
julia> R = OO(Y)
Multivariate Polynomial Ring in x1, x2, x3 over Rational Field
julia> (x1,x2,x3) = gens(R)
3-element Vector{fmpq_mpoly}:
x1
x2
x3
julia> X = subscheme(Y, x1)
Spec of Quotient of Multivariate Polynomial Ring in x1, x2, x3 over Rational Field by ideal(x1)
julia> f = inclusion_morphism(X, Y);
julia> domain(f)
Spec of Quotient of Multivariate Polynomial Ring in x1, x2, x3 over Rational Field by ideal(x1)
```
"""
domain(f::AbsSpecMor) = domain(underlying_morphism(f))
@Markdown.doc """
codomain(f::AbsSpecMor)
On a morphism ``f : X → Y`` of affine schemes, this returns ``Y``.
# Examples
```jldoctest
julia> Y = affine_space(QQ,3)
Spec of Multivariate Polynomial Ring in x1, x2, x3 over Rational Field
julia> R = OO(Y)
Multivariate Polynomial Ring in x1, x2, x3 over Rational Field
julia> (x1,x2,x3) = gens(R)
3-element Vector{fmpq_mpoly}:
x1
x2
x3
julia> X = subscheme(Y, x1)
Spec of Quotient of Multivariate Polynomial Ring in x1, x2, x3 over Rational Field by ideal(x1)
julia> f = inclusion_morphism(X, Y);
julia> codomain(f)
Spec of Multivariate Polynomial Ring in x1, x2, x3 over Rational Field
```
"""
codomain(f::AbsSpecMor) = codomain(underlying_morphism(f))
@Markdown.doc """
pullback(f::AbsSpecMor)
On a morphism ``f : X → Y`` of affine schemes ``X = Spec(S)`` and
``Y = Spec(R)``, this returns the ring homomorphism ``f^* : R → S``.
# Examples
```jldoctest
julia> Y = affine_space(QQ,3)
Spec of Multivariate Polynomial Ring in x1, x2, x3 over Rational Field
julia> R = OO(Y)
Multivariate Polynomial Ring in x1, x2, x3 over Rational Field
julia> (x1,x2,x3) = gens(R)
3-element Vector{fmpq_mpoly}:
x1
x2
x3
julia> X = subscheme(Y, x1)
Spec of Quotient of Multivariate Polynomial Ring in x1, x2, x3 over Rational Field by ideal(x1)
julia> pullback(inclusion_morphism(X, Y))
Map with following data
Domain:
=======
Multivariate Polynomial Ring in x1, x2, x3 over Rational Field
Codomain:
=========
Quotient of Multivariate Polynomial Ring in x1, x2, x3 over Rational Field by ideal(x1)
```
"""
pullback(f::AbsSpecMor) = pullback(underlying_morphism(f))
########################################################################
# (2) Properties for SpecMor
########################################################################
pullback(phi::SpecMor) = phi.pullback
domain(phi::SpecMor) = phi.domain
codomain(phi::SpecMor) = phi.codomain
########################################################################
# (3) Properties for OpenInclusion
########################################################################
underlying_morphism(f::OpenInclusion) = f.inc
complement_ideal(f::OpenInclusion) = f.I
complement_scheme(f::OpenInclusion) = f.Z
########################################################################
# (4) Preimage
########################################################################
function preimage(
phi::AbsSpecMor,
Z::AbsSpec{<:Ring, <:MPolyQuoLocalizedRing{<:Any, <:Any, <:Any, <:Any,
<:MPolyPowersOfElement}};
check::Bool=true
)
X = domain(phi)
Y = codomain(phi)
check && (issubset(Z, Y) || (Z = intersect(Y, Z)))
IZ = modulus(underlying_quotient(OO(Z)))
a = denominators(inverted_set(OO(Z)))
R = ambient_coordinate_ring(X)
f = pullback(phi)
new_units = elem_type(R)[lifted_numerator(f(d)) for d in a]
new_gens = Vector{elem_type(R)}(lifted_numerator.(f.(gens(IZ))))
return hypersurface_complement(subscheme(X, new_gens), new_units)
end
function preimage(f::AbsSpecMor, Z::AbsSpec{<:Ring, <:MPolyRing}; check::Bool=true)
OO(Z) == ambient_coordinate_ring(codomain(f)) || error("schemes can not be compared")
return subscheme(domain(f), ideal(OO(domain(f)), [zero(OO(domain(f)))]))
end
function preimage(f::AbsSpecMor,
Z::AbsSpec{<:Ring, <:MPolyLocalizedRing{<:Any, <:Any, <:Any, <:Any,
<:MPolyPowersOfElement}};
check::Bool=true)
return hypersurface_complement(domain(f), pullback(f).(denominators(inverted_set(OO(Z)))))
end
function preimage(f::AbsSpecMor, Z::AbsSpec; check::Bool=true)
pbf = pullback(f)
R = OO(codomain(f))
S = OO(domain(f))
I = ideal(R, gens(modulus(OO(Z))))
J = ideal(S, pbf.(gens(I)))
return subscheme(domain(f), J)
end
##############################################
# (5) The graph of a morphism
##############################################
@Markdown.doc """
graph(f::AbsSpecMor)
Return the graph of ``f : X → Y`` as a subscheme of ``X×Y`` as well as the two projections to ``X`` and ``Y``.
# Examples
```jldoctest
julia> Y = affine_space(QQ,3)
Spec of Multivariate Polynomial Ring in x1, x2, x3 over Rational Field
julia> R = OO(Y)
Multivariate Polynomial Ring in x1, x2, x3 over Rational Field
julia> (x1,x2,x3) = gens(R)
3-element Vector{fmpq_mpoly}:
x1
x2
x3
julia> X = subscheme(Y, x1)
Spec of Quotient of Multivariate Polynomial Ring in x1, x2, x3 over Rational Field by ideal(x1)
julia> f = inclusion_morphism(X, Y);
julia> graph(f);
```
"""
function graph(f::AbsSpecMor)
X = standard_spec(domain(f))
Y = standard_spec(codomain(f))
fres = restrict(f, X, Y)
G, prX, prY = graph(fres)
return G, compose(prX, SpecMor(X, domain(f), gens(OO(X)))), compose(prY, SpecMor(Y, codomain(f), gens(OO(Y))))
end
function graph(f::AbsSpecMor{SpecType, SpecType}) where {SpecType<:StdSpec}
X = domain(f)
Y = codomain(f)
XxY, prX, prY = product(X, Y)
pb_X = pullback(prX)
pb_Y = pullback(prY)
pb_f = pullback(f)
I = ideal(localized_ring(OO(XxY)), lift.(pb_X.(images(pb_f)) - pb_Y.(gens(OO(Y)))))
G = subscheme(XxY, I)
return G, restrict(prX, G, X), restrict(prY, G, Y)
end
##############################################
# (6) The inverse of a morphism
##############################################
@attr AbsSpecMor function inverse(f::AbsSpecMor)
is_isomorphism(f) || error("the given morphism is not an isomorphism")
return get_attribute(f, :inverse)::morphism_type(codomain(f), domain(f))
end
########################################################################
# (7) Type getters
########################################################################
### Type getters
pullback_type(::Type{T}) where {DomType, CodType, PbType, T<:AbsSpecMor{DomType, CodType, PbType}} = PbType
pullback_type(f::AbsSpecMor) = pullback_type(typeof(f))
domain_type(::Type{T}) where {DomType, CodType, PbType, T<:AbsSpecMor{DomType, CodType, PbType}} = DomType
domain_type(f::AbsSpecMor) = domain_type(typeof(f))
codomain_type(::Type{T}) where {DomType, CodType, PbType, T<:AbsSpecMor{DomType, CodType, PbType}} = CodType
codomain_type(f::AbsSpecMor) = codomain_type(typeof(f))
function morphism_type(::Type{SpecType1}, ::Type{SpecType2}) where {SpecType1<:AbsSpec, SpecType2<:AbsSpec}
return SpecMor{SpecType1, SpecType2, morphism_type(ring_type(SpecType2), ring_type(SpecType1))}
end
morphism_type(X::AbsSpec, Y::AbsSpec) = morphism_type(typeof(X), typeof(Y))