/
state.t
284 lines (249 loc) · 6.79 KB
/
state.t
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
use v6;
use Test;
plan 40;
# L<S04/The Relationship of Blocks and Declarations/There is a new state declarator that introduces>
# RT #67040 -- state initialized with //= instead of =
# (I've put this test here since it gets buggered by later tests
# unless RT #67058 has been fixed.)
{
sub rt67040 {
state $x //= 17;
$x++;
return $x;
}
is rt67040(), 18, 'Assignment to state variable with //= works.';
is rt67040(), 19, 'Assignment to state variable with //= happens once.';
}
# state() inside subs
{
sub inc () {
state $svar;
$svar++;
return $svar;
};
is(inc(), 1, "state() works inside subs (first)");
is(inc(), 2, "state() works inside subs (second)");
is(inc(), 3, "state() works inside subs (#3)");
}
# state() inside coderefs
# L<S04/Phasers/"semantics to any initializer, so this also works">
#?DOES 1
{
my $gen = {
# Note: The following line is only executed once, because it's equivalent
# to
# state $svar will first { 42 };
state $svar = 42;
my $ret = { $svar++ };
};
my $a = $gen(); # $svar == 42
$a(); $a(); # $svar == 44
my $b = $gen(); # $svar == 44
is $b(), 44, "state() works inside coderefs";
}
# state() inside for-loops
{
for 1,2,3 -> $val {
state $svar;
$svar++;
# Only check on last run
if $val == 3 {
is $svar, 3, "state() works inside for-loops";
}
}
}
# state with arrays.
{
my @bar = 1,2,3;
sub swatest {
state (@foo) = @bar;
my $x = @foo.join('|');
@foo[0]++;
return $x
}
is swatest(), '1|2|3', 'array state initialized correctly';
is swatest(), '2|2|3', 'array state retained between calls';
}
# state with arrays.
{
sub swainit_sub { 1,2,3 }
sub swatest2 {
state (@foo) = swainit_sub();
my $x = @foo.join('|');
@foo[0]++;
return $x
}
is swatest2(), '1|2|3', 'array state initialized from call correctly';
is swatest2(), '2|2|3', 'array state retained between calls';
}
# (state @foo) = @bar differs from state @foo = @bar
{
my @bar = 1,2,3;
sub swatest3 {
(state @foo) = @bar;
my $x = @foo.join('|');
@foo[0]++;
return $x
}
is swatest3(), '1|2|3', '(state @foo) = @bar is not state @foo = @bar';
is swatest3(), '1|2|3', '(state @foo) = @bar is not state @foo = @bar';
}
# RHS of state is only run once per init
{
my $rhs_calls = 0;
sub impure_rhs {
state $x = do { $rhs_calls++ } #OK not used
}
impure_rhs() for 1..3;
is $rhs_calls, 1, 'RHS of state $x = ... only called once';
}
# L<http://www.nntp.perl.org/group/perl.perl6.language/20888>
# ("Re: Declaration and definition of state() vars" from Larry)
{
my ($a, $b);
my $gen = {
(state $svar) = 42;
-> { $svar++ };
};
$a = $gen(); # $svar == 42
$a(); $a(); # $svar == 44
$b = $gen()(); # $svar == 42
is $b, 42, "state() and parens"; # svar == 43
}
# state() inside regular expressions
#?rakudo todo 'embedded closures in regexen'
#?niecza skip ':Perl5'
#?DOES 1
{
my $str = "abc";
my $re = {
# Perl 5 RE, as we don't want to force people to install Parrot ATM. (The
# test passes when using the Perl 6 RE, too.)
$str ~~ s:Perl5/^(.)/{
state $svar;
++$svar;
}/;
};
$re();
$re();
$re();
is +$str, 3, "state() inside regular expressions works";
}
# state() inside subs, chained declaration
{
sub step () {
state $svar = state $svar2 = 42;
$svar++;
$svar2--;
return (+$svar, +$svar2);
};
is(step().join('|'), "43|41", "chained state (1)");
is(step().join('|'), "44|40", "chained state (2)");
}
# state in cloned closures
#?DOES 4
{
for <first second> {
my $code = {
state $foo = 42;
++$foo;
};
is $code(), 43, "state was initialized properly ($_ time)";
is $code(), 44, "state keeps its value across calls ($_ time)";
}
}
# state with multiple explicit calls to clone - a little bit subtle
#?DOES 3
{
my $i = 0;
my $func = { state $x = $i++; $x };
my ($a, $b) = $func.clone, $func.clone;
is $a(), 0, 'state was initialized correctly for clone 1';
#?niecza todo
is $b(), 1, 'state was initialized correctly for clone 2';
is $a(), 0, 'state between clones is independent';
}
# recursive state with list assignment initialization happens only first time
#?DOES 2
{
my $seensize;
my sub fib (Int $n) {
state @seen = 0,1,1;
$seensize = +@seen;
@seen[$n] //= fib($n-1) + fib($n-2);
}
is fib(10), 55, "fib 10 works";
is $seensize, 10, "list assignment state in fib memoizes";
}
# recursive state with [list] assignment initialization happens only first time
#?DOES 2
{
my $seensize;
my sub fib (Int $n) {
state $seen = [0,1,1];
$seensize = +@$seen;
$seen[$n] //= fib($n-1) + fib($n-2);
}
is fib(10), 55, "fib 2 works";
is $seensize, 10, "[list] assignment state in fib memoizes";
}
#?rakudo skip 'parse error'
#?DOES 4
{
# now we're just being plain evil:
subset A of Int where { $_ < state $x++ };
my A $y = -4;
# the compiler could have done some checks somehwere, so
# pick a reasonably high number
dies_ok { $y = 900000 }, 'growing subset types rejects too high values';
lives_ok { $y = 1 }, 'the state variable in subset types works (1)';
lives_ok { $y = 2 }, 'the state variable in subset types works (2)';
lives_ok { $y = 3 }, 'the state variable in subset types works (3)';
}
# Test for RT #67058
sub bughunt1 { (state $svar) } #OK not used
{
sub bughunt2 { state $x //= 17; ++$x }
is bughunt2(), 18,
'a state variable in parens works with a state variable with //= init';
}
#?rakudo skip 'parse error'
#?DOES 1
{
# http://irclog.perlgeek.de/perl6/2010-04-27#i_2269848
my @tracker;
for (1..3) {
my $x = sub { state $s++; @tracker.push: $s }
$x();
};
is @tracker.join('|'), '1|1|1',
'state var in anonymous closure in loop is not shared';
}
# niecza regression: state not working at top level
eval_lives_ok 'state $x; $x', 'state outside control structure';
#?rakudo todo 'initialization happens only on first call(?)'
{
sub f($x) {
return if $x;
state $y = 5;
$y;
}
f(1);
is f(0), 5, 'initialization not reached on first run of the functions';
}
{
sub r {
state ($a, $b) = (5, 42);
$a++; $b--;
"$a $b"
}
r();
is r(), '7 40', 'state vars and list assignment mixes';
}
{
my $x = 1;
sub foo() { state $ = $x++ };
is foo(), 1, 'anonymous state variable (1)';
is foo(), 1, 'anonymous state variable (2)';
}
# vim: ft=perl6